nb_kernel303_ia32_sse.s

来自「最著名最快的分子模拟软件」· S 代码 · 共 1,963 行 · 第 1/5 页

        popl %ecx
        popl %ebx
        popl %eax
        leave
        ret



.globl nb_kernel303nf_ia32_sse
.globl _nb_kernel303nf_ia32_sse
nb_kernel303nf_ia32_sse:        
_nb_kernel303nf_ia32_sse:       
.set nb303nf_p_nri, 8
.set nb303nf_iinr, 12
.set nb303nf_jindex, 16
.set nb303nf_jjnr, 20
.set nb303nf_shift, 24
.set nb303nf_shiftvec, 28
.set nb303nf_fshift, 32
.set nb303nf_gid, 36
.set nb303nf_pos, 40
.set nb303nf_faction, 44
.set nb303nf_charge, 48
.set nb303nf_p_facel, 52
.set nb303nf_argkrf, 56
.set nb303nf_argcrf, 60
.set nb303nf_Vc, 64
.set nb303nf_type, 68
.set nb303nf_p_ntype, 72
.set nb303nf_vdwparam, 76
.set nb303nf_Vvdw, 80
.set nb303nf_p_tabscale, 84
.set nb303nf_VFtab, 88
.set nb303nf_invsqrta, 92
.set nb303nf_dvda, 96
.set nb303nf_p_gbtabscale, 100
.set nb303nf_GBtab, 104
.set nb303nf_p_nthreads, 108
.set nb303nf_count, 112
.set nb303nf_mtx, 116
.set nb303nf_outeriter, 120
.set nb303nf_inneriter, 124
.set nb303nf_work, 128
        ## stack offsets for local variables  
        ## bottom of stack is cache-aligned for sse use 
.set nb303nf_ixH1, 0
.set nb303nf_iyH1, 16
.set nb303nf_izH1, 32
.set nb303nf_ixH2, 48
.set nb303nf_iyH2, 64
.set nb303nf_izH2, 80
.set nb303nf_ixM, 96
.set nb303nf_iyM, 112
.set nb303nf_izM, 128
.set nb303nf_iqH, 144
.set nb303nf_iqM, 160
.set nb303nf_qqH, 176
.set nb303nf_qqM, 192
.set nb303nf_rinvH1, 208
.set nb303nf_rinvH2, 224
.set nb303nf_rinvM, 240
.set nb303nf_rH1, 256
.set nb303nf_rH2, 272
.set nb303nf_rM, 288
.set nb303nf_tsc, 304
.set nb303nf_vctot, 320
.set nb303nf_half, 336
.set nb303nf_three, 352
.set nb303nf_is3, 368
.set nb303nf_ii3, 372
.set nb303nf_innerjjnr, 376
.set nb303nf_innerk, 380
.set nb303nf_n, 384
.set nb303nf_nn1, 388
.set nb303nf_nri, 392
.set nb303nf_nouter, 396
.set nb303nf_ninner, 400
.set nb303nf_salign, 404
        pushl %ebp
        movl %esp,%ebp
        pushl %eax
        pushl %ebx
        pushl %ecx
        pushl %edx
        pushl %esi
        pushl %edi
        subl $408,%esp          ## local stack space 
        movl %esp,%eax
        andl $0xf,%eax
        subl %eax,%esp
        movl %eax,nb303nf_salign(%esp)

        emms

        ## Move args passed by reference to stack
        movl nb303nf_p_nri(%ebp),%ecx
        movl (%ecx),%ecx
        movl %ecx,nb303nf_nri(%esp)

        ## zero iteration counters
        movl $0,%eax
        movl %eax,nb303nf_nouter(%esp)
        movl %eax,nb303nf_ninner(%esp)


        movl nb303nf_p_tabscale(%ebp),%eax
        movss (%eax),%xmm3
        shufps $0,%xmm3,%xmm3
        movaps %xmm3,nb303nf_tsc(%esp)
        ## create constant floating-point factors on stack
        movl $0x3f000000,%eax   ## constant 0.5 in IEEE (hex)
        movl %eax,nb303nf_half(%esp)
        movss nb303nf_half(%esp),%xmm1
        shufps $0,%xmm1,%xmm1  ## splat to all elements
        movaps %xmm1,%xmm2
        addps  %xmm2,%xmm2      ## 1.0
        movaps %xmm2,%xmm3
        addps  %xmm2,%xmm2      ## 2.0
        addps  %xmm2,%xmm3      ## 3.0
        movaps %xmm1,nb303nf_half(%esp)
        movaps %xmm3,nb303nf_three(%esp)

        ## assume we have at least one i particle - start directly 
        movl  nb303nf_iinr(%ebp),%ecx           ## ecx = pointer into iinr[]    
        movl  (%ecx),%ebx               ## ebx =ii 

        movl  nb303nf_charge(%ebp),%edx
        movss 4(%edx,%ebx,4),%xmm3
        movss 12(%edx,%ebx,4),%xmm4
        movl nb303nf_p_facel(%ebp),%esi
        movss (%esi),%xmm5
        mulss  %xmm5,%xmm3
        mulss  %xmm5,%xmm4

        shufps $0,%xmm3,%xmm3
        shufps $0,%xmm4,%xmm4
        movaps %xmm3,nb303nf_iqH(%esp)
        movaps %xmm4,nb303nf_iqM(%esp)

_nb_kernel303nf_ia32_sse.nb303nf_threadloop: 
        movl  nb303nf_count(%ebp),%esi            ## pointer to sync counter
        movl  (%esi),%eax
_nb_kernel303nf_ia32_sse.nb303nf_spinlock: 
        movl  %eax,%ebx                         ## ebx=*count=nn0
        addl  $1,%ebx                          ## ebx=nn1=nn0+10
        lock 
        cmpxchgl %ebx,(%esi)                    ## write nn1 to *counter,
                                                ## if it hasnt changed.
                                                ## or reread *counter to eax.
        pause                                   ## -> better p4 performance
        jnz _nb_kernel303nf_ia32_sse.nb303nf_spinlock

        ## if(nn1>nri) nn1=nri
        movl nb303nf_nri(%esp),%ecx
        movl %ecx,%edx
        subl %ebx,%ecx
        cmovlel %edx,%ebx                       ## if(nn1>nri) nn1=nri
        ## Cleared the spinlock if we got here.
        ## eax contains nn0, ebx contains nn1.
        movl %eax,nb303nf_n(%esp)
        movl %ebx,nb303nf_nn1(%esp)
        subl %eax,%ebx                          ## calc number of outer lists
        movl %eax,%esi                          ## copy n to esi
        jg  _nb_kernel303nf_ia32_sse.nb303nf_outerstart
        jmp _nb_kernel303nf_ia32_sse.nb303nf_end

_nb_kernel303nf_ia32_sse.nb303nf_outerstart: 
        ## ebx contains number of outer iterations
        addl nb303nf_nouter(%esp),%ebx
        movl %ebx,nb303nf_nouter(%esp)

_nb_kernel303nf_ia32_sse.nb303nf_outer: 
        movl  nb303nf_shift(%ebp),%eax          ## eax = pointer into shift[] 
        movl  (%eax,%esi,4),%ebx                ## ebx=shift[n] 

        leal  (%ebx,%ebx,2),%ebx        ## ebx=3*is 
        movl  %ebx,nb303nf_is3(%esp)            ## store is3 

        movl  nb303nf_shiftvec(%ebp),%eax     ## eax = base of shiftvec[] 

        movss (%eax,%ebx,4),%xmm0
        movss 4(%eax,%ebx,4),%xmm1
        movss 8(%eax,%ebx,4),%xmm2

        movl  nb303nf_iinr(%ebp),%ecx           ## ecx = pointer into iinr[]    
        movl  (%ecx,%esi,4),%ebx                ## ebx =ii 

        movaps %xmm0,%xmm3
        movaps %xmm1,%xmm4
        movaps %xmm2,%xmm5

        leal  (%ebx,%ebx,2),%ebx        ## ebx = 3*ii=ii3 
        movl  nb303nf_pos(%ebp),%eax    ## eax = base of pos[]  
        movl  %ebx,nb303nf_ii3(%esp)

        addss 12(%eax,%ebx,4),%xmm3
        addss 16(%eax,%ebx,4),%xmm4
        addss 20(%eax,%ebx,4),%xmm5
        shufps $0,%xmm3,%xmm3
        shufps $0,%xmm4,%xmm4
        shufps $0,%xmm5,%xmm5
        movaps %xmm3,nb303nf_ixH1(%esp)
        movaps %xmm4,nb303nf_iyH1(%esp)
        movaps %xmm5,nb303nf_izH1(%esp)

        movss %xmm0,%xmm3
        movss %xmm1,%xmm4
        movss %xmm2,%xmm5
        addss 24(%eax,%ebx,4),%xmm0
        addss 28(%eax,%ebx,4),%xmm1
        addss 32(%eax,%ebx,4),%xmm2
        addss 36(%eax,%ebx,4),%xmm3
        addss 40(%eax,%ebx,4),%xmm4
        addss 44(%eax,%ebx,4),%xmm5

        shufps $0,%xmm0,%xmm0
        shufps $0,%xmm1,%xmm1
        shufps $0,%xmm2,%xmm2
        shufps $0,%xmm3,%xmm3
        shufps $0,%xmm4,%xmm4
        shufps $0,%xmm5,%xmm5
        movaps %xmm0,nb303nf_ixH2(%esp)
        movaps %xmm1,nb303nf_iyH2(%esp)
        movaps %xmm2,nb303nf_izH2(%esp)
        movaps %xmm3,nb303nf_ixM(%esp)
        movaps %xmm4,nb303nf_iyM(%esp)
        movaps %xmm5,nb303nf_izM(%esp)

        ## clear vctot 
        xorps %xmm4,%xmm4
        movaps %xmm4,nb303nf_vctot(%esp)

        movl  nb303nf_jindex(%ebp),%eax
        movl  (%eax,%esi,4),%ecx                ## jindex[n] 
        movl  4(%eax,%esi,4),%edx               ## jindex[n+1] 
        subl  %ecx,%edx                 ## number of innerloop atoms 

        movl  nb303nf_pos(%ebp),%esi
        movl  nb303nf_faction(%ebp),%edi
        movl  nb303nf_jjnr(%ebp),%eax
        shll  $2,%ecx
        addl  %ecx,%eax
        movl  %eax,nb303nf_innerjjnr(%esp)      ## pointer to jjnr[nj0] 
        movl  %edx,%ecx
        subl  $4,%edx
        addl  nb303nf_ninner(%esp),%ecx
        movl  %ecx,nb303nf_ninner(%esp)
        addl  $0,%edx
        movl  %edx,nb303nf_innerk(%esp)         ## number of innerloop atoms 
        jge   _nb_kernel303nf_ia32_sse.nb303nf_unroll_loop
        jmp   _nb_kernel303nf_ia32_sse.nb303nf_odd_inner
_nb_kernel303nf_ia32_sse.nb303nf_unroll_loop: 
        ## quad-unroll innerloop here 
        movl  nb303nf_innerjjnr(%esp),%edx      ## pointer to jjnr[k] 
        movl  (%edx),%eax
        movl  4(%edx),%ebx
        movl  8(%edx),%ecx
        movl  12(%edx),%edx             ## eax-edx=jnr1-4 

        addl $16,nb303nf_innerjjnr(%esp)             ## advance pointer (unrolled 4) 

        movl nb303nf_charge(%ebp),%esi  ## base of charge[] 

        movss (%esi,%eax,4),%xmm3
        movss (%esi,%ecx,4),%xmm4
        movss (%esi,%ebx,4),%xmm6
        movss (%esi,%edx,4),%xmm7

        shufps $0,%xmm6,%xmm3
        shufps $0,%xmm7,%xmm4
        shufps $136,%xmm4,%xmm3 ## 10001000 ;# all charges in xmm3  
        movaps %xmm3,%xmm4              ## and in xmm4 
        mulps  nb303nf_iqH(%esp),%xmm3
        mulps  nb303nf_iqM(%esp),%xmm4

        movd  %eax,%mm0         ## use mmx registers as temp storage 
        movd  %ebx,%mm1
        movd  %ecx,%mm2
        movd  %edx,%mm3

        movaps  %xmm3,nb303nf_qqH(%esp)
        movaps  %xmm4,nb303nf_qqM(%esp)

        movl nb303nf_pos(%ebp),%esi     ## base of pos[] 

        leal  (%eax,%eax,2),%eax        ## replace jnr with j3 
        leal  (%ebx,%ebx,2),%ebx
        leal  (%ecx,%ecx,2),%ecx        ## replace jnr with j3 
        leal  (%edx,%edx,2),%edx

        ## move four coordinates to xmm0-xmm2   
        movlps (%esi,%eax,4),%xmm4
        movlps (%esi,%ecx,4),%xmm5
        movss 8(%esi,%eax,4),%xmm2
        movss 8(%esi,%ecx,4),%xmm6

        movhps (%esi,%ebx,4),%xmm4
        movhps (%esi,%edx,4),%xmm5

        movss 8(%esi,%ebx,4),%xmm0
        movss 8(%esi,%edx,4),%xmm1

        shufps $0,%xmm0,%xmm2
        shufps $0,%xmm1,%xmm6

        movaps %xmm4,%xmm0
        movaps %xmm4,%xmm1

        shufps $136,%xmm6,%xmm2 ## 10001000

        shufps $136,%xmm5,%xmm0 ## 10001000
        shufps $221,%xmm5,%xmm1 ## 11011101             

        ## move ixH1-izH1 to xmm4-xmm6 
        movaps nb303nf_ixH1(%esp),%xmm4
        movaps nb303nf_iyH1(%esp),%xmm5
        movaps nb303nf_izH1(%esp),%xmm6

        ## calc dr 
        subps %xmm0,%xmm4
        subps %xmm1,%xmm5
        subps %xmm2,%xmm6

        ## square it 
        mulps %xmm4,%xmm4
        mulps %xmm5,%xmm5
        mulps %xmm6,%xmm6
        addps %xmm5,%xmm4
        addps %xmm6,%xmm4
        movaps %xmm4,%xmm7
        ## rsqH1 in xmm7 

        ## move ixH2-izH2 to xmm4-xmm6 
        movaps nb303nf_ixH2(%esp),%xmm4
        movaps nb303nf_iyH2(%esp),%xmm5
        movaps nb303nf_izH2(%esp),%xmm6

        ## calc dr 
        subps %xmm0,%xmm4
        subps %xmm1,%xmm5
        subps %xmm2,%xmm6

        ## square it 
        mulps %xmm4,%xmm4
        mulps %xmm5,%xmm5
        mulps %xmm6,%xmm6
        addps %xmm5,%xmm6
        addps %xmm4,%xmm6
        ## rsqH2 in xmm6 

        ## move ixM-izM to xmm3-xmm5  
        movaps nb303nf_ixM(%esp),%xmm3
        movaps nb303nf_iyM(%esp),%xmm4
        movaps nb303nf_izM(%esp),%xmm5

        ## calc dr 
        subps %xmm0,%xmm3
        subps %xmm1,%xmm4
        subps %xmm2,%xmm5

        ## square it 
        mulps %xmm3,%xmm3
        mulps %xmm4,%xmm4
        mulps %xmm5,%xmm5
        addps %xmm4,%xmm5
        addps %xmm3,%xmm5
        ## rsqM in xmm5, rsqH2 in xmm6, rsqH1 in xmm7 

        ## start with rsqH1 - seed to xmm2      
        rsqrtps %xmm7,%xmm2
        movaps  %xmm2,%xmm3
        mulps   %xmm2,%xmm2
        movaps  nb303nf_three(%esp),%xmm4
        mulps   %xmm7,%xmm2     ## rsq*lu*lu 
        subps   %xmm2,%xmm4     ## 30-rsq*lu*lu 
        mulps   %xmm3,%xmm4     ## lu*(3-rsq*lu*lu) 
        mulps   nb303nf_half(%esp),%xmm4
        movaps  %xmm4,nb303nf_rinvH1(%esp)      ## rinvH1 in xmm4 
        mulps   %xmm4,%xmm7
        movaps  %xmm7,nb303nf_rH1(%esp)

        ## rsqH2 - seed in xmm2 
        rsqrtps %xmm6,%xmm2
        movaps  %xmm2,%xmm3
        mulps   %xmm2,%xmm2
        movaps  nb303nf_three(%esp),%xmm4
        mulps   %xmm6,%xmm2     ## rsq*lu*lu 
        subps   %xmm2,%xmm4     ## 30-rsq*lu*lu 
        mulps   %xmm3,%xmm4     ## lu*(3-rsq*lu*lu) 
        mulps   nb303nf_half(%esp),%xmm4
        movaps  %xmm4,nb303nf_rinvH2(%esp)      ## rinvH2 in xmm4 
        mulps   %xmm4,%xmm6
        movaps  %xmm6,nb303nf_rH2(%esp)