nb_kernel303_ia32_sse.s

来自「最著名最快的分子模拟软件」· S 代码 · 共 1,963 行 · 第 1/5 页

##
## $Id: nb_kernel303_ia32_sse.s,v 1.1.2.2 2007/11/28 09:36:34 spoel Exp $
##
## Gromacs 4.0                         Copyright (c) 1991-2003 
## David van der Spoel, Erik Lindahl
##
## This program is free software; you can redistribute it and/or
## modify it under the terms of the GNU General Public License
## as published by the Free Software Foundation; either version 2
## of the License, or (at your option) any later version.
##
## To help us fund GROMACS development, we humbly ask that you cite
## the research papers on the package. Check out http://www.gromacs.org
## 
## And Hey:
## Gnomes, ROck Monsters And Chili Sauce
##



.globl nb_kernel303_ia32_sse
.globl _nb_kernel303_ia32_sse
nb_kernel303_ia32_sse:  
_nb_kernel303_ia32_sse: 
.set nb303_p_nri, 8
.set nb303_iinr, 12
.set nb303_jindex, 16
.set nb303_jjnr, 20
.set nb303_shift, 24
.set nb303_shiftvec, 28
.set nb303_fshift, 32
.set nb303_gid, 36
.set nb303_pos, 40
.set nb303_faction, 44
.set nb303_charge, 48
.set nb303_p_facel, 52
.set nb303_argkrf, 56
.set nb303_argcrf, 60
.set nb303_Vc, 64
.set nb303_type, 68
.set nb303_p_ntype, 72
.set nb303_vdwparam, 76
.set nb303_Vvdw, 80
.set nb303_p_tabscale, 84
.set nb303_VFtab, 88
.set nb303_invsqrta, 92
.set nb303_dvda, 96
.set nb303_p_gbtabscale, 100
.set nb303_GBtab, 104
.set nb303_p_nthreads, 108
.set nb303_count, 112
.set nb303_mtx, 116
.set nb303_outeriter, 120
.set nb303_inneriter, 124
.set nb303_work, 128
        ## stack offsets for local variables  
        ## bottom of stack is cache-aligned for sse use 
.set nb303_ixH1, 0
.set nb303_iyH1, 16
.set nb303_izH1, 32
.set nb303_ixH2, 48
.set nb303_iyH2, 64
.set nb303_izH2, 80
.set nb303_ixM, 96
.set nb303_iyM, 112
.set nb303_izM, 128
.set nb303_iqH, 144
.set nb303_iqM, 160
.set nb303_dxH1, 176
.set nb303_dyH1, 192
.set nb303_dzH1, 208
.set nb303_dxH2, 224
.set nb303_dyH2, 240
.set nb303_dzH2, 256
.set nb303_dxM, 272
.set nb303_dyM, 288
.set nb303_dzM, 304
.set nb303_qqH, 320
.set nb303_qqM, 336
.set nb303_rinvH1, 352
.set nb303_rinvH2, 368
.set nb303_rinvM, 384
.set nb303_rH1, 400
.set nb303_rH2, 416
.set nb303_rM, 432
.set nb303_tsc, 448
.set nb303_two, 464
.set nb303_vctot, 480
.set nb303_fixH1, 496
.set nb303_fiyH1, 512
.set nb303_fizH1, 528
.set nb303_fixH2, 544
.set nb303_fiyH2, 560
.set nb303_fizH2, 576
.set nb303_fixM, 592
.set nb303_fiyM, 608
.set nb303_fizM, 624
.set nb303_fjx, 640
.set nb303_fjy, 656
.set nb303_fjz, 672
.set nb303_half, 688
.set nb303_three, 704
.set nb303_is3, 720
.set nb303_ii3, 724
.set nb303_innerjjnr, 728
.set nb303_innerk, 732
.set nb303_n, 736
.set nb303_nn1, 740
.set nb303_nri, 744
.set nb303_nouter, 748
.set nb303_ninner, 752
.set nb303_salign, 756
        pushl %ebp
        movl %esp,%ebp
        pushl %eax
        pushl %ebx
        pushl %ecx
        pushl %edx
        pushl %esi
        pushl %edi
        subl $760,%esp          ## local stack space 
        movl %esp,%eax
        andl $0xf,%eax
        subl %eax,%esp
        movl %eax,nb303_salign(%esp)

        emms

        ## Move args passed by reference to stack
        movl nb303_p_nri(%ebp),%ecx
        movl (%ecx),%ecx
        movl %ecx,nb303_nri(%esp)

        ## zero iteration counters
        movl $0,%eax
        movl %eax,nb303_nouter(%esp)
        movl %eax,nb303_ninner(%esp)


        movl nb303_p_tabscale(%ebp),%eax
        movss (%eax),%xmm3
        shufps $0,%xmm3,%xmm3
        movaps %xmm3,nb303_tsc(%esp)
        ## create constant floating-point factors on stack
        movl $0x3f000000,%eax   ## constant 0.5 in IEEE (hex)
        movl %eax,nb303_half(%esp)
        movss nb303_half(%esp),%xmm1
        shufps $0,%xmm1,%xmm1  ## splat to all elements
        movaps %xmm1,%xmm2
        addps  %xmm2,%xmm2      ## 1.0
        movaps %xmm2,%xmm3
        addps  %xmm2,%xmm2      ## 2.0
        addps  %xmm2,%xmm3      ## 3.0
        movaps %xmm1,nb303_half(%esp)
        movaps %xmm2,nb303_two(%esp)
        movaps %xmm3,nb303_three(%esp)

        ## assume we have at least one i particle - start directly 
        movl  nb303_iinr(%ebp),%ecx             ## ecx = pointer into iinr[]    
        movl  (%ecx),%ebx               ## ebx =ii 

        movl  nb303_charge(%ebp),%edx
        movss 4(%edx,%ebx,4),%xmm3
        movss 12(%edx,%ebx,4),%xmm4
        movl nb303_p_facel(%ebp),%esi
        movss (%esi),%xmm5
        mulss  %xmm5,%xmm3
        mulss  %xmm5,%xmm4

        shufps $0,%xmm3,%xmm3
        shufps $0,%xmm4,%xmm4
        movaps %xmm3,nb303_iqH(%esp)
        movaps %xmm4,nb303_iqM(%esp)

_nb_kernel303_ia32_sse.nb303_threadloop: 
        movl  nb303_count(%ebp),%esi            ## pointer to sync counter
        movl  (%esi),%eax
_nb_kernel303_ia32_sse.nb303_spinlock: 
        movl  %eax,%ebx                         ## ebx=*count=nn0
        addl  $1,%ebx                          ## ebx=nn1=nn0+10
        lock 
        cmpxchgl %ebx,(%esi)                    ## write nn1 to *counter,
                                                ## if it hasnt changed.
                                                ## or reread *counter to eax.
        pause                                   ## -> better p4 performance
        jnz _nb_kernel303_ia32_sse.nb303_spinlock

        ## if(nn1>nri) nn1=nri
        movl nb303_nri(%esp),%ecx
        movl %ecx,%edx
        subl %ebx,%ecx
        cmovlel %edx,%ebx                       ## if(nn1>nri) nn1=nri
        ## Cleared the spinlock if we got here.
        ## eax contains nn0, ebx contains nn1.
        movl %eax,nb303_n(%esp)
        movl %ebx,nb303_nn1(%esp)
        subl %eax,%ebx                          ## calc number of outer lists
        movl %eax,%esi                          ## copy n to esi
        jg  _nb_kernel303_ia32_sse.nb303_outerstart
        jmp _nb_kernel303_ia32_sse.nb303_end

_nb_kernel303_ia32_sse.nb303_outerstart: 
        ## ebx contains number of outer iterations
        addl nb303_nouter(%esp),%ebx
        movl %ebx,nb303_nouter(%esp)

_nb_kernel303_ia32_sse.nb303_outer: 
        movl  nb303_shift(%ebp),%eax            ## eax = pointer into shift[] 
        movl  (%eax,%esi,4),%ebx                ## ebx=shift[n] 

        leal  (%ebx,%ebx,2),%ebx        ## ebx=3*is 
        movl  %ebx,nb303_is3(%esp)      ## store is3 

        movl  nb303_shiftvec(%ebp),%eax     ## eax = base of shiftvec[] 

        movss (%eax,%ebx,4),%xmm0
        movss 4(%eax,%ebx,4),%xmm1
        movss 8(%eax,%ebx,4),%xmm2

        movl  nb303_iinr(%ebp),%ecx             ## ecx = pointer into iinr[]    
        movl  (%ecx,%esi,4),%ebx                ## ebx =ii 

        movaps %xmm0,%xmm3
        movaps %xmm1,%xmm4
        movaps %xmm2,%xmm5

        leal  (%ebx,%ebx,2),%ebx        ## ebx = 3*ii=ii3 
        movl  nb303_pos(%ebp),%eax      ## eax = base of pos[]  
        movl  %ebx,nb303_ii3(%esp)

        addss 12(%eax,%ebx,4),%xmm3
        addss 16(%eax,%ebx,4),%xmm4
        addss 20(%eax,%ebx,4),%xmm5
        shufps $0,%xmm3,%xmm3
        shufps $0,%xmm4,%xmm4
        shufps $0,%xmm5,%xmm5
        movaps %xmm3,nb303_ixH1(%esp)
        movaps %xmm4,nb303_iyH1(%esp)
        movaps %xmm5,nb303_izH1(%esp)

        movss %xmm0,%xmm3
        movss %xmm1,%xmm4
        movss %xmm2,%xmm5
        addss 24(%eax,%ebx,4),%xmm0
        addss 28(%eax,%ebx,4),%xmm1
        addss 32(%eax,%ebx,4),%xmm2
        addss 36(%eax,%ebx,4),%xmm3
        addss 40(%eax,%ebx,4),%xmm4
        addss 44(%eax,%ebx,4),%xmm5

        shufps $0,%xmm0,%xmm0
        shufps $0,%xmm1,%xmm1
        shufps $0,%xmm2,%xmm2
        shufps $0,%xmm3,%xmm3
        shufps $0,%xmm4,%xmm4
        shufps $0,%xmm5,%xmm5
        movaps %xmm0,nb303_ixH2(%esp)
        movaps %xmm1,nb303_iyH2(%esp)
        movaps %xmm2,nb303_izH2(%esp)
        movaps %xmm3,nb303_ixM(%esp)
        movaps %xmm4,nb303_iyM(%esp)
        movaps %xmm5,nb303_izM(%esp)

        ## clear vctot and i forces 
        xorps %xmm4,%xmm4
        movaps %xmm4,nb303_vctot(%esp)
        movaps %xmm4,nb303_fixH1(%esp)
        movaps %xmm4,nb303_fiyH1(%esp)
        movaps %xmm4,nb303_fizH1(%esp)
        movaps %xmm4,nb303_fixH2(%esp)
        movaps %xmm4,nb303_fiyH2(%esp)
        movaps %xmm4,nb303_fizH2(%esp)
        movaps %xmm4,nb303_fixM(%esp)
        movaps %xmm4,nb303_fiyM(%esp)
        movaps %xmm4,nb303_fizM(%esp)

        movl  nb303_jindex(%ebp),%eax
        movl  (%eax,%esi,4),%ecx                ## jindex[n] 
        movl  4(%eax,%esi,4),%edx               ## jindex[n+1] 
        subl  %ecx,%edx                 ## number of innerloop atoms 

        movl  nb303_pos(%ebp),%esi
        movl  nb303_faction(%ebp),%edi
        movl  nb303_jjnr(%ebp),%eax
        shll  $2,%ecx
        addl  %ecx,%eax
        movl  %eax,nb303_innerjjnr(%esp)        ## pointer to jjnr[nj0] 
        movl  %edx,%ecx
        subl  $4,%edx
        addl  nb303_ninner(%esp),%ecx
        movl  %ecx,nb303_ninner(%esp)
        addl  $0,%edx
        movl  %edx,nb303_innerk(%esp)   ## number of innerloop atoms 
        jge   _nb_kernel303_ia32_sse.nb303_unroll_loop
        jmp   _nb_kernel303_ia32_sse.nb303_odd_inner
_nb_kernel303_ia32_sse.nb303_unroll_loop: 
        ## quad-unroll innerloop here 
        movl  nb303_innerjjnr(%esp),%edx        ## pointer to jjnr[k] 
        movl  (%edx),%eax
        movl  4(%edx),%ebx
        movl  8(%edx),%ecx
        movl  12(%edx),%edx             ## eax-edx=jnr1-4 

        addl $16,nb303_innerjjnr(%esp)             ## advance pointer (unrolled 4) 

        movl nb303_charge(%ebp),%esi    ## base of charge[] 

        movss (%esi,%eax,4),%xmm3
        movss (%esi,%ecx,4),%xmm4
        movss (%esi,%ebx,4),%xmm6
        movss (%esi,%edx,4),%xmm7

        shufps $0,%xmm6,%xmm3
        shufps $0,%xmm7,%xmm4
        shufps $136,%xmm4,%xmm3 ## 10001000 ;# all charges in xmm3  
        movaps %xmm3,%xmm4              ## and in xmm4 
        mulps  nb303_iqH(%esp),%xmm3
        mulps  nb303_iqM(%esp),%xmm4

        movaps  %xmm3,nb303_qqH(%esp)
        movaps  %xmm4,nb303_qqM(%esp)

        movl nb303_pos(%ebp),%esi       ## base of pos[] 

        leal  (%eax,%eax,2),%eax        ## replace jnr with j3 
        leal  (%ebx,%ebx,2),%ebx
        leal  (%ecx,%ecx,2),%ecx        ## replace jnr with j3 
        leal  (%edx,%edx,2),%edx

        ## move four coordinates to xmm0-xmm2   
        movlps (%esi,%eax,4),%xmm4
        movlps (%esi,%ecx,4),%xmm5
        movss 8(%esi,%eax,4),%xmm2
        movss 8(%esi,%ecx,4),%xmm6

        movhps (%esi,%ebx,4),%xmm4
        movhps (%esi,%edx,4),%xmm5

        movss 8(%esi,%ebx,4),%xmm0
        movss 8(%esi,%edx,4),%xmm1

        shufps $0,%xmm0,%xmm2
        shufps $0,%xmm1,%xmm6

        movaps %xmm4,%xmm0
        movaps %xmm4,%xmm1

        shufps $136,%xmm6,%xmm2 ## 10001000

        shufps $136,%xmm5,%xmm0 ## 10001000
        shufps $221,%xmm5,%xmm1 ## 11011101             

        ## move ixH1-izH1 to xmm4-xmm6 
        movaps nb303_ixH1(%esp),%xmm4
        movaps nb303_iyH1(%esp),%xmm5
        movaps nb303_izH1(%esp),%xmm6

        ## calc dr 
        subps %xmm0,%xmm4
        subps %xmm1,%xmm5
        subps %xmm2,%xmm6

        ## store dr 
        movaps %xmm4,nb303_dxH1(%esp)
        movaps %xmm5,nb303_dyH1(%esp)
        movaps %xmm6,nb303_dzH1(%esp)
        ## square it 
        mulps %xmm4,%xmm4
        mulps %xmm5,%xmm5
        mulps %xmm6,%xmm6
        addps %xmm5,%xmm4
        addps %xmm6,%xmm4
        movaps %xmm4,%xmm7
        ## rsqH1 in xmm7 

        ## move ixH2-izH2 to xmm4-xmm6 
        movaps nb303_ixH2(%esp),%xmm4
        movaps nb303_iyH2(%esp),%xmm5
        movaps nb303_izH2(%esp),%xmm6

        ## calc dr 
        subps %xmm0,%xmm4
        subps %xmm1,%xmm5
        subps %xmm2,%xmm6

        ## store dr 
        movaps %xmm4,nb303_dxH2(%esp)
        movaps %xmm5,nb303_dyH2(%esp)
        movaps %xmm6,nb303_dzH2(%esp)
        ## square it 
        mulps %xmm4,%xmm4
        mulps %xmm5,%xmm5
        mulps %xmm6,%xmm6