nb_kernel030_x86_64_sse.intel_syntax.s

来自「最著名最快的分子模拟软件」· S 代码 · 共 1,748 行 · 第 1/4 页

    mulss  xmm7, [rsp + nb030_tsc]
    mulss  xmm7, xmm2
    xorps  xmm9, xmm9
    
    subss  xmm9, xmm7
    movaps xmm10, xmm9
    movaps xmm11, xmm9
    
    movaps xmm12, [rsp + nb030_fix]
    movaps xmm13, [rsp + nb030_fiy]
    movaps xmm14, [rsp + nb030_fiz]
    
    mulss  xmm9,  [rsp + nb030_dx]
    mulss  xmm10, [rsp + nb030_dy]
    mulss  xmm11, [rsp + nb030_dz]

    ;# accumulate i forces
    addss xmm12, xmm9
    addss xmm13, xmm10
    addss xmm14, xmm11
    movss [rsp + nb030_fix], xmm12
    movss [rsp + nb030_fiy], xmm13
    movss [rsp + nb030_fiz], xmm14
    
	mov rsi, [rbp + nb030_faction]
    ;# add to j forces
    addss  xmm9,  [rsi + rax*4]
    addss  xmm10, [rsi + rax*4 + 4]
    addss  xmm11, [rsi + rax*4 + 8]
    movss  [rsi + rax*4],     xmm9
    movss  [rsi + rax*4 + 4], xmm10
    movss  [rsi + rax*4 + 8], xmm11
    
.nb030_updateouterdata:
	mov   ecx, [rsp + nb030_ii3]
	mov   rdi, [rbp + nb030_faction]
	mov   rsi, [rbp + nb030_fshift]
	mov   edx, [rsp + nb030_is3]

	;# accumulate i forces in xmm0, xmm1, xmm2 
	movaps xmm0, [rsp + nb030_fix]
	movaps xmm1, [rsp + nb030_fiy]
	movaps xmm2, [rsp + nb030_fiz]

	movhlps xmm3, xmm0
	movhlps xmm4, xmm1
	movhlps xmm5, xmm2
	addps  xmm0, xmm3
	addps  xmm1, xmm4
	addps  xmm2, xmm5 ;# sum is in 1/2 in xmm0-xmm2 

	movaps xmm3, xmm0	
	movaps xmm4, xmm1	
	movaps xmm5, xmm2	

	shufps xmm3, xmm3, 1
	shufps xmm4, xmm4, 1
	shufps xmm5, xmm5, 1
	addss  xmm0, xmm3
	addss  xmm1, xmm4
	addss  xmm2, xmm5	;# xmm0-xmm2 has single force in pos0 

	;# increment i force 
	movss  xmm3, [rdi + rcx*4]
	movss  xmm4, [rdi + rcx*4 + 4]
	movss  xmm5, [rdi + rcx*4 + 8]
	subss  xmm3, xmm0
	subss  xmm4, xmm1
	subss  xmm5, xmm2
	movss  [rdi + rcx*4],     xmm3
	movss  [rdi + rcx*4 + 4], xmm4
	movss  [rdi + rcx*4 + 8], xmm5

	;# increment fshift force  
	movss  xmm3, [rsi + rdx*4]
	movss  xmm4, [rsi + rdx*4 + 4]
	movss  xmm5, [rsi + rdx*4 + 8]
	subss  xmm3, xmm0
	subss  xmm4, xmm1
	subss  xmm5, xmm2
	movss  [rsi + rdx*4],     xmm3
	movss  [rsi + rdx*4 + 4], xmm4
	movss  [rsi + rdx*4 + 8], xmm5

	;# get n from stack
	mov esi, [rsp + nb030_n]
        ;# get group index for i particle 
        mov   rdx, [rbp + nb030_gid]      	;# base of gid[]
        mov   edx, [rdx + rsi*4]		;# ggid=gid[n]

	;# accumulate total lj energy and update it 
	movaps xmm7, [rsp + nb030_Vvdwtot]
	;# accumulate 
	movhlps xmm6, xmm7
	addps  xmm7, xmm6	;# pos 0-1 in xmm7 have the sum now 
	movaps xmm6, xmm7
	shufps xmm6, xmm6, 1
	addss  xmm7, xmm6		

	;# add earlier value from mem 
	mov   rax, [rbp + nb030_Vvdw]
	addss xmm7, [rax + rdx*4] 
	;# move back to mem 
	movss [rax + rdx*4], xmm7 
	
        ;# finish if last 
        mov ecx, [rsp + nb030_nn1]
	;# esi already loaded with n
	inc esi
        sub ecx, esi
        jz .nb030_outerend

        ;# not last, iterate outer loop once more!  
        mov [rsp + nb030_n], esi
        jmp .nb030_outer
.nb030_outerend:
        ;# check if more outer neighborlists remain
        mov   ecx, [rsp + nb030_nri]
	;# esi already loaded with n above
        sub   ecx, esi
        jz .nb030_end
        ;# non-zero, do one more workunit
        jmp   .nb030_threadloop
.nb030_end:
	
	mov eax, [rsp + nb030_nouter]
	mov ebx, [rsp + nb030_ninner]
	mov rcx, [rbp + nb030_outeriter]
	mov rdx, [rbp + nb030_inneriter]
	mov [rcx], eax
	mov [rdx], ebx

        add rsp, 376
	emms
		
	pop r15
	pop r14
	pop r13
	pop r12

	pop rbx
	pop	rbp
	ret



	

.globl nb_kernel030nf_x86_64_sse
.globl _nb_kernel030nf_x86_64_sse
nb_kernel030nf_x86_64_sse:	
_nb_kernel030nf_x86_64_sse:	
;#	Room for return address and rbp (16 bytes)
.equiv          nb030nf_fshift,         16
.equiv          nb030nf_gid,            24
.equiv          nb030nf_pos,            32
.equiv          nb030nf_faction,        40
.equiv          nb030nf_charge,         48
.equiv          nb030nf_p_facel,        56
.equiv          nb030nf_argkrf,         64
.equiv          nb030nf_argcrf,         72
.equiv          nb030nf_Vc,             80
.equiv          nb030nf_type,           88
.equiv          nb030nf_p_ntype,        96
.equiv          nb030nf_vdwparam,       104
.equiv          nb030nf_Vvdw,           112
.equiv          nb030nf_p_tabscale,     120
.equiv          nb030nf_VFtab,          128
.equiv          nb030nf_invsqrta,       136
.equiv          nb030nf_dvda,           144
.equiv          nb030nf_p_gbtabscale,   152
.equiv          nb030nf_GBtab,          160
.equiv          nb030nf_p_nthreads,     168
.equiv          nb030nf_count,          176
.equiv          nb030nf_mtx,            184
.equiv          nb030nf_outeriter,      192
.equiv          nb030nf_inneriter,      200
.equiv          nb030nf_work,           208
	;# stack offsets for local variables  
	;# bottom of stack is cache-aligned for sse use 
.equiv          nb030nf_ix,             0
.equiv          nb030nf_iy,             16
.equiv          nb030nf_iz,             32
.equiv          nb030nf_tsc,            48
.equiv          nb030nf_c6,             64
.equiv          nb030nf_c12,            80
.equiv          nb030nf_Vvdwtot,        96
.equiv          nb030nf_half,           112
.equiv          nb030nf_three,          128
.equiv          nb030nf_is3,            144
.equiv          nb030nf_ii3,            148
.equiv          nb030nf_innerjjnr,      152
.equiv          nb030nf_nri,            160
.equiv          nb030nf_iinr,           168
.equiv          nb030nf_jindex,         176
.equiv          nb030nf_jjnr,           184
.equiv          nb030nf_shift,          192
.equiv          nb030nf_shiftvec,       200
.equiv          nb030nf_ntia,           208
.equiv          nb030nf_innerk,         212
.equiv          nb030nf_n,              216
.equiv          nb030nf_nn1,            220
.equiv          nb030nf_ntype,          224
.equiv          nb030nf_nouter,         228
.equiv          nb030nf_ninner,         232

	push rbp
	mov  rbp, rsp
	push rbx

        sub rsp, 248		; # local variable stack space (n*16+8)
	emms

	;# zero 32-bit iteration counters
	mov eax, 0
	mov [rsp + nb030nf_nouter], eax
	mov [rsp + nb030nf_ninner], eax

	mov edi, [rdi]
	mov [rsp + nb030nf_nri], edi
	mov [rsp + nb030nf_iinr], rsi
	mov [rsp + nb030nf_jindex], rdx
	mov [rsp + nb030nf_jjnr], rcx
	mov [rsp + nb030nf_shift], r8
	mov [rsp + nb030nf_shiftvec], r9
	mov rdi, [rbp + nb030nf_p_ntype]
	mov edi, [rdi]
	mov [rsp + nb030nf_ntype], edi

	mov rax, [rbp + nb030nf_p_tabscale]
	movss xmm3, [rax]
	shufps xmm3, xmm3, 0
	movaps [rsp + nb030nf_tsc], xmm3

	;# create constant floating-point factors on stack
	mov eax, 0x3f000000     ;# half in IEEE (hex)
	mov [rsp + nb030nf_half], eax
	movss xmm1, [rsp + nb030nf_half]
	shufps xmm1, xmm1, 0    ;# splat to all elements
	movaps xmm2, xmm1       
	addps  xmm2, xmm2	;# one
	movaps xmm3, xmm2
	addps  xmm2, xmm2	;# two
	addps  xmm3, xmm2	;# three
	movaps [rsp + nb030nf_half],  xmm1
	movaps [rsp + nb030nf_three],  xmm3

.nb030nf_threadloop:
        mov   rsi, [rbp + nb030nf_count]          ;# pointer to sync counter
        mov   eax, [rsi]
.nb030nf_spinlock:
        mov   ebx, eax                          ;# ebx=*count=nn0
        add   ebx, 1                           ;# ebx=nn1=nn0+10
        lock
        cmpxchg [esi], ebx                      ;# write nn1 to *counter,
                                                ;# if it hasnt changed.
                                                ;# or reread *counter to eax.
        pause                                   ;# -> better p4 performance
        jnz .nb030nf_spinlock

        ;# if(nn1>nri) nn1=nri
        mov ecx, [rsp + nb030nf_nri]
        mov edx, ecx
        sub ecx, ebx
        cmovle ebx, edx                         ;# if(nn1>nri) nn1=nri
        ;# Cleared the spinlock if we got here.
        ;# eax contains nn0, ebx contains nn1.
        mov [rsp + nb030nf_n], eax
        mov [rsp + nb030nf_nn1], ebx
        sub ebx, eax                            ;# calc number of outer lists
	mov esi, eax				;# copy n to esi
        jg  .nb030nf_outerstart
        jmp .nb030nf_end

.nb030nf_outerstart:
	;# ebx contains number of outer iterations
	add ebx, [rsp + nb030nf_nouter]
	mov [rsp + nb030nf_nouter], ebx

.nb030nf_outer:
	mov   rax, [rsp + nb030nf_shift]      	;# rax = pointer into shift[] 
	mov   ebx, [rax+rsi*4]			;# ebx=shift[n] 
	
	lea   rbx, [rbx + rbx*2]    ;# rbx=3*is 
	mov   [rsp + nb030nf_is3],ebx    	;# store is3 

	mov   rax, [rsp + nb030nf_shiftvec]   	;# rax = base of shiftvec[] 

	movss xmm0, [rax + rbx*4]
	movss xmm1, [rax + rbx*4 + 4]
	movss xmm2, [rax + rbx*4 + 8] 

	mov   rcx, [rsp + nb030nf_iinr]       	;# rcx = pointer into iinr[] 	
	mov   ebx, [rcx+rsi*4]	    		;# ebx =ii 

    	mov   rdx, [rbp + nb030nf_type] 
    	mov   edx, [rdx + rbx*4]
    	imul  edx, [rsp + nb030nf_ntype]
    	shl   edx, 1
    	mov   [rsp + nb030nf_ntia], edx
	
	lea   rbx, [rbx + rbx*2]		;# rbx = 3*ii=ii3 
	mov   rax, [rbp + nb030nf_pos]    	;# rax = base of pos[]  

	addss xmm0, [rax + rbx*4]
	addss xmm1, [rax + rbx*4 + 4]
	addss xmm2, [rax + rbx*4 + 8]
	
	shufps xmm0, xmm0, 0
	shufps xmm1, xmm1, 0
	shufps xmm2, xmm2, 0

	movaps [rsp + nb030nf_ix], xmm0
	movaps [rsp + nb030nf_iy], xmm1
	movaps [rsp + nb030nf_iz], xmm2

	mov   [rsp + nb030nf_ii3], ebx
	
	;# clear tot potential and i forces 
	xorps xmm4, xmm4
	movaps [rsp + nb030nf_Vvdwtot], xmm4
	
	mov   rax, [rsp + nb030nf_jindex]
	mov   ecx, [rax + rsi*4]	     	;# jindex[n] 
	mov   edx, [rax + rsi*4 + 4]	     	;# jindex[n+1] 
	sub   edx, ecx               		;# number of innerloop atoms 

	mov   rsi, [rbp + nb030nf_pos]
	mov   rax, [rsp + nb030nf_jjnr]
	shl   ecx, 2
	add   rax, rcx
	mov   [rsp + nb030nf_innerjjnr], rax    ;# pointer to jjnr[nj0] 
	mov   ecx, edx
	sub   edx,  4
	add   ecx, [rsp + nb030nf_ninner]
	mov   [rsp + nb030nf_ninner], ecx
	add   edx, 0
	mov   [rsp + nb030nf_innerk], edx    	;# number of innerloop atoms 
	jge   .nb030nf_unroll_loop
	jmp   .nb030nf_finish_inner
.nb030nf_unroll_loop:	
	;# quad-unroll innerloop here 
	mov   rdx, [rsp + nb030nf_innerjjnr]     ;# pointer to jjnr[k] 
	mov   eax, [rdx]	
	mov   ebx, [rdx + 4]              
	mov   ecx, [rdx + 8]            
	mov   edx, [rdx + 12]         ;# eax-edx=jnr1-4 
	add qword ptr [rsp + nb030nf_innerjjnr],  16 ;# advance pointer (unrolled 4) 

	movd  mm0, eax		;# use mmx registers as temp storage 
	movd  mm1, ebx
	movd  mm2, ecx
	movd  mm3, edx
	
	mov rsi, [rbp + nb030nf_type]
	mov eax, [rsi + rax*4]
	mov ebx, [rsi + rbx*4]
	mov ecx, [rsi + rcx*4]
	mov edx, [rsi + rdx*4]
	mov rsi, [rbp + nb030nf_vdwparam]
	shl eax, 1	
	shl ebx, 1	
	shl ecx, 1	
	shl edx, 1	
	mov edi, [rsp + nb030nf_ntia]
	add eax, edi
	add ebx, edi
	add ecx, edi
	add edx, edi

	movlps xmm6, [rsi + rax*4]
	movlps xmm7, [rsi + rcx*4]
	movhps xmm6, [rsi + rbx*4]
	movhps xmm7, [rsi + rdx*4]

	movaps xmm4, xmm6
	shufps xmm4, xmm7, 136  ;# 10001000
	shufps xmm6, xmm7, 221  ;# 11011101
	
	movd  eax, mm0		
	movd  ebx, mm1
	movd  ecx, mm2
	movd  edx, mm3

	movaps [rsp + nb030nf_c6], xmm4
	movaps [rsp + nb030nf_c12], xmm6
	
	mov rsi, [rbp + nb030nf_pos]       ;# base of pos[] 

	lea   rax, [rax + rax*2]     ;# replace jnr with j3 
	lea   rbx, [rbx + rbx*2]	

	lea   rcx, [rcx + rcx*2]     ;# replace jnr with j3 
	lea   rdx, [rdx + rdx*2]	

	;# move four coordinates to xmm0-xmm2 	

	movlps xmm4, [rsi + rax*4]
	movlps xmm5, [rsi + rcx*4]
	movss xmm2, [rsi + rax*4 + 8]
	movss xmm6, [rsi + rcx*4 + 8]

	movhps xmm4, [rsi + rbx*4]
	movhps xmm5, [rsi + rdx*4]

	movss xmm0, [rsi + rbx*4 + 8]
	movss xmm1, [rsi + rdx*4 + 8]

	shufps xmm2, xmm0, 0
	shufps xmm6, xmm1, 0
	
	movaps xmm0, xmm4
	movaps xmm1, xmm4

	shufps xmm2, xmm6, 136  ;# 10001000
	
	shufps xmm0, xmm5, 136  ;# 10001000
	shufps xmm1, xmm5, 221  ;# 11011101		

	;# move nb030nf_ix-iz to xmm4-xmm6 
	movaps xmm4, [rsp + nb030nf_ix]
	movaps xmm5, [rsp + nb030nf_iy]
	movaps xmm6, [rsp + nb030nf_iz]

	;# calc dr 
	subps xmm4, xmm0
	subps xmm5, xmm1
	subps xmm6, xmm2

	;# square it 
	mulps xmm4,xmm4
	mulps xmm5,xmm5
	mulps xmm6,xmm6
	addps xmm4, xmm5
	addps xmm4, xmm6
	;# rsq in xmm4