⭐ 欢迎来到虫虫下载站！ | 📦 资源下载 📁 资源专辑 ℹ️ 关于我们
⭐ 虫虫下载站
📤 上传资源

📄 admin_database.asp

📁 玛雅自助导航系统 玛雅自助导航系统 玛雅自助导航系统
💻 ASP
字号:
🔍 
<%@LANGUAGE="VBSCRIPT" CODEPAGE="65001"%>
<!--#include file="Conn.asp"-->
<%
If Session(SiteSN&"_Admin_Login")<>AdminName&"_"&AdminPass Then
   Response.redirect "Admin_Login.asp"
End If

set Wap=nothing
dim Action,FoundErr,ErrMsg
Action=trim(request("Action"))

DIm dbpath,Objfso,ObjInstalled
dbpath=server.mappath(WapLinkMdb)
Objfso = "Scripting.FileSystemObject"
ObjInstalled=IsObjInstalled(Objfso)

%>
<!DOCTYPE HTML PUBLIC "-//W3C//DTD HTML 4.0 Transitional//EN" 
    "http://www.w3.org/TR/html4/loose.dtd">
<html>
<head>
<meta http-equiv="Content-Type" content="text/html; charset=utf-8">
<link href="style.css" rel="stylesheet" type="text/css">
<title>数据库备份 - Powered By ITlearner</title>
</head>
<body>
<div class="main_title1">
<a href="admin_manage.asp">管理首页</a> | <a href="admin_manage.asp?action=ListSite">管理网站信息</a> | <a href="admin_manage.asp?action=ShowLog">查看点击记录</a> | <a href="admin_type.asp">管理网站分类</a> | <a href="admin_manage.asp?action=BatchDelform">批量删除数据</a> | <a href="admin_login.asp?action=exit">退出管理</a>
</div>
<div class="mainbar">
<p align="center"><a href="admin_database.asp?Action=Backup">备份数据库</a> | <a href="admin_database.asp?Action=Restore">恢复数据库</a> | <a href="admin_database.asp?Action=Compact">压缩数据库</a></p>
<%
	If ObjInstalled=false Then
		Response.Write "<b><font color=""red"">你的服务器不支持 FSO(Scripting.FileSystemObject)! 不能使用本功能</font></b><br>"
		Response.Write "建议您每隔一段时间将数据库下载到本地备份，以确保数据安全。<br>"
		Response.Write "为防止数据库无限增大，您可以将数据库下载回本地用Access2000或更高版本压缩数据库。"
	Else
		if IsSqlDataBase=1 then
			sqldata_readme
		else
		if Action="Backup" or Action="BackupData" then
			call ShowBackup()
		elseif Action="Compact" or Action="CompactData" then
			call ShowCompact()
		elseif Action="Restore" or Action="RestoreData" then
			call ShowRestore()
		else
			call ShowCompact()
		end if	
		end if
	End if
	
%>
</div>
<%
sub ShowBackup()
showtit("备 份 数 据 库")  
if request("action")="BackupData" then
	showinfo(backupdata())
else
	dim dbname
	dbname = year(date()) & twonum(month(date())) & twonum(day(date())) & twonum(hour(now()))
%>
	<form method="post" action="admin_database.asp?action=BackupData">
		<p>备份目录：<input type="text" size="20" name="bkfolder" value="Databackup">
    相对路径目录，如目录不存在，将自动创建</p>
    <p>备份名称：<input type="text" size="20" name="bkDBname" value="<%=dbname%>">
    不用输入文件名后缀（默认为“.asa”）。如有同名文件，将覆盖</p>
    <p><input name="submit" type=submit value=" 开始备份 "></p>
	</form>        
<%end if
end sub

sub ShowCompact()
showtit("压 缩 数 据 库")  
if request("action")="CompactData" then
	showinfo(CompactDB(dbpath,false))	
else
%>
      <form method="post" action="admin_database.asp?action=CompactData">
      建议每隔一段时间，对数据库进行压缩操作。压缩前，请先备份数据库，以防止发生意外。
      <p>目前数据库大小：<%ShowFileInfo(WapLinkMdb)%>
      <p><input name="submit2" type="submit" value=" 压缩数据库 "> </p> 
      </form>
<%
end if
end sub

sub ShowRestore()
showtit("恢 复 数 据 库")  
if request("action")="RestoreData" then
	showinfo(RestoreData())
else
%>
		<form method="post" action="admin_database.asp?action=RestoreData">
        <p align="center">备份数据库路径（相对）：<input name="backpath" type="text" value="DataBackup\CuteLink.mdb" size=50 maxlength="200"></p>
        <p align="center"><input name="submit" type=submit value="恢复数据库"></p>        
		</form>
<%end if
end sub

sub sqldata_readme
showtit("SQL数据库数据处理说明")
%>
 			<blockquote>
<B>一、备份数据库</B>
<BR><BR>
1、打开SQL企业管理器，在控制台根目录中依次点开Microsoft SQL Server<BR>
2、SQL Server组-->双击打开你的服务器-->双击打开数据库目录<BR>
3、选择你的数据库名称（如数据库Link）-->然后点上面菜单中的工具-->选择备份数据库<BR>
4、备份选项选择完全备份，目的中的备份到如果原来有路径和名称则选中名称点删除，然后点添加，如果原来没有路径和名称则直接选择添加，接着指定路径和文件名，指定后点确定返回备份窗口，接着点确定进行备份
<BR><BR>
<B>二、还原数据库</B><BR><BR>
1、打开SQL企业管理器，在控制台根目录中依次点开Microsoft SQL Server<BR>
2、SQL Server组-->双击打开你的服务器-->点图标栏的新建数据库图标，新建数据库的名字自行取<BR>
3、点击新建好的数据库名称（如数据库Link）-->然后点上面菜单中的工具-->选择恢复数据库<BR>
4、在弹出来的窗口中的还原选项中选择从设备-->点选择设备-->点添加-->然后选择你的备份文件名-->添加后点确定返回，这时候设备栏应该出现您刚才选择的数据库备份文件名，备份号默认为1（如果您对同一个文件做过多次备份，可以点击备份号旁边的查看内容，在复选框中选择最新的一次备份后点确定）-->然后点击上方常规旁边的选项按钮<BR>
5、在出现的窗口中选择在现有数据库上强制还原，以及在恢复完成状态中选择使数据库可以继续运行但无法还原其它事务日志的选项。在窗口的中间部位的将数据库文件还原为这里要按照你SQL的安装进行设置（也可以指定自己的目录），逻辑文件名不需要改动，移至物理文件名要根据你所恢复的机器情况做改动，如您的SQL数据库装在D:\Program Files\Microsoft SQL Server\MSSQL\Data，那么就按照您恢复机器的目录进行相关改动改动，并且最后的文件名最好改成您当前的数据库名（如原来是link_data.mdf，现在的数据库是link2，就改成link2_data.mdf），日志和数据文件都要按照这样的方式做相关的改动（日志的文件名是*_log.ldf结尾的），这里的恢复目录您可以自由设置，前提是该目录必须存在（如您可以指定d:\sqldata\link_data.mdf或者d:\sqldata\link_log.ldf），否则恢复将报错<BR>
6、修改完成后，点击下面的确定进行恢复，这时会出现一个进度条，提示恢复的进度，恢复完成后系统会自动提示成功，如中间提示报错，请记录下相关的错误内容并询问对SQL操作比较熟悉的人员，一般的错误无非是目录错误或者文件名重复或者文件名错误或者空间不够或者数据库正在使用中的错误，数据库正在使用的错误您可以尝试关闭所有关于SQL窗口然后重新打开进行恢复操作，如果还提示正在使用的错误可以将SQL服务停止然后重起看看，至于上述其它的错误一般都能按照错误内容做相应改动后即可恢复<BR><BR>

<B>三、收缩数据库</B><BR><BR>
一般情况下，SQL数据库的收缩并不能很大程度上减小数据库大小，其主要作用是收缩日志大小，应当定期进行此操作以免数据库日志过大<BR>
1、设置数据库模式为简单模式：打开SQL企业管理器，在控制台根目录中依次点开Microsoft SQL Server-->SQL Server组-->双击打开你的服务器-->双击打开数据库目录-->选择你的数据库名称（如数据库Link）-->然后点击右键选择属性-->选择选项-->在故障还原的模式中选择“简单”，然后按确定保存<BR>
2、在当前数据库上点右键，看所有任务中的收缩数据库，一般里面的默认设置不用调整，直接点确定<BR>
3、<font color="blue">收缩数据库完成后，建议将您的数据库属性重新设置为标准模式，操作方法同第一点，因为日志在一些异常情况下往往是恢复数据库的重要依据</font>
<BR><BR>

<B>四、设定每日自动备份数据库</B><BR><BR>
<font color="red">强烈建议有条件的用户进行此操作！</font><BR>
1、打开企业管理器，在控制台根目录中依次点开Microsoft SQL Server-->SQL Server组-->双击打开你的服务器<BR>
2、然后点上面菜单中的工具-->选择数据库维护计划器<BR>
3、下一步选择要进行自动备份的数据-->下一步更新数据优化信息，这里一般不用做选择-->下一步检查数据完整性，也一般不选择<BR>
4、下一步指定数据库维护计划，默认的是1周备份一次，点击更改选择每天备份后点确定<BR>
5、下一步指定备份的磁盘目录，选择指定目录，如您可以在D盘新建一个目录如：d:\databak，然后在这里选择使用此目录，如果您的数据库比较多最好选择为每个数据库建立子目录，然后选择删除早于多少天前的备份，一般设定4－7天，这看您的具体备份要求，备份文件扩展名一般都是bak就用默认的<BR>
6、下一步指定事务日志备份计划，看您的需要做选择-->下一步要生成的报表，一般不做选择-->下一步维护计划历史记录，最好用默认的选项-->下一步完成<BR>
7、完成后系统很可能会提示Sql Server Agent服务未启动，先点确定完成计划设定，然后找到桌面最右边状态栏中的SQL绿色图标，双击点开，在服务中选择Sql Server Agent，然后点击运行箭头，选上下方的当启动OS时自动启动服务<BR>
8、这个时候数据库计划已经成功的运行了，他将按照您上面的设置进行自动备份
<BR><BR>
修改计划：<BR>
1、打开企业管理器，在控制台根目录中依次点开Microsoft SQL Server-->SQL Server组-->双击打开你的服务器-->管理-->数据库维护计划-->打开后可看到你设定的计划，可以进行修改或者删除操作
<BR><BR>
<B>五、数据的转移（新建数据库或转移服务器）</B><BR><BR>
一般情况下，最好使用备份和还原操作来进行转移数据，在特殊情况下，可以用导入导出的方式进行转移，这里介绍的就是导入导出方式，导入导出方式转移数据一个作用就是可以在收缩数据库无效的情况下用来减小（收缩）数据库的大小，本操作默认为您对SQL的操作有一定的了解，如果对其中的部分操作不理解，可以咨询动网相关人员或者查询网上资料<BR>
1、将原数据库的所有表、存储过程导出成一个SQL文件，导出的时候注意在选项中选择编写索引脚本和编写主键、外键、默认值和检查约束脚本选项<BR>
2、新建数据库，对新建数据库执行第一步中所建立的SQL文件<BR>
3、用SQL的导入导出方式，对新数据库导入原数据库中的所有表内容<BR>
<p>此篇文章选自 动网论坛，itlearner略做修改。</p>
 			</blockquote> 	
<%end sub%>
</body>
</html>
<%

sub showtit(str)
	response.write "<p align=""center"">"&str&"</p>"
end sub
sub showinfo(str)
	response.write "<p><font color=""#FF0000"">" & str & "</font></p>"
end sub
Function BackupData()
	dim bkfolder,bkdbname,fso
	bkfolder=trim(request("bkfolder"))
	bkdbname=trim(request("bkdbname"))
	if bkfolder="" then
		BackupData = "请指定备份目录！"
		exit Function
	end if
	if bkdbname="" then
		FoundErr=True
		BackupData = "请指定备份文件名"
		exit Function
	end if
	bkfolder=server.MapPath(bkfolder)
	Set Fso=server.createobject(Objfso)
	if fso.FileExists(dbpath) then
		If fso.FolderExists(bkfolder)=false Then
			fso.CreateFolder(bkfolder)
		end if
		fso.copyfile dbpath,bkfolder & "\" & bkdbname & ".asa"
		BackupData = "备份数据库成功，备份的数据库为 " & bkfolder & "\" & bkdbname & ".asa"
	Else
		BackupData = "找不到源数据库文件，请检查config.asp中的配置。"
	End if
End Function



'=====================压缩参数=========================
Function CompactDB(dbPath, boolIs97)
	On Error Resume Next
	Dim fso, Engine, strDBPath,JET_3X
	strDBPath = left(dbPath,instrrev(DBPath,"\"))
	Set fso = CreateObject(Objfso)
	If Err Then
		Err.Clear
		CompactDB = "您当前操作的目录不支持FSO，请手动进行压缩数据库操作!" & vbCrLf
		Exit Function
	End If
	If fso.FileExists(dbPath) Then
		fso.CopyFile dbpath,strDBPath & "temp.mdb"
		Set Engine = CreateObject("JRO.JetEngine")
		If boolIs97 = "True" Then
			Engine.CompactDatabase "Provider=Microsoft.Jet.OLEDB.4.0;Data Source=" & strDBPath & "temp.mdb", _
			"Provider=Microsoft.Jet.OLEDB.4.0;Data Source=" & strDBPath & "temp1.mdb;" _
			& "Jet OLEDB:Engine Type=" & JET_3X
		Else
			Engine.CompactDatabase "Provider=Microsoft.Jet.OLEDB.4.0;Data Source=" & strDBPath & "temp.mdb", _
			"Provider=Microsoft.Jet.OLEDB.4.0;Data Source=" & strDBPath & "temp1.mdb"
		End If

		fso.CopyFile strDBPath & "temp1.mdb",dbpath
		fso.DeleteFile(strDBPath & "temp.mdb")
		fso.DeleteFile(strDBPath & "temp1.mdb")
		Set fso = Nothing
		Set Engine = Nothing
		CompactDB = "你的数据库, " & dbpath & ", 已经压缩成功!" & vbCrLf
	Else
		CompactDB = "数据库名称或路径不正确. 请重试!" & vbCrLf
	End If
End Function

Function RestoreData()
	dim backpath,fso
	backpath=request.form("backpath")
	if backpath="" then
		RestoreData = "请指定原备份的数据库文件名！"
		exit Function	
	end if
	backpath=server.mappath(backpath)
	Set Fso=server.createobject(Objfso)
	if fso.fileexists(backpath) then  					
		fso.copyfile Backpath,Dbpath
		RestoreData = "成功恢复数据！"
	else
		RestoreData = "找不到指定的备份文件！"	
	end if
End Function

Sub ShowFileInfo(filespec)
    Dim fs, f, s, showsize
    Set fs = Server.CreateObject(Objfso)
    Set f = fs.GetFile(server.mappath(filespec))
    s = f.size
	if s>1024*1024 then
		showsize=formatnumber(s/1024/1024,2) & "&nbsp;MB"
	elseif s>1024 then
		showsize=formatnumber(s/1024,2) & "&nbsp;KB"
	else
		showsize=s & "&nbsp;Byte" 				
	end if
	response.write "<font face=""verdana"">" & showsize & "</font>"
End Sub 	

'检查组件是否已经安装
Function IsObjInstalled(ClassString)
	On Error Resume Next
	IsObjInstalled = False
	Err = 0
	Dim TestObj
	Set TestObj = Server.CreateObject(ClassString)
	If 0 = Err Then IsObjInstalled = True
	Set TestObj = Nothing
	Err = 0
End Function

Function twonum(num)
	if len(num)=1 then
		twonum="0"&num
	else
		twonum=num
	end if
End Function

%>

⌨️ 快捷键说明

复制代码 Ctrl + C
搜索代码 Ctrl + F
全屏模式 F11
切换主题 Ctrl + Shift + D
显示快捷键 ?
增大字号 Ctrl + =
减小字号 Ctrl + -