nb_kernel203_x86_64_sse.s

来自「最著名最快的分子模拟软件」· S 代码 · 共 1,531 行 · 第 1/4 页

##
## $Id: nb_kernel203_x86_64_sse.s,v 1.4.2.3 2006/09/22 08:32:49 lindahl Exp $
##
## Gromacs 4.0                         Copyright (c) 1991-2003 
## David van der Spoel, Erik Lindahl
##
## This program is free software; you can redistribute it and/or
## modify it under the terms of the GNU General Public License
## as published by the Free Software Foundation; either version 2
## of the License, or (at your option) any later version.
##
## To help us fund GROMACS development, we humbly ask that you cite
## the research papers on the package. Check out http://www.gromacs.org
## 
## And Hey:
## Gnomes, ROck Monsters And Chili Sauce
##






.globl nb_kernel203_x86_64_sse
.globl _nb_kernel203_x86_64_sse
nb_kernel203_x86_64_sse:        
_nb_kernel203_x86_64_sse:       
##      Room for return address and rbp (16 bytes)
.set nb203_fshift, 16
.set nb203_gid, 24
.set nb203_pos, 32
.set nb203_faction, 40
.set nb203_charge, 48
.set nb203_p_facel, 56
.set nb203_argkrf, 64
.set nb203_argcrf, 72
.set nb203_Vc, 80
.set nb203_type, 88
.set nb203_p_ntype, 96
.set nb203_vdwparam, 104
.set nb203_Vvdw, 112
.set nb203_p_tabscale, 120
.set nb203_VFtab, 128
.set nb203_invsqrta, 136
.set nb203_dvda, 144
.set nb203_p_gbtabscale, 152
.set nb203_GBtab, 160
.set nb203_p_nthreads, 168
.set nb203_count, 176
.set nb203_mtx, 184
.set nb203_outeriter, 192
.set nb203_inneriter, 200
.set nb203_work, 208
        ## stack offsets for local variables  
        ## bottom of stack is cache-aligned for sse use 
.set nb203_ixH1, 0
.set nb203_iyH1, 16
.set nb203_izH1, 32
.set nb203_ixH2, 48
.set nb203_iyH2, 64
.set nb203_izH2, 80
.set nb203_ixM, 96
.set nb203_iyM, 112
.set nb203_izM, 128
.set nb203_iqH, 144
.set nb203_iqM, 160
.set nb203_dxH1, 176
.set nb203_dyH1, 192
.set nb203_dzH1, 208
.set nb203_dxH2, 224
.set nb203_dyH2, 240
.set nb203_dzH2, 256
.set nb203_dxM, 272
.set nb203_dyM, 288
.set nb203_dzM, 304
.set nb203_qqH, 320
.set nb203_qqM, 336
.set nb203_vctot, 352
.set nb203_fixH1, 384
.set nb203_fiyH1, 400
.set nb203_fizH1, 416
.set nb203_fixH2, 432
.set nb203_fiyH2, 448
.set nb203_fizH2, 464
.set nb203_fixM, 480
.set nb203_fiyM, 496
.set nb203_fizM, 512
.set nb203_fjx, 528
.set nb203_fjy, 544
.set nb203_fjz, 560
.set nb203_half, 576
.set nb203_three, 592
.set nb203_two, 608
.set nb203_krf, 624
.set nb203_crf, 640
.set nb203_krsqH1, 656
.set nb203_krsqH2, 672
.set nb203_krsqM, 688
.set nb203_is3, 704
.set nb203_ii3, 708
.set nb203_innerjjnr, 712
.set nb203_nri, 720
.set nb203_iinr, 728
.set nb203_jindex, 736
.set nb203_jjnr, 744
.set nb203_shift, 752
.set nb203_shiftvec, 760
.set nb203_facel, 768
.set nb203_innerk, 776
.set nb203_n, 780
.set nb203_nn1, 784
.set nb203_nouter, 788
.set nb203_ninner, 792

        push %rbp
        movq %rsp,%rbp
        push %rbx

        emms

        push %r12
        push %r13
        push %r14
        push %r15

        subq $808,%rsp          ## local variable stack space (n*16+8)

        ## zero 32-bit iteration counters
        movl $0,%eax
        movl %eax,nb203_nouter(%rsp)
        movl %eax,nb203_ninner(%rsp)

        movl (%rdi),%edi
        movl %edi,nb203_nri(%rsp)
        movq %rsi,nb203_iinr(%rsp)
        movq %rdx,nb203_jindex(%rsp)
        movq %rcx,nb203_jjnr(%rsp)
        movq %r8,nb203_shift(%rsp)
        movq %r9,nb203_shiftvec(%rsp)
        movq nb203_p_facel(%rbp),%rsi
        movss (%rsi),%xmm0
        movss %xmm0,nb203_facel(%rsp)


        movq nb203_argkrf(%rbp),%rsi
        movq nb203_argcrf(%rbp),%rdi
        movss (%rsi),%xmm1
        movss (%rdi),%xmm2
        shufps $0,%xmm1,%xmm1
        shufps $0,%xmm2,%xmm2
        movaps %xmm1,nb203_krf(%rsp)
        movaps %xmm2,nb203_crf(%rsp)

        ## create constant floating-point factors on stack
        movl $0x3f000000,%eax   ## half in IEEE (hex)
        movl %eax,nb203_half(%rsp)
        movss nb203_half(%rsp),%xmm1
        shufps $0,%xmm1,%xmm1  ## splat to all elements
        movaps %xmm1,%xmm2
        addps  %xmm2,%xmm2      ## one
        movaps %xmm2,%xmm3
        addps  %xmm2,%xmm2      ## two
        addps  %xmm2,%xmm3      ## three
        movaps %xmm1,nb203_half(%rsp)
        movaps %xmm2,nb203_two(%rsp)
        movaps %xmm3,nb203_three(%rsp)

        ## assume we have at least one i particle - start directly 
        movq  nb203_iinr(%rsp),%rcx             ## rcx = pointer into iinr[]    
        movl  (%rcx),%ebx               ## ebx =ii 

        movq  nb203_charge(%rbp),%rdx
        movss 4(%rdx,%rbx,4),%xmm3
        movss 12(%rdx,%rbx,4),%xmm4
        movq nb203_p_facel(%rbp),%rsi
        movss (%rsi),%xmm0
        movss nb203_facel(%rsp),%xmm5
        mulss  %xmm5,%xmm3
        mulss  %xmm5,%xmm4

        shufps $0,%xmm3,%xmm3
        shufps $0,%xmm4,%xmm4
        movaps %xmm3,nb203_iqH(%rsp)
        movaps %xmm4,nb203_iqM(%rsp)

_nb_kernel203_x86_64_sse.nb203_threadloop: 
        movq  nb203_count(%rbp),%rsi            ## pointer to sync counter
        movl  (%rsi),%eax
_nb_kernel203_x86_64_sse.nb203_spinlock: 
        movl  %eax,%ebx                         ## ebx=*count=nn0
        addq  $1,%rbx                          ## rbx=nn1=nn0+10
        lock 
        cmpxchgl %ebx,(%rsi)                    ## write nn1 to *counter,
                                                ## if it hasnt changed.
                                                ## or reread *counter to eax.
        pause                                   ## -> better p4 performance
        jnz _nb_kernel203_x86_64_sse.nb203_spinlock

        ## if(nn1>nri) nn1=nri
        movl nb203_nri(%rsp),%ecx
        movl %ecx,%edx
        subl %ebx,%ecx
        cmovlel %edx,%ebx                       ## if(nn1>nri) nn1=nri
        ## Cleared the spinlock if we got here.
        ## eax contains nn0, ebx contains nn1.
        movl %eax,nb203_n(%rsp)
        movl %ebx,nb203_nn1(%rsp)
        subl %eax,%ebx                          ## calc number of outer lists
        movl %eax,%esi                          ## copy n to esi
        jg  _nb_kernel203_x86_64_sse.nb203_outerstart
        jmp _nb_kernel203_x86_64_sse.nb203_end

_nb_kernel203_x86_64_sse.nb203_outerstart: 
        ## ebx contains number of outer iterations
        addl nb203_nouter(%rsp),%ebx
        movl %ebx,nb203_nouter(%rsp)

_nb_kernel203_x86_64_sse.nb203_outer: 
        movq  nb203_shift(%rsp),%rax            ## rax = pointer into shift[] 
        movl  (%rax,%rsi,4),%ebx                ## rbx=shift[n] 

        lea  (%rbx,%rbx,2),%rbx        ## rbx=3*is 
        movl  %ebx,nb203_is3(%rsp)      ## store is3 

        movq  nb203_shiftvec(%rsp),%rax     ## rax = base of shiftvec[] 

        movss (%rax,%rbx,4),%xmm0
        movss 4(%rax,%rbx,4),%xmm1
        movss 8(%rax,%rbx,4),%xmm2

        movq  nb203_iinr(%rsp),%rcx             ## rcx = pointer into iinr[]    
        movl  (%rcx,%rsi,4),%ebx                ## ebx =ii 

        movaps %xmm0,%xmm3
        movaps %xmm1,%xmm4
        movaps %xmm2,%xmm5

        lea  (%rbx,%rbx,2),%rbx        ## rbx = 3*ii=ii3 
        movq  nb203_pos(%rbp),%rax      ## rax = base of pos[]  
        movl  %ebx,nb203_ii3(%rsp)

        addss 12(%rax,%rbx,4),%xmm3
        addss 16(%rax,%rbx,4),%xmm4
        addss 20(%rax,%rbx,4),%xmm5
        shufps $0,%xmm3,%xmm3
        shufps $0,%xmm4,%xmm4
        shufps $0,%xmm5,%xmm5
        movaps %xmm3,nb203_ixH1(%rsp)
        movaps %xmm4,nb203_iyH1(%rsp)
        movaps %xmm5,nb203_izH1(%rsp)

        movss %xmm0,%xmm3
        movss %xmm1,%xmm4
        movss %xmm2,%xmm5
        addss 24(%rax,%rbx,4),%xmm0
        addss 28(%rax,%rbx,4),%xmm1
        addss 32(%rax,%rbx,4),%xmm2
        addss 36(%rax,%rbx,4),%xmm3
        addss 40(%rax,%rbx,4),%xmm4
        addss 44(%rax,%rbx,4),%xmm5

        shufps $0,%xmm0,%xmm0
        shufps $0,%xmm1,%xmm1
        shufps $0,%xmm2,%xmm2
        shufps $0,%xmm3,%xmm3
        shufps $0,%xmm4,%xmm4
        shufps $0,%xmm5,%xmm5
        movaps %xmm0,nb203_ixH2(%rsp)
        movaps %xmm1,nb203_iyH2(%rsp)
        movaps %xmm2,nb203_izH2(%rsp)
        movaps %xmm3,nb203_ixM(%rsp)
        movaps %xmm4,nb203_iyM(%rsp)
        movaps %xmm5,nb203_izM(%rsp)

        ## clear vctot and i forces 
        xorps %xmm4,%xmm4
        movaps %xmm4,nb203_vctot(%rsp)
        movaps %xmm4,nb203_fixH1(%rsp)
        movaps %xmm4,nb203_fiyH1(%rsp)
        movaps %xmm4,nb203_fizH1(%rsp)
        movaps %xmm4,nb203_fixH2(%rsp)
        movaps %xmm4,nb203_fiyH2(%rsp)
        movaps %xmm4,nb203_fizH2(%rsp)
        movaps %xmm4,nb203_fixM(%rsp)
        movaps %xmm4,nb203_fiyM(%rsp)
        movaps %xmm4,nb203_fizM(%rsp)

        movq  nb203_jindex(%rsp),%rax
        movl  (%rax,%rsi,4),%ecx                ## jindex[n] 
        movl  4(%rax,%rsi,4),%edx               ## jindex[n+1] 
        subl  %ecx,%edx                 ## number of innerloop atoms 

        movq  nb203_pos(%rbp),%rsi
        movq  nb203_faction(%rbp),%rdi
        movq  nb203_jjnr(%rsp),%rax
        shll  $2,%ecx
        addq  %rcx,%rax
        movq  %rax,nb203_innerjjnr(%rsp)        ## pointer to jjnr[nj0] 
        movl  %edx,%ecx
        subl  $4,%edx
        addl  nb203_ninner(%rsp),%ecx
        movl  %ecx,nb203_ninner(%rsp)
        addl  $0,%edx
        movl  %edx,nb203_innerk(%rsp)   ## number of innerloop atoms 
        jge   _nb_kernel203_x86_64_sse.nb203_unroll_loop
        jmp   _nb_kernel203_x86_64_sse.nb203_odd_inner
_nb_kernel203_x86_64_sse.nb203_unroll_loop: 
        ## quad-unroll innerloop here 
        movq  nb203_innerjjnr(%rsp),%rdx        ## pointer to jjnr[k] 
        movl  (%rdx),%eax
        movl  4(%rdx),%ebx
        movl  8(%rdx),%ecx
        movl  12(%rdx),%edx             ## eax-edx=jnr1-4 

        addq $16,nb203_innerjjnr(%rsp)             ## advance pointer (unrolled 4) 

        movq nb203_charge(%rbp),%rsi    ## base of charge[] 

        movss (%rsi,%rax,4),%xmm3
        movss (%rsi,%rcx,4),%xmm4
        movss (%rsi,%rbx,4),%xmm6
        movss (%rsi,%rdx,4),%xmm7

        shufps $0,%xmm6,%xmm3
        shufps $0,%xmm7,%xmm4
        shufps $136,%xmm4,%xmm3 ## 10001000 ;# all charges in xmm3  
        movaps %xmm3,%xmm4              ## and in xmm4 
        mulps  nb203_iqH(%rsp),%xmm3
        mulps  nb203_iqM(%rsp),%xmm4

        movaps  %xmm3,nb203_qqH(%rsp)
        movaps  %xmm4,nb203_qqM(%rsp)

        movq nb203_pos(%rbp),%rsi       ## base of pos[] 

        lea  (%rax,%rax,2),%rax        ## replace jnr with j3 
        lea  (%rbx,%rbx,2),%rbx
        lea  (%rcx,%rcx,2),%rcx        ## replace jnr with j3 
        lea  (%rdx,%rdx,2),%rdx

        ## move four coordinates to xmm0-xmm2   
        movlps (%rsi,%rax,4),%xmm4
        movlps (%rsi,%rcx,4),%xmm5
        movss 8(%rsi,%rax,4),%xmm2
        movss 8(%rsi,%rcx,4),%xmm6

        movhps (%rsi,%rbx,4),%xmm4
        movhps (%rsi,%rdx,4),%xmm5

        movss 8(%rsi,%rbx,4),%xmm0
        movss 8(%rsi,%rdx,4),%xmm1

        shufps $0,%xmm0,%xmm2
        shufps $0,%xmm1,%xmm6

        movaps %xmm4,%xmm0
        movaps %xmm4,%xmm1

        shufps $136,%xmm6,%xmm2 ## 10001000

        shufps $136,%xmm5,%xmm0 ## 10001000
        shufps $221,%xmm5,%xmm1 ## 11011101             

    ## xmm0 = jx
    ## xmm1 = jy
    ## xmm2 = jz

    movaps %xmm0,%xmm3
    movaps %xmm1,%xmm4
    movaps %xmm2,%xmm5
    movaps %xmm0,%xmm6
    movaps %xmm1,%xmm7
    movaps %xmm2,%xmm8

    subps nb203_ixH1(%rsp),%xmm0
    subps nb203_iyH1(%rsp),%xmm1
    subps nb203_izH1(%rsp),%xmm2
    subps nb203_ixH2(%rsp),%xmm3
    subps nb203_iyH2(%rsp),%xmm4
    subps nb203_izH2(%rsp),%xmm5
    subps nb203_ixM(%rsp),%xmm6
    subps nb203_iyM(%rsp),%xmm7
    subps nb203_izM(%rsp),%xmm8