nb_kernel232_x86_64_sse.s

来自「最著名最快的分子模拟软件」· S 代码 · 共 2,138 行 · 第 1/5 页

    movaps %xmm1,%xmm7
    movaps %xmm2,%xmm8

    subps nb232_ixO(%rsp),%xmm0
    subps nb232_iyO(%rsp),%xmm1
    subps nb232_izO(%rsp),%xmm2
    subps nb232_ixH1(%rsp),%xmm3
    subps nb232_iyH1(%rsp),%xmm4
    subps nb232_izH1(%rsp),%xmm5
    subps nb232_ixH2(%rsp),%xmm6
    subps nb232_iyH2(%rsp),%xmm7
    subps nb232_izH2(%rsp),%xmm8

        movaps %xmm0,nb232_dxOO(%rsp)
        movaps %xmm1,nb232_dyOO(%rsp)
        movaps %xmm2,nb232_dzOO(%rsp)
        mulps  %xmm0,%xmm0
        mulps  %xmm1,%xmm1
        mulps  %xmm2,%xmm2
        movaps %xmm3,nb232_dxH1O(%rsp)
        movaps %xmm4,nb232_dyH1O(%rsp)
        movaps %xmm5,nb232_dzH1O(%rsp)
        mulps  %xmm3,%xmm3
        mulps  %xmm4,%xmm4
        mulps  %xmm5,%xmm5
        movaps %xmm6,nb232_dxH2O(%rsp)
        movaps %xmm7,nb232_dyH2O(%rsp)
        movaps %xmm8,nb232_dzH2O(%rsp)
        mulps  %xmm6,%xmm6
        mulps  %xmm7,%xmm7
        mulps  %xmm8,%xmm8
        addps  %xmm1,%xmm0
        addps  %xmm2,%xmm0
        addps  %xmm4,%xmm3
        addps  %xmm5,%xmm3
    addps  %xmm7,%xmm6
    addps  %xmm8,%xmm6

        ## start doing invsqrt for jO atoms
        rsqrtps %xmm0,%xmm1
        rsqrtps %xmm3,%xmm4
    rsqrtps %xmm6,%xmm7

        movaps  %xmm1,%xmm2
        movaps  %xmm4,%xmm5
    movaps  %xmm7,%xmm8

        mulps   %xmm1,%xmm1 ## lu*lu
        mulps   %xmm4,%xmm4 ## lu*lu
    mulps   %xmm7,%xmm7 ## lu*lu

        movaps  nb232_three(%rsp),%xmm9
        movaps  %xmm9,%xmm10
    movaps  %xmm9,%xmm11

        mulps   %xmm0,%xmm1 ## rsq*lu*lu
        mulps   %xmm3,%xmm4 ## rsq*lu*lu 
    mulps   %xmm6,%xmm7 ## rsq*lu*lu

        subps   %xmm1,%xmm9
        subps   %xmm4,%xmm10
    subps   %xmm7,%xmm11 ## 3-rsq*lu*lu

        mulps   %xmm2,%xmm9
        mulps   %xmm5,%xmm10
    mulps   %xmm8,%xmm11 ## lu*(3-rsq*lu*lu)

        movaps  nb232_half(%rsp),%xmm4
        mulps   %xmm4,%xmm9 ## rinvOO 
        mulps   %xmm4,%xmm10 ## rinvH1O
    mulps   %xmm4,%xmm11 ## rinvH2O

        ## O interactions 
    ## rsq in xmm0,xmm3,xmm6  
    ## rinv in xmm9, xmm10, xmm11
    movaps %xmm0,nb232_rsqOO(%rsp)
    movaps %xmm3,nb232_rsqOH1(%rsp)
    movaps %xmm6,nb232_rsqOH2(%rsp)
    movaps %xmm9,nb232_rinvOO(%rsp)
    movaps %xmm10,nb232_rinvOH1(%rsp)
    movaps %xmm11,nb232_rinvOH2(%rsp)



    ## table LJ interaction
    mulps  %xmm9,%xmm0
    mulps  nb232_tsc(%rsp),%xmm0   ## rtab

    ## truncate and convert to integers
    cvttps2dq %xmm0,%xmm1

    ## convert back to float
    cvtdq2ps  %xmm1,%xmm2

    ## multiply by 8
    pslld   $3,%xmm1

    ## move to integer registers
    movhlps %xmm1,%xmm13
    movd    %xmm1,%r8d
    movd    %xmm13,%r10d
    shufps $1,%xmm1,%xmm1
    shufps $1,%xmm13,%xmm13
    movd    %xmm1,%r9d
    movd    %xmm13,%r11d

    ## calculate eps
    subps     %xmm2,%xmm0
    movq nb232_VFtab(%rbp),%rsi

    movlps (%rsi,%r8,4),%xmm5
        movlps 16(%rsi,%r8,4),%xmm9

        movlps (%rsi,%r10,4),%xmm7
        movlps 16(%rsi,%r10,4),%xmm11

        movhps (%rsi,%r9,4),%xmm5
        movhps 16(%rsi,%r9,4),%xmm9

        movhps (%rsi,%r11,4),%xmm7
        movhps 16(%rsi,%r11,4),%xmm11

    movaps %xmm5,%xmm4
    movaps %xmm9,%xmm8
        shufps $136,%xmm7,%xmm4 ## 10001000
        shufps $136,%xmm11,%xmm8 ## 10001000
        shufps $221,%xmm7,%xmm5 ## 11011101
        shufps $221,%xmm11,%xmm9 ## 11011101

        movlps 8(%rsi,%r8,4),%xmm7
        movlps 24(%rsi,%r8,4),%xmm11

        movlps 8(%rsi,%r10,4),%xmm13
        movlps 24(%rsi,%r10,4),%xmm14

        movhps 8(%rsi,%r9,4),%xmm7
        movhps 24(%rsi,%r9,4),%xmm11

        movhps 8(%rsi,%r11,4),%xmm13
        movhps 24(%rsi,%r11,4),%xmm14

    movaps %xmm7,%xmm6
    movaps %xmm11,%xmm10

        shufps $136,%xmm13,%xmm6 ## 10001000
        shufps $136,%xmm14,%xmm10 ## 10001000
        shufps $221,%xmm13,%xmm7 ## 11011101
        shufps $221,%xmm14,%xmm11 ## 11011101
    ## dispersion table in xmm4-xmm7, repulsion table in xmm8-xmm11

    mulps  %xmm0,%xmm7   ## Heps
    mulps  %xmm0,%xmm11
    mulps  %xmm0,%xmm6  ## Geps
    mulps  %xmm0,%xmm10
    mulps  %xmm0,%xmm7  ## Heps2
    mulps  %xmm0,%xmm11
    addps  %xmm6,%xmm5 ## F+Geps
    addps  %xmm10,%xmm9
    addps  %xmm7,%xmm5  ## F+Geps+Heps2 = Fp
    addps  %xmm11,%xmm9
    addps  %xmm7,%xmm7   ## 2*Heps2
    addps  %xmm11,%xmm11
    addps  %xmm6,%xmm7  ## 2*Heps2+Geps
    addps  %xmm10,%xmm11

    addps  %xmm5,%xmm7 ## FF = Fp + 2*Heps2 + Geps
    addps  %xmm9,%xmm11
    mulps  %xmm0,%xmm5 ## eps*Fp
    mulps  %xmm0,%xmm9
    movaps nb232_c6(%rsp),%xmm12
    movaps nb232_c12(%rsp),%xmm13
    addps  %xmm4,%xmm5 ## VV
    addps  %xmm8,%xmm9

    mulps  %xmm12,%xmm5 ## VV*c6 = vnb6
    mulps  %xmm13,%xmm9 ## VV*c12 = vnb12
    addps  %xmm9,%xmm5
    addps  nb232_Vvdwtot(%rsp),%xmm5
    movaps %xmm5,nb232_Vvdwtot(%rsp)

    mulps  %xmm12,%xmm7  ## FF*c6 = fnb6
    mulps  %xmm13,%xmm11  ## FF*c12  = fnb12
    addps  %xmm11,%xmm7
    mulps  nb232_tsc(%rsp),%xmm7
    movaps %xmm7,nb232_fstmp(%rsp)

    ## Coulomb reaction-field interaction
    movaps nb232_rsqOO(%rsp),%xmm0
    movaps nb232_rsqOH1(%rsp),%xmm3
    movaps nb232_rsqOH2(%rsp),%xmm6
    movaps nb232_rinvOO(%rsp),%xmm9
    movaps nb232_rinvOH1(%rsp),%xmm10
    movaps nb232_rinvOH2(%rsp),%xmm11

    movaps %xmm9,%xmm1 ## copy of rinv
    movaps %xmm10,%xmm4
    movaps %xmm11,%xmm7
    movaps nb232_krf(%rsp),%xmm2
    mulps  %xmm10,%xmm10 ## rinvsq
    mulps  %xmm11,%xmm11
    mulps  %xmm2,%xmm0 ## k*rsq
    mulps  %xmm2,%xmm3
    mulps  %xmm2,%xmm6
    movaps %xmm0,%xmm2 ## copy of k*rsq
    movaps %xmm3,%xmm5
    movaps %xmm6,%xmm8
    addps  %xmm1,%xmm2 ## rinv+krsq
    addps  %xmm4,%xmm5
    addps  %xmm7,%xmm8
    subps  nb232_crf(%rsp),%xmm2     ## rinv+krsq-crf
    subps  nb232_crf(%rsp),%xmm5
    subps  nb232_crf(%rsp),%xmm8
    mulps  nb232_qqOO(%rsp),%xmm2   ## voul=qq*(rinv+ krsq-crf)
    mulps  nb232_qqOH(%rsp),%xmm5   ## voul=qq*(rinv+ krsq-crf)
    mulps  nb232_qqOH(%rsp),%xmm8   ## voul=qq*(rinv+ krsq-crf)
    addps  %xmm0,%xmm0 ## 2*krsq
    addps  %xmm3,%xmm3
    addps  %xmm6,%xmm6
    subps  %xmm0,%xmm1 ## rinv-2*krsq
    subps  %xmm3,%xmm4
    subps  %xmm6,%xmm7
    mulps  nb232_qqOO(%rsp),%xmm1     ## (rinv-2*krsq)*qq
    mulps  nb232_qqOH(%rsp),%xmm4
    mulps  nb232_qqOH(%rsp),%xmm7
    addps  nb232_vctot(%rsp),%xmm2
    addps  %xmm8,%xmm5
    addps  %xmm5,%xmm2
    movaps %xmm2,%xmm15
    mulps  %xmm9,%xmm1  ## fijC
    mulps  %xmm10,%xmm4
    mulps  %xmm11,%xmm7
    ## xmm1, xmm4, xmm7 contains fscal coul
    ## xmm15 contains vctot
    subps nb232_fstmp(%rsp),%xmm1
    mulps %xmm9,%xmm1

        ## move j O forces to local temp variables 
        movq nb232_faction(%rbp),%rdi
    movlps (%rdi,%rax,4),%xmm9 ## jxOa jyOa  -   -
    movlps (%rdi,%rcx,4),%xmm10 ## jxOc jyOc  -   -
    movhps (%rdi,%rbx,4),%xmm9 ## jxOa jyOa jxOb jyOb 
    movhps (%rdi,%rdx,4),%xmm10 ## jxOc jyOc jxOd jyOd 

    movss  8(%rdi,%rax,4),%xmm11    ## jzOa  -  -  -
    movss  8(%rdi,%rcx,4),%xmm12    ## jzOc  -  -  -
    movhps 8(%rdi,%rbx,4),%xmm11    ## jzOa  -  jzOb  -
    movhps 8(%rdi,%rdx,4),%xmm12    ## jzOc  -  jzOd -

    shufps $136,%xmm12,%xmm11 ## 10001000 => jzOa jzOb jzOc jzOd

    ## xmm9: jxOa jyOa jxOb jyOb 
    ## xmm10: jxOc jyOc jxOd jyOd
    ## xmm11: jzOa jzOb jzOc jzOd


    movaps %xmm1,%xmm0
    movaps %xmm1,%xmm2
    movaps %xmm4,%xmm3
    movaps %xmm4,%xmm5
    movaps %xmm7,%xmm6
    movaps %xmm7,%xmm8

        mulps nb232_dxOO(%rsp),%xmm0
        mulps nb232_dyOO(%rsp),%xmm1
        mulps nb232_dzOO(%rsp),%xmm2
        mulps nb232_dxH1O(%rsp),%xmm3
        mulps nb232_dyH1O(%rsp),%xmm4
        mulps nb232_dzH1O(%rsp),%xmm5
        mulps nb232_dxH2O(%rsp),%xmm6
        mulps nb232_dyH2O(%rsp),%xmm7
        mulps nb232_dzH2O(%rsp),%xmm8

    movaps %xmm0,%xmm13
    movaps %xmm1,%xmm14
    addps %xmm2,%xmm11
    addps nb232_fixO(%rsp),%xmm0
    addps nb232_fiyO(%rsp),%xmm1
    addps nb232_fizO(%rsp),%xmm2

    addps %xmm3,%xmm13
    addps %xmm4,%xmm14
    addps %xmm5,%xmm11
    addps nb232_fixH1(%rsp),%xmm3
    addps nb232_fiyH1(%rsp),%xmm4
    addps nb232_fizH1(%rsp),%xmm5

    addps %xmm6,%xmm13
    addps %xmm7,%xmm14
    addps %xmm8,%xmm11
    addps nb232_fixH2(%rsp),%xmm6
    addps nb232_fiyH2(%rsp),%xmm7
    addps nb232_fizH2(%rsp),%xmm8

    movaps %xmm0,nb232_fixO(%rsp)
    movaps %xmm1,nb232_fiyO(%rsp)
    movaps %xmm2,nb232_fizO(%rsp)
    movaps %xmm3,nb232_fixH1(%rsp)
    movaps %xmm4,nb232_fiyH1(%rsp)
    movaps %xmm5,nb232_fizH1(%rsp)
    movaps %xmm6,nb232_fixH2(%rsp)
    movaps %xmm7,nb232_fiyH2(%rsp)
    movaps %xmm8,nb232_fizH2(%rsp)

    ## xmm9 = fOx
    ## xmm10 = fOy
    ## xmm11 = fOz
    movaps %xmm13,%xmm0
    unpcklps %xmm14,%xmm13
    unpckhps %xmm14,%xmm0

    addps %xmm13,%xmm9
    addps %xmm0,%xmm10

    movhlps  %xmm11,%xmm12 ## fOzc fOzd

    movlps %xmm9,(%rdi,%rax,4)
    movhps %xmm9,(%rdi,%rbx,4)
    movlps %xmm10,(%rdi,%rcx,4)
    movhps %xmm10,(%rdi,%rdx,4)
    movss  %xmm11,8(%rdi,%rax,4)
    movss  %xmm12,8(%rdi,%rcx,4)
    shufps $1,%xmm11,%xmm11
    shufps $1,%xmm12,%xmm12
    movss  %xmm11,8(%rdi,%rbx,4)
    movss  %xmm12,8(%rdi,%rdx,4)

    movq nb232_pos(%rbp),%rsi

        ## move j H1 coordinates to local temp variables 
    movlps 12(%rsi,%rax,4),%xmm0    ## jxH1a jyH1a  -   -
    movlps 12(%rsi,%rcx,4),%xmm1    ## jxH1c jyH1c  -   -
    movhps 12(%rsi,%rbx,4),%xmm0    ## jxH1a jyH1a jxH1b jyH1b 
    movhps 12(%rsi,%rdx,4),%xmm1    ## jxH1c jyH1c jxH1d jyH1d 

    movss  20(%rsi,%rax,4),%xmm2    ## jzH1a  -  -  -
    movss  20(%rsi,%rcx,4),%xmm3    ## jzH1c  -  -  -
    movhps 20(%rsi,%rbx,4),%xmm2    ## jzH1a  -  jzH1b  -
    movhps 20(%rsi,%rdx,4),%xmm3    ## jzH1c  -  jzH1d -

    movaps %xmm0,%xmm4
    unpcklps %xmm1,%xmm0 ## jxH1a jxH1c jyH1a jyH1c        
    unpckhps %xmm1,%xmm4 ## jxH1b jxH1d jyH1b jyH1d
    movaps %xmm0,%xmm1
    unpcklps %xmm4,%xmm0 ## x
    unpckhps %xmm4,%xmm1 ## y

    shufps  $136,%xmm3,%xmm2  ## 10001000 => jzH1a jzH1b jzH1c jzH1d

    ## xmm0 = H1x
    ## xmm1 = H1y
    ## xmm2 = H1z

    movaps %xmm0,%xmm3
    movaps %xmm1,%xmm4
    movaps %xmm2,%xmm5
    movaps %xmm0,%xmm6
    movaps %xmm1,%xmm7
    movaps %xmm2,%xmm8


    subps nb232_ixO(%rsp),%xmm0
    subps nb232_iyO(%rsp),%xmm1
    subps nb232_izO(%rsp),%xmm2
    subps nb232_ixH1(%rsp),%xmm3
    subps nb232_iyH1(%rsp),%xmm4
    subps nb232_izH1(%rsp),%xmm5
    subps nb232_ixH2(%rsp),%xmm6
    subps nb232_iyH2(%rsp),%xmm7
    subps nb232_izH2(%rsp),%xmm8

        movaps %xmm0,nb232_dxOH1(%rsp)
        movaps %xmm1,nb232_dyOH1(%rsp)
        movaps %xmm2,nb232_dzOH1(%rsp)
        mulps  %xmm0,%xmm0
        mulps  %xmm1,%xmm1
        mulps  %xmm2,%xmm2
        movaps %xmm3,nb232_dxH1H1(%rsp)
        movaps %xmm4,nb232_dyH1H1(%rsp)
        movaps %xmm5,nb232_dzH1H1(%rsp)
        mulps  %xmm3,%xmm3
        mulps  %xmm4,%xmm4
        mulps  %xmm5,%xmm5
        movaps %xmm6,nb232_dxH2H1(%rsp)
        movaps %xmm7,nb232_dyH2H1(%rsp)
        movaps %xmm8,nb232_dzH2H1(%rsp)
        mulps  %xmm6,%xmm6
        mulps  %xmm7,%xmm7
        mulps  %xmm8,%xmm8
        addps  %xmm1,%xmm0
        addps  %xmm2,%xmm0
        addps  %xmm4,%xmm3
        addps  %xmm5,%xmm3
    addps  %xmm7,%xmm6
    addps  %xmm8,%xmm6

        ## start doing invsqrt for jH1 atoms
        rsqrtps %xmm0,%xmm1
        rsqrtps %xmm3,%xmm4
    rsqrtps %xmm6,%xmm7

        movaps  %xmm1,%xmm2
        movaps  %xmm4,%xmm5
    movaps  %xmm7,%xmm8

        mulps   %xmm1,%xmm1 ## lu*lu
        mulps   %xmm4,%xmm4 ## lu*lu
    mulps   %xmm7,%xmm7 ## lu*lu

        movaps  nb232_three(%rsp),%xmm9
        movaps  %xmm9,%xmm10
    movaps  %xmm9,%xmm11

        mulps   %xmm0,%xmm1 ## rsq*lu*lu
        mulps   %xmm3,%xmm4 ## rsq*lu*lu 
    mulps   %xmm6,%xmm7 ## rsq*lu*lu

        subps   %xmm1,%xmm9
        subps   %xmm4,%xmm10
    subps   %xmm7,%xmm11 ## 3-rsq*lu*lu

        mulps   %xmm2,%xmm9
        mulps   %xmm5,%xmm10
    mulps   %xmm8,%xmm11 ## lu*(3-rsq*lu*lu)

        movaps  nb232_half(%rsp),%xmm4
        mulps   %xmm4,%xmm9 ## rinvOH1
        mulps   %xmm4,%xmm10 ## rinvH1H1
    mulps   %xmm4,%xmm11 ## rinvH2H1