nb_kernel203_x86_64_sse.s

来自「最著名最快的分子模拟软件」· S 代码 · 共 1,531 行 · 第 1/4 页

        addps  %xmm5,%xmm2 ## sum is in 1/2 in xmm0-xmm2 

        movaps %xmm0,%xmm3
        movaps %xmm1,%xmm4
        movaps %xmm2,%xmm5

        shufps $1,%xmm3,%xmm3
        shufps $1,%xmm4,%xmm4
        shufps $1,%xmm5,%xmm5
        addss  %xmm3,%xmm0
        addss  %xmm4,%xmm1
        addss  %xmm5,%xmm2      ## xmm0-xmm2 has single force in pos0 

        ## increment i force 
        movss  12(%rdi,%rcx,4),%xmm3
        movss  16(%rdi,%rcx,4),%xmm4
        movss  20(%rdi,%rcx,4),%xmm5
        subss  %xmm0,%xmm3
        subss  %xmm1,%xmm4
        subss  %xmm2,%xmm5
        movss  %xmm3,12(%rdi,%rcx,4)
        movss  %xmm4,16(%rdi,%rcx,4)
        movss  %xmm5,20(%rdi,%rcx,4)

        ## accumulate force in xmm6/xmm7 for fshift 
        movaps %xmm0,%xmm6
        movss %xmm2,%xmm7
        movlhps %xmm1,%xmm6
        shufps $8,%xmm6,%xmm6 ## 00001000       

        ## accumulate H2 i forces in xmm0, xmm1, xmm2 
        movaps nb203_fixH2(%rsp),%xmm0
        movaps nb203_fiyH2(%rsp),%xmm1
        movaps nb203_fizH2(%rsp),%xmm2

        movhlps %xmm0,%xmm3
        movhlps %xmm1,%xmm4
        movhlps %xmm2,%xmm5
        addps  %xmm3,%xmm0
        addps  %xmm4,%xmm1
        addps  %xmm5,%xmm2 ## sum is in 1/2 in xmm0-xmm2 

        movaps %xmm0,%xmm3
        movaps %xmm1,%xmm4
        movaps %xmm2,%xmm5

        shufps $1,%xmm3,%xmm3
        shufps $1,%xmm4,%xmm4
        shufps $1,%xmm5,%xmm5
        addss  %xmm3,%xmm0
        addss  %xmm4,%xmm1
        addss  %xmm5,%xmm2      ## xmm0-xmm2 has single force in pos0 

        ## increment i force 
        movss  24(%rdi,%rcx,4),%xmm3
        movss  28(%rdi,%rcx,4),%xmm4
        movss  32(%rdi,%rcx,4),%xmm5
        subss  %xmm0,%xmm3
        subss  %xmm1,%xmm4
        subss  %xmm2,%xmm5
        movss  %xmm3,24(%rdi,%rcx,4)
        movss  %xmm4,28(%rdi,%rcx,4)
        movss  %xmm5,32(%rdi,%rcx,4)

        ## accumulate force in xmm6/xmm7 for fshift 
        addss %xmm2,%xmm7
        movlhps %xmm1,%xmm0
        shufps $8,%xmm0,%xmm0 ## 00001000       
        addps   %xmm0,%xmm6

        ## accumulate m i forces in xmm0, xmm1, xmm2 
        movaps nb203_fixM(%rsp),%xmm0
        movaps nb203_fiyM(%rsp),%xmm1
        movaps nb203_fizM(%rsp),%xmm2

        movhlps %xmm0,%xmm3
        movhlps %xmm1,%xmm4
        movhlps %xmm2,%xmm5
        addps  %xmm3,%xmm0
        addps  %xmm4,%xmm1
        addps  %xmm5,%xmm2 ## sum is in 1/2 in xmm0-xmm2 

        movaps %xmm0,%xmm3
        movaps %xmm1,%xmm4
        movaps %xmm2,%xmm5

        shufps $1,%xmm3,%xmm3
        shufps $1,%xmm4,%xmm4
        shufps $1,%xmm5,%xmm5
        addss  %xmm3,%xmm0
        addss  %xmm4,%xmm1
        addss  %xmm5,%xmm2      ## xmm0-xmm2 has single force in pos0 

        ## increment i force 
        movss  36(%rdi,%rcx,4),%xmm3
        movss  40(%rdi,%rcx,4),%xmm4
        movss  44(%rdi,%rcx,4),%xmm5
        subss  %xmm0,%xmm3
        subss  %xmm1,%xmm4
        subss  %xmm2,%xmm5
        movss  %xmm3,36(%rdi,%rcx,4)
        movss  %xmm4,40(%rdi,%rcx,4)
        movss  %xmm5,44(%rdi,%rcx,4)

        ## accumulate force in xmm6/xmm7 for fshift 
        addss %xmm2,%xmm7
        movlhps %xmm1,%xmm0
        shufps $8,%xmm0,%xmm0 ## 00001000       
        addps   %xmm0,%xmm6

        ## increment fshift force  
        movlps  (%rsi,%rdx,4),%xmm3
        movss  8(%rsi,%rdx,4),%xmm4
        subps  %xmm6,%xmm3
        subss  %xmm7,%xmm4
        movlps  %xmm3,(%rsi,%rdx,4)
        movss  %xmm4,8(%rsi,%rdx,4)

        ## get n from stack
        movl nb203_n(%rsp),%esi
        ## get group index for i particle 
        movq  nb203_gid(%rbp),%rdx              ## base of gid[]
        movl  (%rdx,%rsi,4),%edx                ## ggid=gid[n]

        ## accumulate total potential energy and update it 
        movaps nb203_vctot(%rsp),%xmm7
        ## accumulate 
        movhlps %xmm7,%xmm6
        addps  %xmm6,%xmm7      ## pos 0-1 in xmm7 have the sum now 
        movaps %xmm7,%xmm6
        shufps $1,%xmm6,%xmm6
        addss  %xmm6,%xmm7

        ## add earlier value from mem 
        movq  nb203_Vc(%rbp),%rax
        addss (%rax,%rdx,4),%xmm7
        ## move back to mem 
        movss %xmm7,(%rax,%rdx,4)

        ## finish if last 
        movl nb203_nn1(%rsp),%ecx
        ## esi already loaded with n
        incl %esi
        subl %esi,%ecx
        jz _nb_kernel203_x86_64_sse.nb203_outerend

        ## not last, iterate outer loop once more!  
        movl %esi,nb203_n(%rsp)
        jmp _nb_kernel203_x86_64_sse.nb203_outer
_nb_kernel203_x86_64_sse.nb203_outerend: 
        ## check if more outer neighborlists remain
        movl  nb203_nri(%rsp),%ecx
        ## esi already loaded with n above
        subl  %esi,%ecx
        jz _nb_kernel203_x86_64_sse.nb203_end
        ## non-zero, do one more workunit
        jmp   _nb_kernel203_x86_64_sse.nb203_threadloop
_nb_kernel203_x86_64_sse.nb203_end: 

        movl nb203_nouter(%rsp),%eax
        movl nb203_ninner(%rsp),%ebx
        movq nb203_outeriter(%rbp),%rcx
        movq nb203_inneriter(%rbp),%rdx
        movl %eax,(%rcx)
        movl %ebx,(%rdx)

        addq $808,%rsp
        emms


        pop %r15
        pop %r14
        pop %r13
        pop %r12

        pop %rbx
        pop    %rbp
        ret








.globl nb_kernel203nf_x86_64_sse
.globl _nb_kernel203nf_x86_64_sse
nb_kernel203nf_x86_64_sse:      
_nb_kernel203nf_x86_64_sse:     
##      Room for return address and rbp (16 bytes)
.set nb203nf_fshift, 16
.set nb203nf_gid, 24
.set nb203nf_pos, 32
.set nb203nf_faction, 40
.set nb203nf_charge, 48
.set nb203nf_p_facel, 56
.set nb203nf_argkrf, 64
.set nb203nf_argcrf, 72
.set nb203nf_Vc, 80
.set nb203nf_type, 88
.set nb203nf_p_ntype, 96
.set nb203nf_vdwparam, 104
.set nb203nf_Vvdw, 112
.set nb203nf_p_tabscale, 120
.set nb203nf_VFtab, 128
.set nb203nf_invsqrta, 136
.set nb203nf_dvda, 144
.set nb203nf_p_gbtabscale, 152
.set nb203nf_GBtab, 160
.set nb203nf_p_nthreads, 168
.set nb203nf_count, 176
.set nb203nf_mtx, 184
.set nb203nf_outeriter, 192
.set nb203nf_inneriter, 200
.set nb203nf_work, 208
        ## stack offsets for local variables  
        ## bottom of stack is cache-aligned for sse use 
.set nb203nf_ixH1, 0
.set nb203nf_iyH1, 16
.set nb203nf_izH1, 32
.set nb203nf_ixH2, 48
.set nb203nf_iyH2, 64
.set nb203nf_izH2, 80
.set nb203nf_ixM, 96
.set nb203nf_iyM, 112
.set nb203nf_izM, 128
.set nb203nf_iqH, 144
.set nb203nf_iqM, 160
.set nb203nf_qqH, 176
.set nb203nf_qqM, 192
.set nb203nf_vctot, 208
.set nb203nf_half, 224
.set nb203nf_three, 240
.set nb203nf_krf, 256
.set nb203nf_crf, 272
.set nb203nf_krsqH1, 288
.set nb203nf_krsqH2, 304
.set nb203nf_krsqM, 320
.set nb203nf_is3, 336
.set nb203nf_ii3, 340
.set nb203nf_innerjjnr, 344
.set nb203nf_nri, 352
.set nb203nf_iinr, 360
.set nb203nf_jindex, 368
.set nb203nf_jjnr, 376
.set nb203nf_shift, 384
.set nb203nf_shiftvec, 392
.set nb203nf_facel, 400
.set nb203nf_innerk, 408
.set nb203nf_n, 412
.set nb203nf_nn1, 416
.set nb203nf_nouter, 420
.set nb203nf_ninner, 424

        push %rbp
        movq %rsp,%rbp
        push %rbx

        emms

        push %r12
        push %r13
        push %r14
        push %r15

        subq $440,%rsp          ## local variable stack space (n*16+8)

        ## zero 32-bit iteration counters
        movl $0,%eax
        movl %eax,nb203nf_nouter(%rsp)
        movl %eax,nb203nf_ninner(%rsp)

        movl (%rdi),%edi
        movl %edi,nb203nf_nri(%rsp)
        movq %rsi,nb203nf_iinr(%rsp)
        movq %rdx,nb203nf_jindex(%rsp)
        movq %rcx,nb203nf_jjnr(%rsp)
        movq %r8,nb203nf_shift(%rsp)
        movq %r9,nb203nf_shiftvec(%rsp)
        movq nb203nf_p_facel(%rbp),%rsi
        movss (%rsi),%xmm0
        movss %xmm0,nb203nf_facel(%rsp)

        movq nb203nf_argkrf(%rbp),%rsi
        movq nb203nf_argcrf(%rbp),%rdi
        movss (%rsi),%xmm1
        movss (%rdi),%xmm2
        shufps $0,%xmm1,%xmm1
        shufps $0,%xmm2,%xmm2
        movaps %xmm1,nb203nf_krf(%rsp)
        movaps %xmm2,nb203nf_crf(%rsp)

        ## create constant floating-point factors on stack
        movl $0x3f000000,%eax   ## half in IEEE (hex)
        movl %eax,nb203nf_half(%rsp)
        movss nb203nf_half(%rsp),%xmm1
        shufps $0,%xmm1,%xmm1  ## splat to all elements
        movaps %xmm1,%xmm2
        addps  %xmm2,%xmm2      ## one
        movaps %xmm2,%xmm3
        addps  %xmm2,%xmm2      ## two
        addps  %xmm2,%xmm3      ## three
        movaps %xmm1,nb203nf_half(%rsp)
        movaps %xmm3,nb203nf_three(%rsp)

        ## assume we have at least one i particle - start directly 
        movq  nb203nf_iinr(%rsp),%rcx           ## rcx = pointer into iinr[]    
        movl  (%rcx),%ebx               ## ebx =ii 

        movq  nb203nf_charge(%rbp),%rdx
        movss 4(%rdx,%rbx,4),%xmm3
        movss 12(%rdx,%rbx,4),%xmm4
        movq nb203nf_p_facel(%rbp),%rsi
        movss (%rsi),%xmm0
        movss nb203nf_facel(%rsp),%xmm5
        mulss  %xmm5,%xmm3
        mulss  %xmm5,%xmm4

        shufps $0,%xmm3,%xmm3
        shufps $0,%xmm4,%xmm4
        movaps %xmm3,nb203nf_iqH(%rsp)
        movaps %xmm4,nb203nf_iqM(%rsp)

_nb_kernel203nf_x86_64_sse.nb203nf_threadloop: 
        movq  nb203nf_count(%rbp),%rsi            ## pointer to sync counter
        movl  (%rsi),%eax
_nb_kernel203nf_x86_64_sse.nb203nf_spinlock: 
        movl  %eax,%ebx                         ## ebx=*count=nn0
        addq  $1,%rbx                          ## rbx=nn1=nn0+10
        lock 
        cmpxchgl %ebx,(%rsi)                    ## write nn1 to *counter,
                                                ## if it hasnt changed.
                                                ## or reread *counter to eax.
        pause                                   ## -> better p4 performance
        jnz _nb_kernel203nf_x86_64_sse.nb203nf_spinlock

        ## if(nn1>nri) nn1=nri
        movl nb203nf_nri(%rsp),%ecx
        movl %ecx,%edx
        subl %ebx,%ecx
        cmovlel %edx,%ebx                       ## if(nn1>nri) nn1=nri
        ## Cleared the spinlock if we got here.
        ## eax contains nn0, ebx contains nn1.
        movl %eax,nb203nf_n(%rsp)
        movl %ebx,nb203nf_nn1(%rsp)
        subl %eax,%ebx                          ## calc number of outer lists
        movl %eax,%esi                          ## copy n to esi
        jg  _nb_kernel203nf_x86_64_sse.nb203nf_outerstart
        jmp _nb_kernel203nf_x86_64_sse.nb203nf_end

_nb_kernel203nf_x86_64_sse.nb203nf_outerstart: 
        ## ebx contains number of outer iterations
        addl nb203nf_nouter(%rsp),%ebx
        movl %ebx,nb203nf_nouter(%rsp)

_nb_kernel203nf_x86_64_sse.nb203nf_outer: 
        movq  nb203nf_shift(%rsp),%rax          ## rax = pointer into shift[] 
        movl  (%rax,%rsi,4),%ebx                ## rbx=shift[n] 

        lea  (%rbx,%rbx,2),%rbx        ## rbx=3*is 
        movl  %ebx,nb203nf_is3(%rsp)            ## store is3 

        movq  nb203nf_shiftvec(%rsp),%rax     ## rax = base of shiftvec[] 

        movss (%rax,%rbx,4),%xmm0
        movss 4(%rax,%rbx,4),%xmm1
        movss 8(%rax,%rbx,4),%xmm2

        movq  nb203nf_iinr(%rsp),%rcx           ## rcx = pointer into iinr[]    
        movl  (%rcx,%rsi,4),%ebx                ## ebx =ii 

        movaps %xmm0,%xmm3
        movaps %xmm1,%xmm4
        movaps %xmm2,%xmm5

        lea  (%rbx,%rbx,2),%rbx        ## rbx = 3*ii=ii3 
        movq  nb203nf_pos(%rbp),%rax    ## rax = base of pos[]  
        movl  %ebx,nb203nf_ii3(%rsp)

        addss 12(%rax,%rbx,4),%xmm3
        addss 16(%rax,%rbx,4),%xmm4
        addss 20(%rax,%rbx,4),%xmm5