condch.f90

来自「CLM集合卡曼滤波数据同化算法」· F90 代码 · 共 53 行

  SUBROUTINE condch (sigf,lsai,ra,rb,rd, &
                     wta,wtl,wtg,wta0,wtl0,wtg0,wtal,wtga,wtgl )

!=======================================================================
!      Source file: condch.f90
! Original version: Yongjiu Dai, September 15, 1999
!
! Provide dimensional and non-dimensional sensible heat conductances
! for canopy and soil flux calculations.
!
!=======================================================================

  IMPLICIT NONE

! dummy argument
  real, INTENT(in) :: &
        sigf, &! fraction of veg cover, excluding snow-covered veg [-]
        lsai, &! leaf + stem area index 
        ra,   &! aerodynamical resistance [s/m]
        rb,   &! leaf boundary layer resistance [s/m]
        rd     ! thermal resistance between ground and bottom of canopy

  real, INTENT(out) :: &
        wta,  &! heat conduactance for air [m/s]
        wtg,  &! heat conduactance for ground [m/s]
        wtl,  &! heat conduactance for leaf [m/s]
        wta0, &! normalized heat conduactance for air [-]
        wtl0, &! normalized heat conduactance for air [-]
        wtg0, &! normalized heat conduactance for ground [-]
        wtal, &! normalized heat conductance for air and leaf [-]
        wtgl, &! normalized heat conductance for leaf and ground [-]
        wtga   ! normalized heat cond. for air and ground  [-]

! local variables
  real  wtshi  ! heat resistance for air, ground and leaf [s/m]

!-----------------------------------------------------------------------

        wta   = sigf/ra           ! air
        wtl   = sigf*lsai/rb      ! leaf
        wtg   = sigf/rd           ! ground
        wtshi = 1./(wta+wtl+wtg)

        wtl0  = wtl*wtshi         ! leaf
        wtg0  = wtg*wtshi         ! ground
        wta0  = wta*wtshi         ! air

        wtgl  = wtl0+wtg0         ! ground + leaf
        wtga  = wta0+wtg0         ! ground + air
        wtal  = wta0+wtl0         ! air + leaf

  END SUBROUTINE condch