se3208_rom.vct

ADC图形图像例子

OUTPUT_FORMAT("elf32-se3208", "elf32-se3208", "elf32-se3208")
OUTPUT_ARCH(se3208)

ENTRY(_start)

GROUP(-lc -lgcc)

/* STARTUP(crt0.o) */

SEARCH_DIR(/usr/local/se3208-elf/lib);

/* Do we need any of these for elf? */

/* __DYNAMIC = 0; */

MEMORY
{
	rom : ORIGIN = 0x0,         LENGTH = 1M
	ram : ORIGIN = 0x02010000,  LENGTH = 0x7F0000
}

SECTIONS
{
  /* Read-only sections, merged into text segment: */
  . = 0x0;
  .text :
  {
    *(.vects)
    . = 0x140;
    *(.sfvects)
    . = 0x200;
    *(.smartdata)
    *(.text)
    *(.stub)
    *(.rodata)
    *(.rodata1)
    ___ctors = . ;
    *(.ctors)
    ___ctors_end = . ;
    ___dtors = . ;
    *(.dtors)
    ___dtors_end = . ;
    _etext = . ;
    ___shadow_data = . ;
  } > rom
  PROVIDE (etext = .);
  PROVIDE (___shadow_data = . );
  _erodata = .;
  _data = .;   
  .data :
  AT ( ADDR (.text) + SIZEOF(.text) )
  {
    _data_reload = . ;
    PROVIDE(___data_reload = . );
    *(.data)
    *(.sdata)
    CONSTRUCTORS
  } > ram
  _edata  =  .;
  PROVIDE (edata = .);
  .bss (NOLOAD) :
  {
   __bss_start = .;
   *(.dynbss)
   *(.bss)
   *(COMMON)
  } > ram
  _end = . ;
  PROVIDE (end = .);
  /* Stabs debugging sections.  */
  .stab 0 : { *(.stab) }
  .stabstr 0 : { *(.stabstr) }
  .stab.excl 0 : { *(.stab.excl) }
  .stab.exclstr 0 : { *(.stab.exclstr) }
  .stab.index 0 : { *(.stab.index) }
  .stab.indexstr 0 : { *(.stab.indexstr) }
  .comment 0 : { *(.comment) }
  /* DWARF debug sections.
     Symbols in the DWARF debugging sections are relative to the beginning
     of the section so we begin them at 0.  */
  /* DWARF 1 */
  .debug          0 : { *(.debug) }
  .line           0 : { *(.line) }
  /* GNU DWARF 1 extensions */
  .debug_srcinfo  0 : { *(.debug_srcinfo) }
  .debug_sfnames  0 : { *(.debug_sfnames) }
  /* DWARF 1.1 and DWARF 2 */
  .debug_aranges  0 : { *(.debug_aranges) }
  .debug_pubnames 0 : { *(.debug_pubnames) }
  /* DWARF 2 */
  .debug_info     0 : { *(.debug_info) }
  .debug_abbrev   0 : { *(.debug_abbrev) }
  .debug_line     0 : { *(.debug_line) }
  .debug_frame    0 : { *(.debug_frame) }
  .debug_str      0 : { *(.debug_str) }
  .debug_loc      0 : { *(.debug_loc) }
  .debug_macinfo  0 : { *(.debug_macinfo) }
  /* SGI/MIPS DWARF 2 extensions */
  .debug_weaknames 0 : { *(.debug_weaknames) }
  .debug_funcnames 0 : { *(.debug_funcnames) }
  .debug_typenames 0 : { *(.debug_typenames) }
  .debug_varnames  0 : { *(.debug_varnames) }
  /* These must appear regardless of  .  */
  .stack 0x027ffff0 : { _stack = .; *(.stack) }
}
PROVIDE(___data_size = SIZEOF(.data));