nb_kernel232_x86_64_sse.s

来自「最著名最快的分子模拟软件」· S 代码 · 共 2,138 行 · 第 1/5 页

        movl  (%rdx,%rsi,4),%edx                ## ggid=gid[n]

        ## accumulate total potential energy and update it 
        movaps nb232_vctot(%rsp),%xmm7
        ## accumulate 
        movhlps %xmm7,%xmm6
        addps  %xmm6,%xmm7      ## pos 0-1 in xmm7 have the sum now 
        movaps %xmm7,%xmm6
        shufps $1,%xmm6,%xmm6
        addss  %xmm6,%xmm7

        ## add earlier value from mem 
        movq  nb232_Vc(%rbp),%rax
        addss (%rax,%rdx,4),%xmm7
        ## move back to mem 
        movss %xmm7,(%rax,%rdx,4)

        ## accumulate total lj energy and update it 
        movaps nb232_Vvdwtot(%rsp),%xmm7
        ## accumulate 
        movhlps %xmm7,%xmm6
        addps  %xmm6,%xmm7      ## pos 0-1 in xmm7 have the sum now 
        movaps %xmm7,%xmm6
        shufps $1,%xmm6,%xmm6
        addss  %xmm6,%xmm7

        ## add earlier value from mem 
        movq  nb232_Vvdw(%rbp),%rax
        addss (%rax,%rdx,4),%xmm7
        ## move back to mem 
        movss %xmm7,(%rax,%rdx,4)

        ## finish if last 
        movl nb232_nn1(%rsp),%ecx
        ## esi already loaded with n
        incl %esi
        subl %esi,%ecx
        jz _nb_kernel232_x86_64_sse.nb232_outerend

        ## not last, iterate outer loop once more!  
        movl %esi,nb232_n(%rsp)
        jmp _nb_kernel232_x86_64_sse.nb232_outer
_nb_kernel232_x86_64_sse.nb232_outerend: 
        ## check if more outer neighborlists remain
        movl  nb232_nri(%rsp),%ecx
        ## esi already loaded with n above
        subl  %esi,%ecx
        jz _nb_kernel232_x86_64_sse.nb232_end
        ## non-zero, do one more workunit
        jmp   _nb_kernel232_x86_64_sse.nb232_threadloop
_nb_kernel232_x86_64_sse.nb232_end: 
        movl nb232_nouter(%rsp),%eax
        movl nb232_ninner(%rsp),%ebx
        movq nb232_outeriter(%rbp),%rcx
        movq nb232_inneriter(%rbp),%rdx
        movl %eax,(%rcx)
        movl %ebx,(%rdx)

        addq $1624,%rsp
        emms

        pop %r15
        pop %r14
        pop %r13
        pop %r12

        pop %rbx
        pop    %rbp
        ret






.globl nb_kernel232nf_x86_64_sse
.globl _nb_kernel232nf_x86_64_sse
nb_kernel232nf_x86_64_sse:      
_nb_kernel232nf_x86_64_sse:     
##      Room for return address and rbp (16 bytes)
.set nb232nf_fshift, 16
.set nb232nf_gid, 24
.set nb232nf_pos, 32
.set nb232nf_faction, 40
.set nb232nf_charge, 48
.set nb232nf_p_facel, 56
.set nb232nf_argkrf, 64
.set nb232nf_argcrf, 72
.set nb232nf_Vc, 80
.set nb232nf_type, 88
.set nb232nf_p_ntype, 96
.set nb232nf_vdwparam, 104
.set nb232nf_Vvdw, 112
.set nb232nf_p_tabscale, 120
.set nb232nf_VFtab, 128
.set nb232nf_invsqrta, 136
.set nb232nf_dvda, 144
.set nb232nf_p_gbtabscale, 152
.set nb232nf_GBtab, 160
.set nb232nf_p_nthreads, 168
.set nb232nf_count, 176
.set nb232nf_mtx, 184
.set nb232nf_outeriter, 192
.set nb232nf_inneriter, 200
.set nb232nf_work, 208
        ## stack offsets for local variables  
        ## bottom of stack is cache-aligned for sse use 
.set nb232nf_ixO, 0
.set nb232nf_iyO, 16
.set nb232nf_izO, 32
.set nb232nf_ixH1, 48
.set nb232nf_iyH1, 64
.set nb232nf_izH1, 80
.set nb232nf_ixH2, 96
.set nb232nf_iyH2, 112
.set nb232nf_izH2, 128
.set nb232nf_jxO, 144
.set nb232nf_jyO, 160
.set nb232nf_jzO, 176
.set nb232nf_jxH1, 192
.set nb232nf_jyH1, 208
.set nb232nf_jzH1, 224
.set nb232nf_jxH2, 240
.set nb232nf_jyH2, 256
.set nb232nf_jzH2, 272
.set nb232nf_qqOO, 288
.set nb232nf_qqOH, 304
.set nb232nf_qqHH, 320
.set nb232nf_c6, 336
.set nb232nf_c12, 352
.set nb232nf_vctot, 368
.set nb232nf_Vvdwtot, 384
.set nb232nf_half, 400
.set nb232nf_three, 416
.set nb232nf_rsqOO, 432
.set nb232nf_rsqOH1, 448
.set nb232nf_rsqOH2, 464
.set nb232nf_rsqH1O, 480
.set nb232nf_rsqH1H1, 496
.set nb232nf_rsqH1H2, 512
.set nb232nf_rsqH2O, 528
.set nb232nf_rsqH2H1, 544
.set nb232nf_rsqH2H2, 560
.set nb232nf_rinvOO, 576
.set nb232nf_rinvOH1, 592
.set nb232nf_rinvOH2, 608
.set nb232nf_rinvH1O, 624
.set nb232nf_rinvH1H1, 640
.set nb232nf_rinvH1H2, 656
.set nb232nf_rinvH2O, 672
.set nb232nf_rinvH2H1, 688
.set nb232nf_rinvH2H2, 704
.set nb232nf_krf, 720
.set nb232nf_crf, 736
.set nb232nf_tsc, 752
.set nb232nf_nri, 768
.set nb232nf_iinr, 776
.set nb232nf_jindex, 784
.set nb232nf_jjnr, 792
.set nb232nf_shift, 800
.set nb232nf_shiftvec, 808
.set nb232nf_facel, 816
.set nb232nf_innerjjnr, 824
.set nb232nf_is3, 832
.set nb232nf_ii3, 836
.set nb232nf_innerk, 840
.set nb232nf_n, 844
.set nb232nf_nn1, 848
.set nb232nf_nouter, 852
.set nb232nf_ninner, 856
        push %rbp
        movq %rsp,%rbp
        push %rbx


        emms
        subq $872,%rsp          ## local variable stack space (n*16+8)

        ## zero 32-bit iteration counters
        movl $0,%eax
        movl %eax,nb232nf_nouter(%rsp)
        movl %eax,nb232nf_ninner(%rsp)

        movl (%rdi),%edi
        movl %edi,nb232nf_nri(%rsp)
        movq %rsi,nb232nf_iinr(%rsp)
        movq %rdx,nb232nf_jindex(%rsp)
        movq %rcx,nb232nf_jjnr(%rsp)
        movq %r8,nb232nf_shift(%rsp)
        movq %r9,nb232nf_shiftvec(%rsp)
        movq nb232nf_p_facel(%rbp),%rsi
        movss (%rsi),%xmm0
        movss %xmm0,nb232nf_facel(%rsp)

        movq nb232nf_p_tabscale(%rbp),%rax
        movss (%rax),%xmm3
        shufps $0,%xmm3,%xmm3
        movaps %xmm3,nb232nf_tsc(%rsp)

        movq nb232nf_argkrf(%rbp),%rsi
        movq nb232nf_argcrf(%rbp),%rdi
        movss (%rsi),%xmm1
        movss (%rdi),%xmm2
        shufps $0,%xmm1,%xmm1
        shufps $0,%xmm2,%xmm2
        movaps %xmm1,nb232nf_krf(%rsp)
        movaps %xmm2,nb232nf_crf(%rsp)

        ## assume we have at least one i particle - start directly 
        movq  nb232nf_iinr(%rsp),%rcx         ## rcx = pointer into iinr[]      
        movl  (%rcx),%ebx           ## ebx =ii 

        movq  nb232nf_charge(%rbp),%rdx
        movss (%rdx,%rbx,4),%xmm3
        movss %xmm3,%xmm4
        movss 4(%rdx,%rbx,4),%xmm5
        movq nb232nf_p_facel(%rbp),%rsi
        movss (%rsi),%xmm0
        movss nb232nf_facel(%rsp),%xmm6
        mulss  %xmm3,%xmm3
        mulss  %xmm5,%xmm4
        mulss  %xmm5,%xmm5
        mulss  %xmm6,%xmm3
        mulss  %xmm6,%xmm4
        mulss  %xmm6,%xmm5
        shufps $0,%xmm3,%xmm3
        shufps $0,%xmm4,%xmm4
        shufps $0,%xmm5,%xmm5
        movaps %xmm3,nb232nf_qqOO(%rsp)
        movaps %xmm4,nb232nf_qqOH(%rsp)
        movaps %xmm5,nb232nf_qqHH(%rsp)

        xorps %xmm0,%xmm0
        movq  nb232nf_type(%rbp),%rdx
        movl  (%rdx,%rbx,4),%ecx
        shll  %ecx
        movl  %ecx,%edx
        movq nb232nf_p_ntype(%rbp),%rdi
        imull (%rdi),%ecx     ## rcx = ntia = 2*ntype*type[ii0] 
        addq  %rcx,%rdx
        movq  nb232nf_vdwparam(%rbp),%rax
        movlps (%rax,%rdx,4),%xmm0
        movaps %xmm0,%xmm1
        shufps $0,%xmm0,%xmm0
        shufps $85,%xmm1,%xmm1 ## 01010101
        movaps %xmm0,nb232nf_c6(%rsp)
        movaps %xmm1,nb232nf_c12(%rsp)

        ## create constant floating-point factors on stack
        movl $0x3f000000,%eax   ## half in IEEE (hex)
        movl %eax,nb232nf_half(%rsp)
        movss nb232nf_half(%rsp),%xmm1
        shufps $0,%xmm1,%xmm1  ## splat to all elements
        movaps %xmm1,%xmm2
        addps  %xmm2,%xmm2      ## one
        movaps %xmm2,%xmm3
        addps  %xmm2,%xmm2      ## two
        addps  %xmm2,%xmm3      ## three
        movaps %xmm1,nb232nf_half(%rsp)
        movaps %xmm3,nb232nf_three(%rsp)

_nb_kernel232nf_x86_64_sse.nb232nf_threadloop: 
        movq  nb232nf_count(%rbp),%rsi            ## pointer to sync counter
        movl  (%rsi),%eax
_nb_kernel232nf_x86_64_sse.nb232nf_spinlock: 
        movl  %eax,%ebx                         ## ebx=*count=nn0
        addl  $1,%ebx                          ## ebx=nn1=nn0+10
        lock 
        cmpxchgl %ebx,(%rsi)                    ## write nn1 to *counter,
                                                ## if it hasnt changed.
                                                ## or reread *counter to eax.
        pause                                   ## -> better p4 performance
        jnz _nb_kernel232nf_x86_64_sse.nb232nf_spinlock

        ## if(nn1>nri) nn1=nri
        movl nb232nf_nri(%rsp),%ecx
        movl %ecx,%edx
        subl %ebx,%ecx
        cmovlel %edx,%ebx                       ## if(nn1>nri) nn1=nri
        ## Cleared the spinlock if we got here.
        ## eax contains nn0, ebx contains nn1.
        movl %eax,nb232nf_n(%rsp)
        movl %ebx,nb232nf_nn1(%rsp)
        subl %eax,%ebx                          ## calc number of outer lists
        movl %eax,%esi                          ## copy n to esi
        jg  _nb_kernel232nf_x86_64_sse.nb232nf_outerstart
        jmp _nb_kernel232nf_x86_64_sse.nb232nf_end

_nb_kernel232nf_x86_64_sse.nb232nf_outerstart: 
        ## ebx contains number of outer iterations
        addl nb232nf_nouter(%rsp),%ebx
        movl %ebx,nb232nf_nouter(%rsp)

_nb_kernel232nf_x86_64_sse.nb232nf_outer: 
        movq  nb232nf_shift(%rsp),%rax        ## eax = pointer into shift[] 
        movl  (%rax,%rsi,4),%ebx                ## ebx=shift[n] 

        lea  (%rbx,%rbx,2),%rbx    ## rbx=3*is 
        movl  %ebx,nb232nf_is3(%rsp)            ## store is3 

        movq  nb232nf_shiftvec(%rsp),%rax     ## eax = base of shiftvec[] 

        movss (%rax,%rbx,4),%xmm0
        movss 4(%rax,%rbx,4),%xmm1
        movss 8(%rax,%rbx,4),%xmm2

        movq  nb232nf_iinr(%rsp),%rcx         ## ecx = pointer into iinr[]      
        movl  (%rcx,%rsi,4),%ebx            ## ebx =ii 

        lea  (%rbx,%rbx,2),%rbx        ## rbx = 3*ii=ii3 
        movq  nb232nf_pos(%rbp),%rax      ## eax = base of pos[]  
        movl  %ebx,nb232nf_ii3(%rsp)

        movaps %xmm0,%xmm3
        movaps %xmm1,%xmm4
        movaps %xmm2,%xmm5
        addss (%rax,%rbx,4),%xmm3
        addss 4(%rax,%rbx,4),%xmm4
        addss 8(%rax,%rbx,4),%xmm5
        shufps $0,%xmm3,%xmm3
        shufps $0,%xmm4,%xmm4
        shufps $0,%xmm5,%xmm5
        movaps %xmm3,nb232nf_ixO(%rsp)
        movaps %xmm4,nb232nf_iyO(%rsp)
        movaps %xmm5,nb232nf_izO(%rsp)

        movss %xmm0,%xmm3
        movss %xmm1,%xmm4
        movss %xmm2,%xmm5
        addss 12(%rax,%rbx,4),%xmm0
        addss 16(%rax,%rbx,4),%xmm1
        addss 20(%rax,%rbx,4),%xmm2
        addss 24(%rax,%rbx,4),%xmm3
        addss 28(%rax,%rbx,4),%xmm4
        addss 32(%rax,%rbx,4),%xmm5

        shufps $0,%xmm0,%xmm0
        shufps $0,%xmm1,%xmm1
        shufps $0,%xmm2,%xmm2
        shufps $0,%xmm3,%xmm3
        shufps $0,%xmm4,%xmm4
        shufps $0,%xmm5,%xmm5
        movaps %xmm0,nb232nf_ixH1(%rsp)
        movaps %xmm1,nb232nf_iyH1(%rsp)
        movaps %xmm2,nb232nf_izH1(%rsp)
        movaps %xmm3,nb232nf_ixH2(%rsp)
        movaps %xmm4,nb232nf_iyH2(%rsp)
        movaps %xmm5,nb232nf_izH2(%rsp)

        ## clear vctot
        xorps %xmm4,%xmm4
        movaps %xmm4,nb232nf_vctot(%rsp)
        movaps %xmm4,nb232nf_Vvdwtot(%rsp)

        movq  nb232nf_jindex(%rsp),%rax
        movl  (%rax,%rsi,4),%ecx             ## jindex[n] 
        movl  4(%rax,%rsi,4),%edx            ## jindex[n+1] 
        subl  %ecx,%edx              ## number of innerloop atoms 

        movq  nb232nf_pos(%rbp),%rsi
        movq  nb232nf_jjnr(%rsp),%rax
        shll  $2,%ecx
        addq  %rcx,%rax
        movq  %rax,nb232nf_innerjjnr(%rsp)       ## pointer to jjnr[nj0] 
        movl  %edx,%ecx
        subl  $4,%edx
        addl  nb232nf_ninner(%rsp),%ecx
        movl  %ecx,nb232nf_ninner(%rsp)
        addl  $0,%edx
        movl  %edx,nb232nf_innerk(%rsp)      ## number of innerloop atoms 
        jge   _nb_kernel232nf_x86_64_sse.nb232nf_unroll_loop
        jmp   _nb_kernel232nf_x86_64_sse.nb232nf_single_check
_nb_kernel232nf_x86_64_sse.nb232nf_unroll_loop: 
        ## quad-unroll innerloop here 
        movq  nb232nf_innerjjnr(%rsp),%rdx       ## pointer to jjnr[k] 

        movl  (%rdx),%eax
        movl  4(%rdx),%ebx
        movl  8(%rdx),%ecx
        movl  12(%rdx),%edx           ## eax-edx=jnr1-4 

        addq $16,nb232nf_innerjjnr(%rsp)             ## advance pointer (unrolled 4) 

        movq nb232nf_pos(%rbp),%rsi        ## base of pos[] 

        lea  (%rax,%rax,2),%rax     ## replace jnr with j3 
        lea  (%rbx,%rbx,2),%rbx
        lea  (%rcx,%rcx,2),%rcx     ## replace jnr with j3 
        lea  (%rdx,%rdx,2),%rdx

        ## move j coordinates to local temp variables 
        movlps (%rsi,%rax,4),%xmm2
        movlps 12(%rsi,%rax,4),%xmm3
        movlps 24(%rsi,%rax,4),%xmm4

        movlps (%rsi,%rbx,4),%xmm5
        movlps 12(%rsi,%rbx,4),%xmm6
        movlps 24(%rsi,%rbx,4),%xmm7

        movhps (%rsi,%rcx,4),%xmm2
        movhps 12(%rsi,%rcx,4),%xmm3
        movhps 24(%rsi,%rcx,4),%xmm4

        movhps (%rsi,%rdx,4),%xmm5
        movhps 12(%rsi,%rdx,4),%xmm6
        movhps 24(%rsi,%rdx,4),%xmm7

        ## current state:       
        ## xmm2= jxOa  jyOa  jxOc  jyOc 
        ## xmm3= jxH1a jyH1a jxH1c jyH1c 
        ## xmm4= jxH2a jyH2a jxH2c jyH2c 
        ## xmm5= jxOb  jyOb  jxOd  jyOd 
        ## xmm6= jxH1b jyH1b jxH1d jyH1d 
        ## xmm7= jxH2b jyH2b jxH2d jyH2d 

        movaps %xmm2,%xmm0
        movaps %xmm3,%xmm1
        unpcklps %xmm5,%xmm0    ## xmm0= jxOa  jxOb  jyOa  jyOb 
        unpcklps %xmm6,%xmm1    ## xmm1= jxH1a jxH1b jyH1a jyH1b 
        unpckhps %xmm5,%xmm2    ## xmm2= jxOc  jxOd  jyOc  jyOd 
        unpckhps %xmm6,%xmm3    ## xmm3= jxH1c jxH1d jyH1c jyH1d 
        movaps %xmm4,%xmm5
        movaps   %xmm0,%xmm6
        unpcklps %xmm7,%xmm4    ## xmm4= jxH2a jxH2b jyH2a jyH2b                
        unpckhps %xmm7,%xmm5    ## xmm5= jxH2c jxH2d jyH2c jyH2d 
        movaps