nb_kernel113_x86_64_sse.s

来自「最著名最快的分子模拟软件」· S 代码 · 共 1,821 行 · 第 1/4 页

    mulps  %xmm3,%xmm4      ## rinv6
    movaps %xmm4,%xmm5
    mulps  %xmm5,%xmm5      ## rinv12
    mulps  nb113_c6(%rsp),%xmm4
    mulps  nb113_c12(%rsp),%xmm5
    movaps %xmm5,%xmm6
    subps  %xmm4,%xmm6 ## Vvdw=vvdw12-vvdw6
    mulps  nb113_six(%rsp),%xmm4
    mulps  nb113_twelve(%rsp),%xmm5
    subps  %xmm4,%xmm5
    mulps  %xmm5,%xmm3  ## fscal

    addps  nb113_Vvdwtot(%rsp),%xmm6
    movaps %xmm6,nb113_Vvdwtot(%rsp)

    mulps  %xmm3,%xmm13 ## fx
    mulps  %xmm3,%xmm14 ## fy
    mulps  %xmm3,%xmm15 ## fz

    ## save j force temporarily
    movaps %xmm13,nb113_fjx(%rsp)
    movaps %xmm14,nb113_fjy(%rsp)
    movaps %xmm15,nb113_fjz(%rsp)

    ## increment i O force
    addps nb113_fixO(%rsp),%xmm13
    addps nb113_fiyO(%rsp),%xmm14
    addps nb113_fizO(%rsp),%xmm15
    movaps %xmm13,nb113_fixO(%rsp)
    movaps %xmm14,nb113_fiyO(%rsp)
    movaps %xmm15,nb113_fizO(%rsp)
    ## finished O LJ interaction.


    ## do H1, H2, and M interactions in parallel.
    ## xmm0-xmm2 still contain j coordinates.
    movaps %xmm0,%xmm3
    movaps %xmm1,%xmm4
    movaps %xmm2,%xmm5
    movaps %xmm0,%xmm6
    movaps %xmm1,%xmm7
    movaps %xmm2,%xmm8


    subps nb113_ixH1(%rsp),%xmm0
    subps nb113_iyH1(%rsp),%xmm1
    subps nb113_izH1(%rsp),%xmm2
    subps nb113_ixH2(%rsp),%xmm3
    subps nb113_iyH2(%rsp),%xmm4
    subps nb113_izH2(%rsp),%xmm5
    subps nb113_ixM(%rsp),%xmm6
    subps nb113_iyM(%rsp),%xmm7
    subps nb113_izM(%rsp),%xmm8

        movaps %xmm0,nb113_dxH1(%rsp)
        movaps %xmm1,nb113_dyH1(%rsp)
        movaps %xmm2,nb113_dzH1(%rsp)
        mulps  %xmm0,%xmm0
        mulps  %xmm1,%xmm1
        mulps  %xmm2,%xmm2
        movaps %xmm3,nb113_dxH2(%rsp)
        movaps %xmm4,nb113_dyH2(%rsp)
        movaps %xmm5,nb113_dzH2(%rsp)
        mulps  %xmm3,%xmm3
        mulps  %xmm4,%xmm4
        mulps  %xmm5,%xmm5
        movaps %xmm6,nb113_dxM(%rsp)
        movaps %xmm7,nb113_dyM(%rsp)
        movaps %xmm8,nb113_dzM(%rsp)
        mulps  %xmm6,%xmm6
        mulps  %xmm7,%xmm7
        mulps  %xmm8,%xmm8
        addps  %xmm1,%xmm0
        addps  %xmm2,%xmm0
        addps  %xmm4,%xmm3
        addps  %xmm5,%xmm3
    addps  %xmm7,%xmm6
    addps  %xmm8,%xmm6

        ## start doing invsqrt for j atoms
        rsqrtps %xmm0,%xmm1
        rsqrtps %xmm3,%xmm4
    rsqrtps %xmm6,%xmm7

        movaps  %xmm1,%xmm2
        movaps  %xmm4,%xmm5
    movaps  %xmm7,%xmm8

        mulps   %xmm1,%xmm1 ## lu*lu
        mulps   %xmm4,%xmm4 ## lu*lu
    mulps   %xmm7,%xmm7 ## lu*lu

        movaps  nb113_three(%rsp),%xmm9
        movaps  %xmm9,%xmm10
    movaps  %xmm9,%xmm11

        mulps   %xmm0,%xmm1 ## rsq*lu*lu
        mulps   %xmm3,%xmm4 ## rsq*lu*lu 
    mulps   %xmm6,%xmm7 ## rsq*lu*lu

        subps   %xmm1,%xmm9
        subps   %xmm4,%xmm10
    subps   %xmm7,%xmm11 ## 3-rsq*lu*lu

        mulps   %xmm2,%xmm9
        mulps   %xmm5,%xmm10
    mulps   %xmm8,%xmm11 ## lu*(3-rsq*lu*lu)

        movaps  nb113_half(%rsp),%xmm0
        mulps   %xmm0,%xmm9 ## rinvH1
        mulps   %xmm0,%xmm10 ## rinvH2
    mulps   %xmm0,%xmm11 ## rinvM

        ## interactions 
    movaps %xmm9,%xmm0
    movaps %xmm10,%xmm1
    movaps %xmm11,%xmm2
    mulps  %xmm9,%xmm9
    mulps  %xmm10,%xmm10
    mulps  %xmm11,%xmm11
    mulps  nb113_qqH(%rsp),%xmm0
    mulps  nb113_qqH(%rsp),%xmm1
    mulps  nb113_qqM(%rsp),%xmm2
    mulps  %xmm0,%xmm9
    mulps  %xmm1,%xmm10
    mulps  %xmm2,%xmm11

    addps nb113_vctot(%rsp),%xmm0
    addps %xmm2,%xmm1
    addps %xmm1,%xmm0
    movaps %xmm0,nb113_vctot(%rsp)

        movq  nb113_faction(%rbp),%rdi
        ## move j forces to local temp variables 
    movlps (%rdi,%rax,4),%xmm0 ## jxa jya  -   -
    movlps (%rdi,%rcx,4),%xmm1 ## jxc jyc  -   -
    movhps (%rdi,%rbx,4),%xmm0 ## jxa jya jxb jyb 
    movhps (%rdi,%rdx,4),%xmm1 ## jxc jyc jxd jyd 

    movss  8(%rdi,%rax,4),%xmm2    ## jza  -  -  -
    movss  8(%rdi,%rcx,4),%xmm3    ## jzc  -  -  -
    movss  8(%rdi,%rbx,4),%xmm4    ## jzb
    movss  8(%rdi,%rdx,4),%xmm5    ## jzd
    movlhps %xmm4,%xmm2 ## jza  -  jzb  -
    movlhps %xmm5,%xmm3 ## jzc  -  jzd -

    shufps $136,%xmm3,%xmm2 ## 10001000 => jza jzb jzc jzd

    ## xmm0: jxa jya jxb jyb 
    ## xmm1: jxc jyc jxd jyd
    ## xmm2: jza jzb jzc jzd

    movaps %xmm9,%xmm7
    movaps %xmm9,%xmm8
    movaps %xmm11,%xmm13
    movaps %xmm11,%xmm14
    movaps %xmm11,%xmm15
    movaps %xmm10,%xmm11
    movaps %xmm10,%xmm12

        mulps nb113_dxH1(%rsp),%xmm7
        mulps nb113_dyH1(%rsp),%xmm8
        mulps nb113_dzH1(%rsp),%xmm9
        mulps nb113_dxH2(%rsp),%xmm10
        mulps nb113_dyH2(%rsp),%xmm11
        mulps nb113_dzH2(%rsp),%xmm12
        mulps nb113_dxM(%rsp),%xmm13
        mulps nb113_dyM(%rsp),%xmm14
        mulps nb113_dzM(%rsp),%xmm15

    ## fetch forces from O interaction
    movaps nb113_fjx(%rsp),%xmm3
    movaps nb113_fjy(%rsp),%xmm4
    addps  nb113_fjz(%rsp),%xmm2

    addps %xmm7,%xmm3
    addps %xmm8,%xmm4
    addps %xmm9,%xmm2
    addps nb113_fixH1(%rsp),%xmm7
    addps nb113_fiyH1(%rsp),%xmm8
    addps nb113_fizH1(%rsp),%xmm9

    addps %xmm10,%xmm3
    addps %xmm11,%xmm4
    addps %xmm12,%xmm2
    addps nb113_fixH2(%rsp),%xmm10
    addps nb113_fiyH2(%rsp),%xmm11
    addps nb113_fizH2(%rsp),%xmm12

    addps %xmm13,%xmm3
    addps %xmm14,%xmm4
    addps %xmm15,%xmm2
    addps nb113_fixM(%rsp),%xmm13
    addps nb113_fiyM(%rsp),%xmm14
    addps nb113_fizM(%rsp),%xmm15

    movaps %xmm7,nb113_fixH1(%rsp)
    movaps %xmm8,nb113_fiyH1(%rsp)
    movaps %xmm9,nb113_fizH1(%rsp)
    movaps %xmm10,nb113_fixH2(%rsp)
    movaps %xmm11,nb113_fiyH2(%rsp)
    movaps %xmm12,nb113_fizH2(%rsp)
    movaps %xmm13,nb113_fixM(%rsp)
    movaps %xmm14,nb113_fiyM(%rsp)
    movaps %xmm15,nb113_fizM(%rsp)

    ## xmm3 = fjx , xmm4 = fjy
    movaps %xmm3,%xmm5
    unpcklps %xmm4,%xmm3
    unpckhps %xmm4,%xmm5

    addps %xmm3,%xmm0
    addps %xmm5,%xmm1

    movhlps  %xmm2,%xmm3 ## fjzc fjzd

    movlps %xmm0,(%rdi,%rax,4)
    movhps %xmm0,(%rdi,%rbx,4)
    movlps %xmm1,(%rdi,%rcx,4)
    movhps %xmm1,(%rdi,%rdx,4)
    movss  %xmm2,8(%rdi,%rax,4)
    movss  %xmm3,8(%rdi,%rcx,4)
    shufps $1,%xmm2,%xmm2
    shufps $1,%xmm3,%xmm3
    movss  %xmm2,8(%rdi,%rbx,4)
    movss  %xmm3,8(%rdi,%rdx,4)

        ## should we do one more iteration? 
        subl $4,nb113_innerk(%rsp)
        jl    _nb_kernel113_x86_64_sse.nb113_odd_inner
        jmp   _nb_kernel113_x86_64_sse.nb113_unroll_loop
_nb_kernel113_x86_64_sse.nb113_odd_inner: 
        addl $4,nb113_innerk(%rsp)
        jnz   _nb_kernel113_x86_64_sse.nb113_odd_loop
        jmp   _nb_kernel113_x86_64_sse.nb113_updateouterdata
_nb_kernel113_x86_64_sse.nb113_odd_loop: 
        movq  nb113_innerjjnr(%rsp),%rdx        ## pointer to jjnr[k] 
        movl  (%rdx),%eax
        addq $4,nb113_innerjjnr(%rsp)

        xorps %xmm4,%xmm4       ## clear reg.
        movss nb113_iqM(%rsp),%xmm4
        movq nb113_charge(%rbp),%rsi
        movhps nb113_iqH(%rsp),%xmm4    ## [qM  0  qH  qH] 
        shufps $41,%xmm4,%xmm4 ## [0 qH qH qM]

        movss (%rsi,%rax,4),%xmm3       ## charge in xmm3 
        shufps $0,%xmm3,%xmm3
        mulps %xmm4,%xmm3
        movaps %xmm3,nb113_qqM(%rsp)    ## use dummy qq for storage 

        xorps %xmm6,%xmm6
        movq nb113_type(%rbp),%rsi
        movl (%rsi,%rax,4),%ebx
        movq nb113_vdwparam(%rbp),%rsi
        shll %ebx
        addl nb113_ntia(%rsp),%ebx
        movlps (%rsi,%rbx,4),%xmm6
        movaps %xmm6,%xmm7
        shufps $252,%xmm6,%xmm6 ## 11111100
        shufps $253,%xmm7,%xmm7 ## 11111101
        movaps %xmm6,nb113_c6(%rsp)
        movaps %xmm7,nb113_c12(%rsp)

        movq nb113_pos(%rbp),%rsi
        lea    (%rax,%rax,2),%rax

        movss nb113_ixO(%rsp),%xmm0
        movss nb113_iyO(%rsp),%xmm1
        movss nb113_izO(%rsp),%xmm2
        movss nb113_ixH1(%rsp),%xmm3
        movss nb113_iyH1(%rsp),%xmm4
        movss nb113_izH1(%rsp),%xmm5
        unpcklps nb113_ixH2(%rsp),%xmm0         ## ixO ixH2 - -
        unpcklps nb113_iyH2(%rsp),%xmm1         ## iyO iyH2 - -
        unpcklps nb113_izH2(%rsp),%xmm2         ## izO izH2 - -
        unpcklps nb113_ixM(%rsp),%xmm3          ## ixH1 ixM - -
        unpcklps nb113_iyM(%rsp),%xmm4          ## iyH1 iyM - -
        unpcklps nb113_izM(%rsp),%xmm5          ## izH1 izM - -
        unpcklps %xmm3,%xmm0    ## ixO ixH1 ixH2 ixM
        unpcklps %xmm4,%xmm1    ## same for y
        unpcklps %xmm5,%xmm2    ## same for z

        ## move j coords to xmm0-xmm2 
        movss (%rsi,%rax,4),%xmm3
        movss 4(%rsi,%rax,4),%xmm4
        movss 8(%rsi,%rax,4),%xmm5
        shufps $0,%xmm3,%xmm3
        shufps $0,%xmm4,%xmm4
        shufps $0,%xmm5,%xmm5

        subps %xmm0,%xmm3
        subps %xmm1,%xmm4
        subps %xmm2,%xmm5

        ## use O distances for storage
        movaps %xmm3,nb113_dxO(%rsp)
        movaps %xmm4,nb113_dyO(%rsp)
        movaps %xmm5,nb113_dzO(%rsp)

        mulps  %xmm3,%xmm3
        mulps  %xmm4,%xmm4
        mulps  %xmm5,%xmm5

        addps  %xmm3,%xmm4
        addps  %xmm5,%xmm4
        ## rsq in xmm4 

        rsqrtps %xmm4,%xmm5
        ## lookup seed in xmm5 
        movaps %xmm5,%xmm2
        mulps %xmm5,%xmm5
        movaps nb113_three(%rsp),%xmm1
        mulps %xmm4,%xmm5       ## rsq*lu*lu                    
        movaps nb113_half(%rsp),%xmm0
        subps %xmm5,%xmm1       ## 30-rsq*lu*lu 
        mulps %xmm2,%xmm1
        mulps %xmm1,%xmm0       ## xmm0=rinv

        movaps %xmm0,%xmm1
        mulps %xmm1,%xmm1       ## rinvsq 
        movaps %xmm0,%xmm7
        mulps  nb113_qqM(%rsp),%xmm7   ## vcoul
        movaps %xmm7,%xmm6

        addps  nb113_vctot(%rsp),%xmm7
        movaps %xmm7,nb113_vctot(%rsp)

        movaps %xmm1,%xmm2
        mulss  %xmm1,%xmm1
        mulss  %xmm2,%xmm1      ## xmm1=rinvsix
        xorps  %xmm4,%xmm4
        movss  %xmm1,%xmm4
        mulss  %xmm4,%xmm4      ## xmm4=rinvtwelve 
        mulss  nb113_c6(%rsp),%xmm1
        mulss  nb113_c12(%rsp),%xmm4
        movaps %xmm4,%xmm3
        subss  %xmm1,%xmm3      ## xmm3=Vvdw12-Vvdw6 
        mulss  nb113_six(%rsp),%xmm1
        mulss  nb113_twelve(%rsp),%xmm4
        subss  %xmm1,%xmm4
        addss  nb113_Vvdwtot(%rsp),%xmm3
        movss  %xmm3,nb113_Vvdwtot(%rsp)
        addps  %xmm6,%xmm4
        mulps  %xmm0,%xmm4
        mulps  %xmm0,%xmm4      ## fscal

        movaps nb113_dxO(%rsp),%xmm0
        movaps nb113_dyO(%rsp),%xmm1
        movaps nb113_dzO(%rsp),%xmm2

        mulps  %xmm4,%xmm0
        mulps  %xmm4,%xmm1
        mulps  %xmm4,%xmm2 ## xmm0-xmm2 now contains tx-tz (partial force)

        movss  nb113_fixO(%rsp),%xmm3
        movss  nb113_fiyO(%rsp),%xmm4
        movss  nb113_fizO(%rsp),%xmm5
        addss  %xmm0,%xmm3
        addss  %xmm1,%xmm4
        addss  %xmm2,%xmm5
        movss  %xmm3,nb113_fixO(%rsp)
        movss  %xmm4,nb113_fiyO(%rsp)
        movss  %xmm5,nb113_fizO(%rsp)   ## updated the O force now do the H's

        movaps %xmm0,%xmm3
        movaps %xmm1,%xmm4
        movaps %xmm2,%xmm5
        shufps $0x39,%xmm3,%xmm3 ## shift right 
        shufps $0x39,%xmm4,%xmm4
        shufps $0x39,%xmm5,%xmm5
        addss  nb113_fixH1(%rsp),%xmm3
        addss  nb113_fiyH1(%rsp),%xmm4
        addss  nb113_fizH1(%rsp),%xmm5
        movss  %xmm3,nb113_fixH1(%rsp)
        movss  %xmm4,nb113_fiyH1(%rsp)
        movss  %xmm5,nb113_fizH1(%rsp)          ## updated the H1 force 

        shufps $0x39,%xmm3,%xmm3
        shufps $0x39,%xmm4,%xmm4
        shufps $0x39,%xmm5,%xmm5
        addss  nb113_fixH2(%rsp),%xmm3
        addss  nb113_fiyH2(%rsp),%xmm4
        addss  nb113_fizH2(%rsp),%xmm5
        movss  %xmm3,nb113_fixH2(%rsp)
        movss  %xmm4,nb113_fiyH2(%rsp)
        movss  %xmm5,nb113_fizH2(%rsp)          ## updated the H2 force 

        movq nb113_faction(%rbp),%rdi
        shufps $0x39,%xmm3,%xmm3
        shufps $0x39,%xmm4,%xmm4
        shufps $0x39,%xmm5,%xmm5
        addss  nb113_fixM(%rsp),%xmm3
        addss  nb113_fiyM(%rsp),%xmm4
        addss  nb113_fizM(%rsp),%xmm5
        movss  %xmm3,nb113_fixM(%rsp)
        movss  %xmm4,nb113_fiyM(%rsp)
        movss  %xmm5,nb113_fizM(%rsp)   ## updated the M force 

        ## the fj's - move in from mem start by acc. tx/ty/tz in xmm0, xmm1
        movlps (%rdi,%rax,4),%xmm6
        movss  8(%rdi,%rax,4),%xmm7

        movhlps %xmm0,%xmm3
        movhlps %xmm1,%xmm4
        movhlps %xmm2,%xmm5
        addps   %xmm0,%xmm3
        addps   %xmm1,%xmm4
        addps   %xmm2,%xmm5
        movaps  %xmm3,%xmm0
        movaps  %xmm4,%xmm1
        movaps  %xmm5,%xmm2

        shufps $0x39,%xmm3,%xmm3 ## shift right 
        shufps $0x39,%xmm4,%xmm4
        shufps $0x39,%xmm5,%xmm5
        addss  %xmm3,%xmm0
        addss  %xmm4,%xmm1
        addss  %xmm5,%xmm2
        unpcklps %xmm1,%xmm0    ## x,y sum in xmm0, z sum in xmm2

        addps    %xmm0,%xmm6
        addss    %xmm2,%xmm7

        movlps %xmm6,(%rdi,%rax,4)
        movss  %xmm7,8(%rdi,%rax,4)

        decl nb113_innerk(%rsp)
        jz    _nb_kernel113_x86_64_sse.nb113_updateouterdata
        jmp   _nb_kernel113_x86_64_sse.nb113_odd_loop
_nb_kernel113_x86_64_sse.nb113_updateouterdata: 
        movl  nb113_ii3(%rsp),%ecx
        movq  nb113_faction(%rbp),%rdi
        movq  nb113_fshift(%rbp),%rsi
        movl  nb113_is3(%rsp),%edx

        ## accumulate  Oi forces in xmm0, xmm1, xmm2 
        movaps nb113_fixO(%rsp),%xmm0
        movaps nb113_fiyO(%rsp),%xmm1
        movaps nb113_fizO(%rsp),%xmm2

        movhlps %xmm0,%xmm3
        movhlps %xmm1,%xmm4
        movhlps %xmm2,%xmm5
        addps  %xmm3,%xmm0
        addps  %xmm4,%xmm1
        addps  %xmm5,%xmm2 ## sum is in 1/2 in xmm0-xmm2 

        movaps %xmm0,%xmm3
        movaps %xmm1,%xmm4
        movaps %xmm2,%xmm5

        shufps $1,%xmm3,%xmm3
        shufps $1,%xmm4,%xmm4
        shufps $1,%xmm5,%xmm5
        addss  %xmm3,%xmm0