nb_kernel113_x86_64_sse.s

来自「最著名最快的分子模拟软件」· S 代码 · 共 1,821 行 · 第 1/4 页

        addss  %xmm4,%xmm1
        addss  %xmm5,%xmm2      ## xmm0-xmm2 has single force in pos0 

        ## increment i force 
        movss  (%rdi,%rcx,4),%xmm3
        movss  4(%rdi,%rcx,4),%xmm4
        movss  8(%rdi,%rcx,4),%xmm5
        subss  %xmm0,%xmm3
        subss  %xmm1,%xmm4
        subss  %xmm2,%xmm5
        movss  %xmm3,(%rdi,%rcx,4)
        movss  %xmm4,4(%rdi,%rcx,4)
        movss  %xmm5,8(%rdi,%rcx,4)

        ## accumulate force in xmm6/xmm7 for fshift 
        movaps %xmm0,%xmm6
        movss %xmm2,%xmm7
        movlhps %xmm1,%xmm6
        shufps $8,%xmm6,%xmm6 ## 00001000       

        ## accumulate H1i forces in xmm0, xmm1, xmm2 
        movaps nb113_fixH1(%rsp),%xmm0
        movaps nb113_fiyH1(%rsp),%xmm1
        movaps nb113_fizH1(%rsp),%xmm2

        movhlps %xmm0,%xmm3
        movhlps %xmm1,%xmm4
        movhlps %xmm2,%xmm5
        addps  %xmm3,%xmm0
        addps  %xmm4,%xmm1
        addps  %xmm5,%xmm2 ## sum is in 1/2 in xmm0-xmm2 

        movaps %xmm0,%xmm3
        movaps %xmm1,%xmm4
        movaps %xmm2,%xmm5

        shufps $1,%xmm3,%xmm3
        shufps $1,%xmm4,%xmm4
        shufps $1,%xmm5,%xmm5
        addss  %xmm3,%xmm0
        addss  %xmm4,%xmm1
        addss  %xmm5,%xmm2      ## xmm0-xmm2 has single force in pos0 

        ## increment i force 
        movss  12(%rdi,%rcx,4),%xmm3
        movss  16(%rdi,%rcx,4),%xmm4
        movss  20(%rdi,%rcx,4),%xmm5
        subss  %xmm0,%xmm3
        subss  %xmm1,%xmm4
        subss  %xmm2,%xmm5
        movss  %xmm3,12(%rdi,%rcx,4)
        movss  %xmm4,16(%rdi,%rcx,4)
        movss  %xmm5,20(%rdi,%rcx,4)

        ## accumulate force in xmm6/xmm7 for fshift 
        addss %xmm2,%xmm7
        movlhps %xmm1,%xmm0
        shufps $8,%xmm0,%xmm0 ## 00001000       
        addps   %xmm0,%xmm6

        ## accumulate H2i forces in xmm0, xmm1, xmm2 
        movaps nb113_fixH2(%rsp),%xmm0
        movaps nb113_fiyH2(%rsp),%xmm1
        movaps nb113_fizH2(%rsp),%xmm2

        movhlps %xmm0,%xmm3
        movhlps %xmm1,%xmm4
        movhlps %xmm2,%xmm5
        addps  %xmm3,%xmm0
        addps  %xmm4,%xmm1
        addps  %xmm5,%xmm2 ## sum is in 1/2 in xmm0-xmm2 

        movaps %xmm0,%xmm3
        movaps %xmm1,%xmm4
        movaps %xmm2,%xmm5

        shufps $1,%xmm3,%xmm3
        shufps $1,%xmm4,%xmm4
        shufps $1,%xmm5,%xmm5
        addss  %xmm3,%xmm0
        addss  %xmm4,%xmm1
        addss  %xmm5,%xmm2      ## xmm0-xmm2 has single force in pos0 

        ## increment i force 
        movss  24(%rdi,%rcx,4),%xmm3
        movss  28(%rdi,%rcx,4),%xmm4
        movss  32(%rdi,%rcx,4),%xmm5
        subss  %xmm0,%xmm3
        subss  %xmm1,%xmm4
        subss  %xmm2,%xmm5
        movss  %xmm3,24(%rdi,%rcx,4)
        movss  %xmm4,28(%rdi,%rcx,4)
        movss  %xmm5,32(%rdi,%rcx,4)

        ## accumulate force in xmm6/xmm7 for fshift 
        addss %xmm2,%xmm7
        movlhps %xmm1,%xmm0
        shufps $8,%xmm0,%xmm0 ## 00001000       
        addps   %xmm0,%xmm6

        ## accumulate Mi forces in xmm0, xmm1, xmm2 
        movaps nb113_fixM(%rsp),%xmm0
        movaps nb113_fiyM(%rsp),%xmm1
        movaps nb113_fizM(%rsp),%xmm2

        movhlps %xmm0,%xmm3
        movhlps %xmm1,%xmm4
        movhlps %xmm2,%xmm5
        addps  %xmm3,%xmm0
        addps  %xmm4,%xmm1
        addps  %xmm5,%xmm2 ## sum is in 1/2 in xmm0-xmm2 

        movaps %xmm0,%xmm3
        movaps %xmm1,%xmm4
        movaps %xmm2,%xmm5

        shufps $1,%xmm3,%xmm3
        shufps $1,%xmm4,%xmm4
        shufps $1,%xmm5,%xmm5
        addss  %xmm3,%xmm0
        addss  %xmm4,%xmm1
        addss  %xmm5,%xmm2      ## xmm0-xmm2 has single force in pos0 

        ## increment i force 
        movss  36(%rdi,%rcx,4),%xmm3
        movss  40(%rdi,%rcx,4),%xmm4
        movss  44(%rdi,%rcx,4),%xmm5
        subss  %xmm0,%xmm3
        subss  %xmm1,%xmm4
        subss  %xmm2,%xmm5
        movss  %xmm3,36(%rdi,%rcx,4)
        movss  %xmm4,40(%rdi,%rcx,4)
        movss  %xmm5,44(%rdi,%rcx,4)

        ## accumulate force in xmm6/xmm7 for fshift 
        addss %xmm2,%xmm7
        movlhps %xmm1,%xmm0
        shufps $8,%xmm0,%xmm0 ## 00001000       
        addps   %xmm0,%xmm6

        ## increment fshift force  
        movlps  (%rsi,%rdx,4),%xmm3
        movss  8(%rsi,%rdx,4),%xmm4
        subps  %xmm6,%xmm3
        subss  %xmm7,%xmm4
        movlps  %xmm3,(%rsi,%rdx,4)
        movss  %xmm4,8(%rsi,%rdx,4)

        ## get n from stack
        movl nb113_n(%rsp),%esi
        ## get group index for i particle 
        movq  nb113_gid(%rbp),%rdx              ## base of gid[]
        movl  (%rdx,%rsi,4),%edx                ## ggid=gid[n]

        ## accumulate total potential energy and update it 
        movaps nb113_vctot(%rsp),%xmm7
        ## accumulate 
        movhlps %xmm7,%xmm6
        addps  %xmm6,%xmm7      ## pos 0-1 in xmm7 have the sum now 
        movaps %xmm7,%xmm6
        shufps $1,%xmm6,%xmm6
        addss  %xmm6,%xmm7

        ## add earlier value from mem 
        movq  nb113_Vc(%rbp),%rax
        addss (%rax,%rdx,4),%xmm7
        ## move back to mem 
        movss %xmm7,(%rax,%rdx,4)

        ## accumulate total lj energy and update it 
        movaps nb113_Vvdwtot(%rsp),%xmm7
        ## accumulate 
        movhlps %xmm7,%xmm6
        addps  %xmm6,%xmm7      ## pos 0-1 in xmm7 have the sum now 
        movaps %xmm7,%xmm6
        shufps $1,%xmm6,%xmm6
        addss  %xmm6,%xmm7

        ## add earlier value from mem 
        movq  nb113_Vvdw(%rbp),%rax
        addss (%rax,%rdx,4),%xmm7
        ## move back to mem 
        movss %xmm7,(%rax,%rdx,4)

        ## finish if last 
        movl nb113_nn1(%rsp),%ecx
        ## esi already loaded with n
        incl %esi
        subl %esi,%ecx
        jz _nb_kernel113_x86_64_sse.nb113_outerend

        ## not last, iterate outer loop once more!  
        movl %esi,nb113_n(%rsp)
        jmp _nb_kernel113_x86_64_sse.nb113_outer
_nb_kernel113_x86_64_sse.nb113_outerend: 
        ## check if more outer neighborlists remain
        movl  nb113_nri(%rsp),%ecx
        ## esi already loaded with n above
        subl  %esi,%ecx
        jz _nb_kernel113_x86_64_sse.nb113_end
        ## non-zero, do one more workunit
        jmp   _nb_kernel113_x86_64_sse.nb113_threadloop
_nb_kernel113_x86_64_sse.nb113_end: 


        movl nb113_nouter(%rsp),%eax
        movl nb113_ninner(%rsp),%ebx
        movq nb113_outeriter(%rbp),%rcx
        movq nb113_inneriter(%rbp),%rdx
        movl %eax,(%rcx)
        movl %ebx,(%rdx)

        addq $984,%rsp
        emms

        pop %r15
        pop %r14
        pop %r13
        pop %r12

        pop %rbx
        pop    %rbp
        ret



.globl nb_kernel113nf_x86_64_sse
.globl _nb_kernel113nf_x86_64_sse
nb_kernel113nf_x86_64_sse:      
_nb_kernel113nf_x86_64_sse:     
##      Room for return address and rbp (16 bytes)
.set nb113nf_fshift, 16
.set nb113nf_gid, 24
.set nb113nf_pos, 32
.set nb113nf_faction, 40
.set nb113nf_charge, 48
.set nb113nf_p_facel, 56
.set nb113nf_argkrf, 64
.set nb113nf_argcrf, 72
.set nb113nf_Vc, 80
.set nb113nf_type, 88
.set nb113nf_p_ntype, 96
.set nb113nf_vdwparam, 104
.set nb113nf_Vvdw, 112
.set nb113nf_p_tabscale, 120
.set nb113nf_VFtab, 128
.set nb113nf_invsqrta, 136
.set nb113nf_dvda, 144
.set nb113nf_p_gbtabscale, 152
.set nb113nf_GBtab, 160
.set nb113nf_p_nthreads, 168
.set nb113nf_count, 176
.set nb113nf_mtx, 184
.set nb113nf_outeriter, 192
.set nb113nf_inneriter, 200
.set nb113nf_work, 208
        ## stack offsets for local variables  
        ## bottom of stack is cache-aligned for sse use 
.set nb113nf_ixO, 0
.set nb113nf_iyO, 16
.set nb113nf_izO, 32
.set nb113nf_ixH1, 48
.set nb113nf_iyH1, 64
.set nb113nf_izH1, 80
.set nb113nf_ixH2, 96
.set nb113nf_iyH2, 112
.set nb113nf_izH2, 128
.set nb113nf_ixM, 144
.set nb113nf_iyM, 160
.set nb113nf_izM, 176
.set nb113nf_iqM, 192
.set nb113nf_iqH, 208
.set nb113nf_qqM, 224
.set nb113nf_qqH, 240
.set nb113nf_rinvH1, 256
.set nb113nf_rinvH2, 272
.set nb113nf_rinvM, 288
.set nb113nf_c6, 304
.set nb113nf_c12, 320
.set nb113nf_vctot, 336
.set nb113nf_Vvdwtot, 352
.set nb113nf_half, 368
.set nb113nf_three, 384
.set nb113nf_two, 400
.set nb113nf_facel, 416
.set nb113nf_iinr, 424
.set nb113nf_jindex, 432
.set nb113nf_jjnr, 440
.set nb113nf_shift, 448
.set nb113nf_shiftvec, 456
.set nb113nf_innerjjnr, 464
.set nb113nf_ntia, 472
.set nb113nf_nri, 476
.set nb113nf_is3, 480
.set nb113nf_ii3, 484
.set nb113nf_innerk, 488
.set nb113nf_n, 492
.set nb113nf_nn1, 496
.set nb113nf_nouter, 500
.set nb113nf_ninner, 504

        push %rbp
        movq %rsp,%rbp
        push %rbx

        emms

        push %r12
        push %r13
        push %r14
        push %r15

        subq $520,%rsp

        ## zero 32-bit iteration counters
        movl $0,%eax
        movl %eax,nb113nf_nouter(%rsp)
        movl %eax,nb113nf_ninner(%rsp)

        movl (%rdi),%edi
        movl %edi,nb113nf_nri(%rsp)
        movq %rsi,nb113nf_iinr(%rsp)
        movq %rdx,nb113nf_jindex(%rsp)
        movq %rcx,nb113nf_jjnr(%rsp)
        movq %r8,nb113nf_shift(%rsp)
        movq %r9,nb113nf_shiftvec(%rsp)
        movq nb113nf_p_facel(%rbp),%rsi
        movss (%rsi),%xmm0
        movss %xmm0,nb113nf_facel(%rsp)

        ## create constant floating-point factors on stack
        movl $0x3f000000,%eax   ## half in IEEE (hex)
        movl %eax,nb113nf_half(%rsp)
        movss nb113nf_half(%rsp),%xmm1
        shufps $0,%xmm1,%xmm1  ## splat to all elements
        movaps %xmm1,%xmm2
        addps  %xmm2,%xmm2      ## one
        movaps %xmm2,%xmm3
        addps  %xmm2,%xmm2      ## two
        addps  %xmm2,%xmm3      ## three
        movaps %xmm1,nb113nf_half(%rsp)
        movaps %xmm2,nb113nf_two(%rsp)
        movaps %xmm3,nb113nf_three(%rsp)

        ## assume we have at least one i particle - start directly 
        movq  nb113nf_iinr(%rsp),%rcx         ## rcx = pointer into iinr[]      
        movl  (%rcx),%ebx           ## ebx =ii 

        movq  nb113nf_charge(%rbp),%rdx
        movss 4(%rdx,%rbx,4),%xmm4
        movss 12(%rdx,%rbx,4),%xmm3
        movq nb113nf_p_facel(%rbp),%rsi
        movss (%rsi),%xmm0
        movss nb113nf_facel(%rsp),%xmm5
        mulss  %xmm5,%xmm3
        mulss  %xmm5,%xmm4

        shufps $0,%xmm3,%xmm3
        shufps $0,%xmm4,%xmm4
        movaps %xmm3,nb113nf_iqM(%rsp)
        movaps %xmm4,nb113nf_iqH(%rsp)

        movq  nb113nf_type(%rbp),%rdx
        movl  (%rdx,%rbx,4),%ecx
        shll  %ecx
        movq nb113nf_p_ntype(%rbp),%rdi
        imull (%rdi),%ecx     ## rcx = ntia = 2*ntype*type[ii0] 
        movl  %ecx,nb113nf_ntia(%rsp)

_nb_kernel113nf_x86_64_sse.nb113nf_threadloop: 
        movq  nb113nf_count(%rbp),%rsi            ## pointer to sync counter
        movl  (%rsi),%eax
_nb_kernel113nf_x86_64_sse.nb113nf_spinlock: 
        movl  %eax,%ebx                         ## ebx=*count=nn0
        addl  $1,%ebx                          ## ebx=nn1=nn0+10
        lock 
        cmpxchgl %ebx,(%rsi)                    ## write nn1 to *counter,
                                                ## if it hasnt changed.
                                                ## or reread *counter to eax.
        pause                                   ## -> better p4 performance
        jnz _nb_kernel113nf_x86_64_sse.nb113nf_spinlock

        ## if(nn1>nri) nn1=nri
        movl nb113nf_nri(%rsp),%ecx
        movl %ecx,%edx
        subl %ebx,%ecx
        cmovlel %edx,%ebx                       ## if(nn1>nri) nn1=nri
        ## Cleared the spinlock if we got here.
        ## eax contains nn0, ebx contains nn1.
        movl %eax,nb113nf_n(%rsp)
        movl %ebx,nb113nf_nn1(%rsp)
        subl %eax,%ebx                          ## calc number of outer lists
        movl %eax,%esi                          ## copy n to esi
        jg  _nb_kernel113nf_x86_64_sse.nb113nf_outerstart
        jmp _nb_kernel113nf_x86_64_sse.nb113nf_end

_nb_kernel113nf_x86_64_sse.nb113nf_outerstart: 
        ## ebx contains number of outer iterations
        addl nb113nf_nouter(%rsp),%ebx
        movl %ebx,nb113nf_nouter(%rsp)

_nb_kernel113nf_x86_64_sse.nb113nf_outer: 
        movq  nb113nf_shift(%rsp),%rax        ## rax = pointer into shift[] 
        movl  (%rax,%rsi,4),%ebx                ## rbx=shift[n] 

        lea  (%rbx,%rbx,2),%rbx        ## rbx=3*is 
        movl  %ebx,nb113nf_is3(%rsp)            ## store is3 

        movq  nb113nf_shiftvec(%rsp),%rax     ## rax = base of shiftvec[] 

        movss (%rax,%rbx,4),%xmm0
        movss 4(%rax,%rbx,4),%xmm1
        movss 8(%rax,%rbx,4),%xmm2

        movq  nb113nf_iinr(%rsp),%rcx           ## rcx = pointer into iinr[]    
        movl  (%rcx,%rsi,4),%ebx                ## ebx =ii 

        movaps %xmm0,%xmm3
        movaps %xmm1,%xmm4
        movaps %xmm2,%xmm5
        movaps %xmm0,%xmm6
        movaps %xmm1,%xmm7

        lea  (%rbx,%rbx,2),%rbx        ## rbx = 3*ii=ii3 
        movq  nb113nf_pos(%rbp),%rax    ## rax = base of pos[]  
        movl  %ebx,nb113nf_ii3(%rsp)

        addss (%rax,%rbx,4),%xmm3       ## ox
        addss 4(%rax,%rbx,4),%xmm4     ## oy
        addss 8(%rax,%rbx,4),%xmm5     ## oz
        addss 12(%rax,%rbx,4),%xmm6    ## h1x
        addss 16(%rax,%rbx,4),%xmm7    ## h1y
        shufps $0,%xmm3,%xmm3
        shufps $0,%xmm4,%xmm4
        shufps $0,%xmm5,%xmm5
        shufps $0,%xmm6,%xmm6
        shufps $0,%xmm7,%xmm7
        movaps %xmm3,nb113nf_ixO(%rsp)
        movaps %xmm4,nb113nf_iyO(%rsp)
        movaps %xmm5,nb113nf_izO(%rsp)
        movaps %xmm6,nb113nf_ixH1(%rsp)
        movaps %xmm7,nb113nf_iyH1(%rsp)

        movss %xmm2,%xmm6
        movss %xmm0,%xmm3
        movss %xmm1,%xmm4
        movss %xmm2,%xmm5
        addss 20(%rax,%rbx,4),%xmm6    ## h1z
        addss 24(%rax,%rbx,4),%xmm0    ## h2x
        addss 28(%rax,%rbx,4),%xmm1    ## h2y
        addss 32(%rax,%rbx,4),%xmm2    ## h2z
        addss 36(%rax,%rbx,4),%xmm3    ## mx
        addss 40(%rax,%rbx,4),%xmm4    ## my
        addss 44(%rax,%rbx,4),%xmm5    ## mz

        shufps $0,%xmm6,%xmm6