nb_kernel030_x86_64_sse.intel_syntax.s

来自「最著名最快的分子模拟软件」· S 代码 · 共 1,748 行 · 第 1/4 页

;#
;# $Id: nb_kernel030_x86_64_sse.intel_syntax.s,v 1.1.2.2 2006/09/22 08:32:48 lindahl Exp $
;#
;# Gromacs 4.0                         Copyright (c) 1991-2003 
;# David van der Spoel, Erik Lindahl
;#
;# This program is free software; you can redistribute it and/or
;# modify it under the terms of the GNU General Public License
;# as published by the Free Software Foundation; either version 2
;# of the License, or (at your option) any later version.
;#
;# To help us fund GROMACS development, we humbly ask that you cite
;# the research papers on the package. Check out http://www.gromacs.org
;# 
;# And Hey:
;# Gnomes, ROck Monsters And Chili Sauce
;#

;# These files require GNU binutils 2.10 or later, since we
;# use intel syntax for portability, or a recent version 
;# of NASM that understands Extended 3DNow and SSE2 instructions.
;# (NASM is normally only used with MS Visual C++).
;# Since NASM and gnu as disagree on some definitions and use 
;# completely different preprocessing options I have to introduce a
;# trick: NASM uses ';' for comments, while gnu as uses '#' on x86.
;# Gnu as treats ';' as a line break, i.e. ignores it. This is the
;# reason why all comments need both symbols...
;# The source is written for GNU as, with intel syntax. When you use
;# NASM we redefine a couple of things. The false if-statement around 
;# the following code is seen by GNU as, but NASM doesn't see it, so 
;# the code inside is read by NASM but not gcc.

; .if 0    # block below only read by NASM
%define .section	section
%define .long		dd
%define .align		align
%define .globl		global
;# NASM only wants 'dword', not 'dword ptr'.
%define ptr
.equiv          .equiv                  2
   %1 equ %2
%endmacro
; .endif                   # End of NASM-specific block
; .intel_syntax noprefix   # Line only read by gnu as



.globl nb_kernel030_x86_64_sse
.globl _nb_kernel030_x86_64_sse
nb_kernel030_x86_64_sse:	
_nb_kernel030_x86_64_sse:	
;#	Room for return address and rbp (16 bytes)
.equiv          nb030_fshift,           16
.equiv          nb030_gid,              24
.equiv          nb030_pos,              32
.equiv          nb030_faction,          40
.equiv          nb030_charge,           48
.equiv          nb030_p_facel,          56
.equiv          nb030_argkrf,           64
.equiv          nb030_argcrf,           72
.equiv          nb030_Vc,               80
.equiv          nb030_type,             88
.equiv          nb030_p_ntype,          96
.equiv          nb030_vdwparam,         104
.equiv          nb030_Vvdw,             112
.equiv          nb030_p_tabscale,       120
.equiv          nb030_VFtab,            128
.equiv          nb030_invsqrta,         136
.equiv          nb030_dvda,             144
.equiv          nb030_p_gbtabscale,     152
.equiv          nb030_GBtab,            160
.equiv          nb030_p_nthreads,       168
.equiv          nb030_count,            176
.equiv          nb030_mtx,              184
.equiv          nb030_outeriter,        192
.equiv          nb030_inneriter,        200
.equiv          nb030_work,             208
	;# stack offsets for local variables  
	;# bottom of stack is cache-aligned for sse use 
.equiv          nb030_ix,               0
.equiv          nb030_iy,               16
.equiv          nb030_iz,               32
.equiv          nb030_dx,               48
.equiv          nb030_dy,               64
.equiv          nb030_dz,               80
.equiv          nb030_two,              96
.equiv          nb030_tsc,              112
.equiv          nb030_c6,               128
.equiv          nb030_c12,              144
.equiv          nb030_fscal,            160
.equiv          nb030_Vvdwtot,          176
.equiv          nb030_fix,              192
.equiv          nb030_fiy,              208
.equiv          nb030_fiz,              224
.equiv          nb030_half,             240
.equiv          nb030_three,            256
.equiv          nb030_is3,              272
.equiv          nb030_ii3,              276
.equiv          nb030_nri,              280
.equiv          nb030_iinr,             288
.equiv          nb030_jindex,           296
.equiv          nb030_jjnr,             304
.equiv          nb030_shift,            312
.equiv          nb030_shiftvec,         320
.equiv          nb030_innerjjnr,        328
.equiv          nb030_ntia,             336
.equiv          nb030_innerk,           340
.equiv          nb030_n,                344
.equiv          nb030_nn1,              348
.equiv          nb030_ntype,            352
.equiv          nb030_nouter,           356
.equiv          nb030_ninner,           360

	push rbp
	mov  rbp, rsp
	push rbx

	push r12
	push r13
	push r14
	push r15
	
    sub rsp, 376		; # local variable stack space (n*16+8)
	emms

	;# zero 32-bit iteration counters
	mov eax, 0
	mov [rsp + nb030_nouter], eax
	mov [rsp + nb030_ninner], eax

	mov edi, [rdi]
	mov [rsp + nb030_nri], edi
	mov [rsp + nb030_iinr], rsi
	mov [rsp + nb030_jindex], rdx
	mov [rsp + nb030_jjnr], rcx
	mov [rsp + nb030_shift], r8
	mov [rsp + nb030_shiftvec], r9
	mov rdi, [rbp + nb030_p_ntype]
	mov edi, [rdi]
	mov [rsp + nb030_ntype], edi

	mov rax, [rbp + nb030_p_tabscale]
	movss xmm3, [rax]
	shufps xmm3, xmm3, 0
	movaps [rsp + nb030_tsc], xmm3

    mov r8,  [rbp + nb030_pos]    
    mov r9,  [rbp + nb030_faction] 
    mov r10, [rbp + nb030_type]    
    mov r11, [rbp + nb030_vdwparam]    


	;# create constant floating-point factors on stack
	mov eax, 0x3f000000     ;# half in IEEE (hex)
	mov [rsp + nb030_half], eax
	movss xmm1, [rsp + nb030_half]
	shufps xmm1, xmm1, 0    ;# splat to all elements
	movaps xmm2, xmm1       
	addps  xmm2, xmm2	;# one
	movaps xmm3, xmm2
	addps  xmm2, xmm2	;# two
	addps  xmm3, xmm2	;# three
	movaps [rsp + nb030_half],  xmm1
	movaps [rsp + nb030_two], xmm2
	movaps [rsp + nb030_three],  xmm3

.nb030_threadloop:
        mov   rsi, [rbp + nb030_count]          ;# pointer to sync counter
        mov   eax, [rsi]
.nb030_spinlock:
        mov   ebx, eax                          ;# ebx=*count=nn0
        add   ebx, 1                           ;# ebx=nn1=nn0+10
        lock
        cmpxchg [esi], ebx                      ;# write nn1 to *counter,
                                                ;# if it hasnt changed.
                                                ;# or reread *counter to eax.
        pause                                   ;# -> better p4 performance
        jnz .nb030_spinlock

        ;# if(nn1>nri) nn1=nri
        mov ecx, [rsp + nb030_nri]
        mov edx, ecx
        sub ecx, ebx
        cmovle ebx, edx                         ;# if(nn1>nri) nn1=nri
        ;# Cleared the spinlock if we got here.
        ;# eax contains nn0, ebx contains nn1.
        mov [rsp + nb030_n], eax
        mov [rsp + nb030_nn1], ebx
        sub ebx, eax                            ;# calc number of outer lists
	mov esi, eax				;# copy n to esi
        jg  .nb030_outerstart
        jmp .nb030_end

.nb030_outerstart:
	;# ebx contains number of outer iterations
	add ebx, [rsp + nb030_nouter]
	mov [rsp + nb030_nouter], ebx

.nb030_outer:
	mov   rax, [rsp + nb030_shift]      ;# rax = pointer into shift[] 
	mov   ebx, [rax+rsi*4]			;# ebx=shift[n] 
	
	lea   rbx, [rbx + rbx*2]    ;# rbx=3*is 
	mov   [rsp + nb030_is3],ebx    	;# store is3 

	mov   rax, [rsp + nb030_shiftvec]   ;# rax = base of shiftvec[] 

	movss xmm0, [rax + rbx*4]
	movss xmm1, [rax + rbx*4 + 4]
	movss xmm2, [rax + rbx*4 + 8] 

	mov   rcx, [rsp + nb030_iinr]       ;# rcx = pointer into iinr[] 	
	mov   ebx, [rcx+rsi*4]	    ;# ebx =ii 

    	mov   rdx, [rbp + nb030_type] 
    	mov   edx, [rdx + rbx*4]
    	imul  edx, [rsp + nb030_ntype]
    	shl   edx, 1
    	mov   [rsp + nb030_ntia], edx
	
	lea   rbx, [rbx + rbx*2]	;# rbx = 3*ii=ii3 
	mov   rax, [rbp + nb030_pos]    ;# rax = base of pos[]  

	addss xmm0, [rax + rbx*4]
	addss xmm1, [rax + rbx*4 + 4]
	addss xmm2, [rax + rbx*4 + 8]
	
	shufps xmm0, xmm0, 0
	shufps xmm1, xmm1, 0
	shufps xmm2, xmm2, 0

	movaps [rsp + nb030_ix], xmm0
	movaps [rsp + nb030_iy], xmm1
	movaps [rsp + nb030_iz], xmm2

	mov   [rsp + nb030_ii3], ebx
	
	;# clear tot potential and i forces 
	xorps xmm4, xmm4
	movaps [rsp + nb030_Vvdwtot], xmm4
	movaps [rsp + nb030_fix], xmm4
	movaps [rsp + nb030_fiy], xmm4
	movaps [rsp + nb030_fiz], xmm4
	
	mov   rax, [rsp + nb030_jindex]
	mov   ecx, [rax + rsi*4]	     ;# jindex[n] 
	mov   edx, [rax + rsi*4+ 4]	     ;# jindex[n+1] 
	sub   edx, ecx               ;# number of innerloop atoms 
	

	mov   rax, [rsp + nb030_jjnr]
	shl   ecx, 2
	add   rax, rcx
	mov   [rsp + nb030_innerjjnr], rax     ;# pointer to jjnr[nj0] 
	mov   ecx, edx
	sub   edx,  4
	add   ecx, [rsp + nb030_ninner]
	mov   [rsp + nb030_ninner], ecx
	add   edx, 0
	mov   [rsp + nb030_innerk], edx    ;# number of innerloop atoms 
	jge   .nb030_unroll_loop
	jmp   .nb030_finish_inner
.nb030_unroll_loop:	
	;# quad-unroll innerloop here 
	mov   rdx, [rsp + nb030_innerjjnr]     ;# pointer to jjnr[k] 
	mov   eax, [rdx]	
	mov   ebx, [rdx + 4]              
	mov   ecx, [rdx + 8]            
	mov   edx, [rdx + 12]         ;# eax-edx=jnr1-4 
	add qword ptr [rsp + nb030_innerjjnr],  16 ;# advance pointer (unrolled 4) 

	lea   r12, [rax + rax*2]     ;#  j3 
	lea   r13, [rbx + rbx*2]	
	lea   r14, [rcx + rcx*2]    
	lea   r15, [rdx + rdx*2]	

	mov rdi, [rbp + nb030_pos]
	;# load coordinates
	movlps xmm1, [rdi + r12*4]	;# x1 y1 - - 
	movlps xmm2, [rdi + r14*4]	;# x3 y3 - - 
	movhps xmm1, [rdi + r13*4]	;# x2 y2 - -
	movhps xmm2, [rdi + r15*4]	;# x4 y4 - -

	movss xmm5, [rdi + r12*4 + 8]	;# z1 - - - 
	movss xmm6, [rdi + r14*4 + 8]	;# z2 - - - 
	movss xmm7, [rdi + r13*4 + 8]	;# z3 - - - 
	movss xmm8, [rdi + r15*4 + 8]	;# z4 - - - 
    movlhps xmm5, xmm7 ;# jzOa  -  jzOb  -
    movlhps xmm6, xmm8 ;# jzOc  -  jzOd -

    movaps xmm4, xmm1
    unpcklps xmm1, xmm2  ;# jxa jxc jya jyc        
    unpckhps xmm4, xmm2  ;# jxb jxd jyb jyd
    movaps xmm2, xmm1
    unpcklps xmm1, xmm4 ;# x
    unpckhps xmm2, xmm4 ;# y
    shufps   xmm5, xmm6,  136  ;# 10001000 => jzH2a jzH2b jzH2c jzH2d

	mov rsi, [rbp + nb030_type]

	;# calc dr  
	subps xmm1, [rsp + nb030_ix]
	subps xmm2, [rsp + nb030_iy]
	subps xmm5, [rsp + nb030_iz]

	;# store dr
    movaps [rsp + nb030_dx], xmm1
    movaps [rsp + nb030_dy], xmm2
    movaps [rsp + nb030_dz], xmm5
    

	;# square it 
	mulps xmm1,xmm1
	mulps xmm2,xmm2
	mulps xmm5,xmm5
	addps xmm1, xmm2
	addps xmm1, xmm5
	;# rsq in xmm1
    
    ;# load vdw types
	mov eax, [rsi + rax*4]
	mov ebx, [rsi + rbx*4]
	mov ecx, [rsi + rcx*4]
	mov edx, [rsi + rdx*4]
    
    ;# calculate rinv=1/sqrt(rsq)
	rsqrtps xmm5, xmm1
	movaps xmm2, xmm5
	mulps xmm5, xmm5
	movaps xmm4, [rsp + nb030_three]
	mulps xmm5, xmm1	;# rsq*lu*lu 	
    subps xmm4, xmm5	;# 30-rsq*lu*lu 
	mulps xmm4, xmm2	
	mulps xmm4, [rsp + nb030_half]	
	movaps xmm2, xmm4
	mulps  xmm1, xmm4	
    ;# xmm2=rinv
    ;# xmm1=r

    mov edi, [rsp + nb030_ntia]
    ;# type*=2
    shl eax, 1	
	shl ebx, 1	
	shl ecx, 1	
	shl edx, 1	

    mulps xmm1, [rsp + nb030_tsc] ;# rtab

    ;# truncate and convert to integers
    cvttps2dq xmm5, xmm1
    
	add eax, edi
	add ebx, edi
	add ecx, edi
	add edx, edi

    ;# convert back to float
    cvtdq2ps  xmm4, xmm5
    
    ;# multiply by 8
    pslld   xmm5, 3

    ;# calculate eps
    subps     xmm1, xmm4

    ;# move to integer registers
    movhlps xmm6, xmm5
    movd    r8d, xmm5
    movd    r10d, xmm6
    pshufd  xmm5, xmm5, 1
    pshufd  xmm6, xmm6, 1
    movd    r9d, xmm5
    movd    r11d, xmm6

    ;# xmm1=eps
    ;# xmm2=rinv
    
	mov rsi, [rbp + nb030_VFtab]
    ;# calculate LJ table
    movlps xmm5, [rsi + r8*4]
   	movlps xmm9, [rsi + r8*4 + 16]

	movlps xmm7,  [rsi + r10*4]
	movlps xmm11, [rsi + r10*4 + 16]

	movhps xmm5, [rsi + r9*4]
	movhps xmm9, [rsi + r9*4 + 16]

	movhps xmm7,  [rsi + r11*4]
	movhps xmm11, [rsi + r11*4 + 16]

    movaps xmm4, xmm5
    movaps xmm8, xmm9
	shufps xmm4, xmm7, 136  ;# 10001000
	shufps xmm8, xmm11, 136  ;# 10001000
	shufps xmm5, xmm7, 221  ;# 11011101
	shufps xmm9, xmm11, 221  ;# 11011101

	movlps xmm7,  [rsi + r8*4 + 8]
	movlps xmm11, [rsi + r8*4 + 24]
    
	movlps xmm13, [rsi + r10*4 + 8]
	movlps xmm14, [rsi + r10*4 + 24]

	movhps xmm7,  [rsi + r9*4 + 8]
	movhps xmm11, [rsi + r9*4 + 24]
    
	movhps xmm13, [rsi + r11*4 + 8]
	movhps xmm14, [rsi + r11*4 + 24]

    movaps xmm6, xmm7
    movaps xmm10, xmm11
    
	shufps xmm6, xmm13, 136  ;# 10001000
	shufps xmm10, xmm14, 136  ;# 10001000
	shufps xmm7, xmm13, 221  ;# 11011101
	shufps xmm11, xmm14, 221  ;# 11011101
    ;# dispersion table in xmm4-xmm7, repulsion table in xmm8-xmm11
    
	mov rsi, [rbp + nb030_vdwparam]

    mulps  xmm7, xmm1    ;# Heps
    mulps  xmm11, xmm1 
    mulps  xmm6, xmm1   ;# Geps
    mulps  xmm10, xmm1 
    mulps  xmm7, xmm1   ;# Heps2
    mulps  xmm11, xmm1 
    
    ;# load c6/c12
    movlps xmm13, [rsi + rax*4]
	movlps xmm14, [rsi + rcx*4]

    addps  xmm5, xmm6  ;# F+Geps
    addps  xmm9, xmm10 
    addps  xmm5, xmm7   ;# F+Geps+Heps2 = Fp
    addps  xmm9, xmm11