dtrdatarec.pas

提取铁路的GPS数据通过串口

unit DTRDataREC;

interface
uses Classes, dialogs, sysutils,Unit_dll;

type

  TDTUDataRec = packed record
    m_DTUID: Cardinal;
    m_DTUPhone: array [1..11] of Char;
    m_DTUSerial: Integer;
    m_Loco: array [1..11] of char;
    m_Train: array [1..11] of char;
    m_TrainDirect: Integer;
    m_TrainLength: Integer;
    m_Longitude: array [0..10] of char;
    m_Latitude: array[0..9] of char;
  end;

  TRecordStream = class(TFileStream)
  private
    function GetNumRecs: Longint;
    function GetCurRec: Longint;
    procedure SetCurRec(RecNo: Longint);
  protected
    function GetRecSize: Longint; virtual;
  public
    function SeekRec(RecNo: Longint; Origin: Word): Longint;
    function WriteRec(const Rec): Longint;
    function AppendRec(const Rec): Longint;
    function ReadRec(var Rec): Longint;
    procedure First;
    procedure Last;
    procedure NextRec;
    procedure PreviousRec;
    property NumRecs: Longint read GetNumRecs;
    property CurRec: Longint read GetCurRec write SetCurRec;
  end;

implementation

function TRecordStream.GetRecSize:Longint;
begin
  Result := SizeOf(TDTUDataRec);
end;

function TRecordStream.GetNumRecs: Longint;
begin
  Result := Size div GetRecSize;
end;

function TRecordStream.GetCurRec: Longint;
begin
  Result := (Position div GetRecSize) + 1;
end;

procedure TRecordStream.SetCurRec(RecNo: Longint);
begin
  if RecNo > 0 then
    Position := (RecNo - 1) * GetRecSize
  else
    Raise Exception.Create('已经到达文件的开始。');
end;

function TRecordStream.SeekRec(RecNo: Longint; Origin: Word): Longint;
begin
  Result := Seek(RecNo * GetRecSize, Origin);
end;

function TRecordStream.WriteRec(Const Rec): Longint;
begin
  Result := Write(Rec, GetRecSize);
end;

function TRecordStream.AppendRec(Const Rec): Longint;
begin
  Seek(0, 2);
  Result := Write(Rec, GetRecSize);
end;

function TRecordStream.ReadRec(var Rec): Longint;
begin
  Result := Read(Rec, GetRecSize);
  Seek(-GetRecSize, 1);
end;

procedure TRecordStream.First;
begin
  Seek(0, 0);
end;

procedure TRecordStream.Last;
begin
  Seek(0, 2);
  Seek(-GetRecSize, 1);
end;

procedure TRecordStream.NextRec;
begin
  if ((Position + GetRecSize) div GetRecSize) = GetNumRecs then
    raise Exception.Create('已经到达文件的结尾')
  else
    Seek(GetRecSize, 1);
end;

procedure TRecordStream.PreviousRec;
begin
  if (Position - GetRecSize >= 0) then
    Seek(-GetRecSize, 1)
  else
    Raise Exception.Create('已经到达文件的开始');
end;

end.