nb_kernel310_ia32_sse.s

来自「最著名最快的分子模拟软件」· S 代码 · 共 1,824 行 · 第 1/4 页

##
## $Id: nb_kernel310_ia32_sse.s,v 1.1.2.2 2007/11/28 09:36:34 spoel Exp $
##
## Gromacs 4.0                         Copyright (c) 1991-2003 
## David van der Spoel, Erik Lindahl
##
## This program is free software; you can redistribute it and/or
## modify it under the terms of the GNU General Public License
## as published by the Free Software Foundation; either version 2
## of the License, or (at your option) any later version.
##
## To help us fund GROMACS development, we humbly ask that you cite
## the research papers on the package. Check out http://www.gromacs.org
## 
## And Hey:
## Gnomes, ROck Monsters And Chili Sauce
##



.globl nb_kernel310_ia32_sse
.globl _nb_kernel310_ia32_sse
nb_kernel310_ia32_sse:  
_nb_kernel310_ia32_sse: 
.set nb310_p_nri, 8
.set nb310_iinr, 12
.set nb310_jindex, 16
.set nb310_jjnr, 20
.set nb310_shift, 24
.set nb310_shiftvec, 28
.set nb310_fshift, 32
.set nb310_gid, 36
.set nb310_pos, 40
.set nb310_faction, 44
.set nb310_charge, 48
.set nb310_p_facel, 52
.set nb310_argkrf, 56
.set nb310_argcrf, 60
.set nb310_Vc, 64
.set nb310_type, 68
.set nb310_p_ntype, 72
.set nb310_vdwparam, 76
.set nb310_Vvdw, 80
.set nb310_p_tabscale, 84
.set nb310_VFtab, 88
.set nb310_invsqrta, 92
.set nb310_dvda, 96
.set nb310_p_gbtabscale, 100
.set nb310_GBtab, 104
.set nb310_p_nthreads, 108
.set nb310_count, 112
.set nb310_mtx, 116
.set nb310_outeriter, 120
.set nb310_inneriter, 124
.set nb310_work, 128
        ## stack offsets for local variables  
        ## bottom of stack is cache-aligned for sse use 
.set nb310_ix, 0
.set nb310_iy, 16
.set nb310_iz, 32
.set nb310_iq, 48
.set nb310_dx, 64
.set nb310_dy, 80
.set nb310_dz, 96
.set nb310_two, 112
.set nb310_six, 128
.set nb310_twelve, 144
.set nb310_tsc, 160
.set nb310_qq, 176
.set nb310_c6, 192
.set nb310_c12, 208
.set nb310_fscal, 224
.set nb310_vctot, 240
.set nb310_Vvdwtot, 256
.set nb310_fix, 272
.set nb310_fiy, 288
.set nb310_fiz, 304
.set nb310_half, 320
.set nb310_three, 336
.set nb310_is3, 352
.set nb310_ii3, 356
.set nb310_ntia, 360
.set nb310_innerjjnr, 364
.set nb310_innerk, 368
.set nb310_n, 372
.set nb310_nn1, 376
.set nb310_nri, 380
.set nb310_facel, 384
.set nb310_ntype, 388
.set nb310_nouter, 392
.set nb310_ninner, 396
.set nb310_salign, 400
        pushl %ebp
        movl %esp,%ebp
        pushl %eax
        pushl %ebx
        pushl %ecx
        pushl %edx
        pushl %esi
        pushl %edi
        subl $404,%esp          ## local stack space 
        movl %esp,%eax
        andl $0xf,%eax
        subl %eax,%esp
        movl %eax,nb310_salign(%esp)

        emms

        ## Move args passed by reference to stack
        movl nb310_p_nri(%ebp),%ecx
        movl nb310_p_facel(%ebp),%esi
        movl nb310_p_ntype(%ebp),%edi
        movl (%ecx),%ecx
        movl (%esi),%esi
        movl (%edi),%edi
        movl %ecx,nb310_nri(%esp)
        movl %esi,nb310_facel(%esp)
        movl %edi,nb310_ntype(%esp)

        ## zero iteration counters
        movl $0,%eax
        movl %eax,nb310_nouter(%esp)
        movl %eax,nb310_ninner(%esp)


        movl nb310_p_tabscale(%ebp),%eax
        movss (%eax),%xmm5
        shufps $0,%xmm5,%xmm5
        movaps %xmm5,nb310_tsc(%esp)

        ## create constant floating-point factors on stack
        movl $0x3f000000,%eax   ## constant 0.5 in IEEE (hex)
        movl %eax,nb310_half(%esp)
        movss nb310_half(%esp),%xmm1
        shufps $0,%xmm1,%xmm1  ## splat to all elements
        movaps %xmm1,%xmm2
        addps  %xmm2,%xmm2      ## constant 1.0
        movaps %xmm2,%xmm3
        addps  %xmm2,%xmm2      ## constant 2.0
        addps  %xmm2,%xmm3      ## constant 3.0
        movaps %xmm3,%xmm4
        addps  %xmm4,%xmm4      ## 6.0
        movaps %xmm4,%xmm5
        addps  %xmm5,%xmm5      ## constant 12.0
        movaps %xmm1,nb310_half(%esp)
        movaps %xmm2,nb310_two(%esp)
        movaps %xmm3,nb310_three(%esp)
        movaps %xmm4,nb310_six(%esp)
        movaps %xmm5,nb310_twelve(%esp)

_nb_kernel310_ia32_sse.nb310_threadloop: 
        movl  nb310_count(%ebp),%esi            ## pointer to sync counter
        movl  (%esi),%eax
_nb_kernel310_ia32_sse.nb310_spinlock: 
        movl  %eax,%ebx                         ## ebx=*count=nn0
        addl  $1,%ebx                          ## ebx=nn1=nn0+10
        lock 
        cmpxchgl %ebx,(%esi)                    ## write nn1 to *counter,
                                                ## if it hasnt changed.
                                                ## or reread *counter to eax.
        pause                                   ## -> better p4 performance
        jnz _nb_kernel310_ia32_sse.nb310_spinlock

        ## if(nn1>nri) nn1=nri
        movl nb310_nri(%esp),%ecx
        movl %ecx,%edx
        subl %ebx,%ecx
        cmovlel %edx,%ebx                       ## if(nn1>nri) nn1=nri
        ## Cleared the spinlock if we got here.
        ## eax contains nn0, ebx contains nn1.
        movl %eax,nb310_n(%esp)
        movl %ebx,nb310_nn1(%esp)
        subl %eax,%ebx                          ## calc number of outer lists
        movl %eax,%esi                          ## copy n to esi
        jg  _nb_kernel310_ia32_sse.nb310_outerstart
        jmp _nb_kernel310_ia32_sse.nb310_end

_nb_kernel310_ia32_sse.nb310_outerstart: 
        ## ebx contains number of outer iterations
        addl nb310_nouter(%esp),%ebx
        movl %ebx,nb310_nouter(%esp)

_nb_kernel310_ia32_sse.nb310_outer: 
        movl  nb310_shift(%ebp),%eax        ## eax = pointer into shift[] 
        movl  (%eax,%esi,4),%ebx        ## ebx=shift[n] 

        leal  (%ebx,%ebx,2),%ebx    ## ebx=3*is 
        movl  %ebx,nb310_is3(%esp)      ## store is3 

        movl  nb310_shiftvec(%ebp),%eax     ## eax = base of shiftvec[] 

        movss (%eax,%ebx,4),%xmm0
        movss 4(%eax,%ebx,4),%xmm1
        movss 8(%eax,%ebx,4),%xmm2

        movl  nb310_iinr(%ebp),%ecx         ## ecx = pointer into iinr[]        
        movl  (%ecx,%esi,4),%ebx            ## ebx =ii 

        movl  nb310_charge(%ebp),%edx
        movss (%edx,%ebx,4),%xmm3
        mulss nb310_facel(%esp),%xmm3
        shufps $0,%xmm3,%xmm3

        movl  nb310_type(%ebp),%edx
        movl  (%edx,%ebx,4),%edx
        imull nb310_ntype(%esp),%edx
        shll  %edx
        movl  %edx,nb310_ntia(%esp)

        leal  (%ebx,%ebx,2),%ebx        ## ebx = 3*ii=ii3 
        movl  nb310_pos(%ebp),%eax      ## eax = base of pos[]  

        addss (%eax,%ebx,4),%xmm0
        addss 4(%eax,%ebx,4),%xmm1
        addss 8(%eax,%ebx,4),%xmm2

        movaps %xmm3,nb310_iq(%esp)

        shufps $0,%xmm0,%xmm0
        shufps $0,%xmm1,%xmm1
        shufps $0,%xmm2,%xmm2

        movaps %xmm0,nb310_ix(%esp)
        movaps %xmm1,nb310_iy(%esp)
        movaps %xmm2,nb310_iz(%esp)

        movl  %ebx,nb310_ii3(%esp)

        ## clear vctot and i forces 
        xorps %xmm4,%xmm4
        movaps %xmm4,nb310_vctot(%esp)
        movaps %xmm4,nb310_Vvdwtot(%esp)
        movaps %xmm4,nb310_fix(%esp)
        movaps %xmm4,nb310_fiy(%esp)
        movaps %xmm4,nb310_fiz(%esp)

        movl  nb310_jindex(%ebp),%eax
        movl  (%eax,%esi,4),%ecx             ## jindex[n] 
        movl  4(%eax,%esi,4),%edx            ## jindex[n+1] 
        subl  %ecx,%edx              ## number of innerloop atoms 

        movl  nb310_pos(%ebp),%esi
        movl  nb310_faction(%ebp),%edi
        movl  nb310_jjnr(%ebp),%eax
        shll  $2,%ecx
        addl  %ecx,%eax
        movl  %eax,nb310_innerjjnr(%esp)       ## pointer to jjnr[nj0] 
        movl  %edx,%ecx
        subl  $4,%edx
        addl  nb310_ninner(%esp),%ecx
        movl  %ecx,nb310_ninner(%esp)
        addl  $0,%edx
        movl  %edx,nb310_innerk(%esp)      ## number of innerloop atoms 
        jge   _nb_kernel310_ia32_sse.nb310_unroll_loop
        jmp   _nb_kernel310_ia32_sse.nb310_finish_inner
_nb_kernel310_ia32_sse.nb310_unroll_loop: 
        ## quad-unroll innerloop here 
        movl  nb310_innerjjnr(%esp),%edx       ## pointer to jjnr[k] 
        movl  (%edx),%eax
        movl  4(%edx),%ebx
        movl  8(%edx),%ecx
        movl  12(%edx),%edx           ## eax-edx=jnr1-4 
        addl $16,nb310_innerjjnr(%esp)             ## advance pointer (unrolled 4) 

        movl nb310_charge(%ebp),%esi     ## base of charge[] 

        movss (%esi,%eax,4),%xmm3
        movss (%esi,%ecx,4),%xmm4
        movss (%esi,%ebx,4),%xmm6
        movss (%esi,%edx,4),%xmm7

        movaps nb310_iq(%esp),%xmm2
        shufps $0,%xmm6,%xmm3
        shufps $0,%xmm7,%xmm4
        shufps $136,%xmm4,%xmm3 ## constant 10001000 ;# all charges in xmm3  
        movd  %eax,%mm0         ## use mmx registers as temp storage 
        movd  %ebx,%mm1
        mulps  %xmm2,%xmm3
        movd  %ecx,%mm2
        movd  %edx,%mm3

        movaps %xmm3,nb310_qq(%esp)

        movl nb310_type(%ebp),%esi
        movl (%esi,%eax,4),%eax
        movl (%esi,%ebx,4),%ebx
        movl (%esi,%ecx,4),%ecx
        movl (%esi,%edx,4),%edx
        movl nb310_vdwparam(%ebp),%esi
        shll %eax
        shll %ebx
        shll %ecx
        shll %edx
        movl nb310_ntia(%esp),%edi
        addl %edi,%eax
        addl %edi,%ebx
        addl %edi,%ecx
        addl %edi,%edx

        movlps (%esi,%eax,4),%xmm6
        movlps (%esi,%ecx,4),%xmm7
        movhps (%esi,%ebx,4),%xmm6
        movhps (%esi,%edx,4),%xmm7

        movaps %xmm6,%xmm4
        shufps $136,%xmm7,%xmm4 ## constant 10001000
        shufps $221,%xmm7,%xmm6 ## constant 11011101

        movd  %mm0,%eax
        movd  %mm1,%ebx
        movd  %mm2,%ecx
        movd  %mm3,%edx

        movaps %xmm4,nb310_c6(%esp)
        movaps %xmm6,nb310_c12(%esp)

        movl nb310_pos(%ebp),%esi        ## base of pos[] 

        leal  (%eax,%eax,2),%eax     ## replace jnr with j3 
        leal  (%ebx,%ebx,2),%ebx

        leal  (%ecx,%ecx,2),%ecx     ## replace jnr with j3 
        leal  (%edx,%edx,2),%edx

        ## move four coordinates to xmm0-xmm2   

        movlps (%esi,%eax,4),%xmm4
        movlps (%esi,%ecx,4),%xmm5
        movss 8(%esi,%eax,4),%xmm2
        movss 8(%esi,%ecx,4),%xmm6

        movhps (%esi,%ebx,4),%xmm4
        movhps (%esi,%edx,4),%xmm5

        movss 8(%esi,%ebx,4),%xmm0
        movss 8(%esi,%edx,4),%xmm1

        shufps $0,%xmm0,%xmm2
        shufps $0,%xmm1,%xmm6

        movaps %xmm4,%xmm0
        movaps %xmm4,%xmm1

        shufps $136,%xmm6,%xmm2 ## constant 10001000

        shufps $136,%xmm5,%xmm0 ## constant 10001000
        shufps $221,%xmm5,%xmm1 ## constant 11011101            

        ## move ix-iz to xmm4-xmm6 
        movaps nb310_ix(%esp),%xmm4
        movaps nb310_iy(%esp),%xmm5
        movaps nb310_iz(%esp),%xmm6

        ## calc dr 
        subps %xmm0,%xmm4
        subps %xmm1,%xmm5
        subps %xmm2,%xmm6

        ## store dr 
        movaps %xmm4,nb310_dx(%esp)
        movaps %xmm5,nb310_dy(%esp)
        movaps %xmm6,nb310_dz(%esp)
        ## square it 
        mulps %xmm4,%xmm4
        mulps %xmm5,%xmm5
        mulps %xmm6,%xmm6
        addps %xmm5,%xmm4
        addps %xmm6,%xmm4
        ## rsq in xmm4 

        rsqrtps %xmm4,%xmm5
        ## lookup seed in xmm5 
        movaps %xmm5,%xmm2
        mulps %xmm5,%xmm5
        movaps nb310_three(%esp),%xmm1
        mulps %xmm4,%xmm5       ## rsq*lu*lu                    
        movaps nb310_half(%esp),%xmm0
        subps %xmm5,%xmm1       ## constant 30-rsq*lu*lu 
        mulps %xmm2,%xmm1
        mulps %xmm1,%xmm0       ## xmm0=rinv 
        mulps %xmm0,%xmm4       ## xmm4=r 
        mulps nb310_tsc(%esp),%xmm4

        movhlps %xmm4,%xmm5
        cvttps2pi %xmm4,%mm6
        cvttps2pi %xmm5,%mm7    ## mm6/mm7 contain lu indices 
        cvtpi2ps %mm6,%xmm6
        cvtpi2ps %mm7,%xmm5
        movlhps %xmm5,%xmm6
        subps %xmm6,%xmm4
        movaps %xmm4,%xmm1      ## xmm1=eps 
        movaps %xmm1,%xmm2
        mulps  %xmm2,%xmm2      ## xmm2=eps2 
        pslld $2,%mm6
        pslld $2,%mm7

        movd %eax,%mm0
        movd %ebx,%mm1
        movd %ecx,%mm2
        movd %edx,%mm3

        movl nb310_VFtab(%ebp),%esi
        movd %mm6,%eax
        psrlq $32,%mm6
        movd %mm7,%ecx
        psrlq $32,%mm7
        movd %mm6,%ebx
        movd %mm7,%edx

        movlps (%esi,%eax,4),%xmm5
        movlps (%esi,%ecx,4),%xmm7
        movhps (%esi,%ebx,4),%xmm5
        movhps (%esi,%edx,4),%xmm7 ## got half coulomb table 

        movaps %xmm5,%xmm4
        shufps $136,%xmm7,%xmm4 ## constant 10001000
        shufps $221,%xmm7,%xmm5 ## constant 11011101

        movlps 8(%esi,%eax,4),%xmm7
        movlps 8(%esi,%ecx,4),%xmm3
        movhps 8(%esi,%ebx,4),%xmm7
        movhps 8(%esi,%edx,4),%xmm3    ## other half of coulomb table  
        movaps %xmm7,%xmm6
        shufps $136,%xmm3,%xmm6 ## constant 10001000
        shufps $221,%xmm3,%xmm7 ## constant 11011101
        ## coulomb table ready, in xmm4-xmm7    

        mulps  %xmm1,%xmm6      ## xmm6=Geps 
        mulps  %xmm2,%xmm7      ## xmm7=Heps2 
        addps  %xmm6,%xmm5
        addps  %xmm7,%xmm5      ## xmm5=Fp      
        mulps  nb310_two(%esp),%xmm7    ## two*Heps2 
        movaps nb310_qq(%esp),%xmm3
        addps  %xmm6,%xmm7
        addps  %xmm5,%xmm7 ## xmm7=FF 
        mulps  %xmm1,%xmm5 ## xmm5=eps*Fp 
        addps  %xmm4,%xmm5 ## xmm5=VV 
        mulps  %xmm3,%xmm5 ## vcoul=qq*VV  
        mulps  %xmm7,%xmm3 ## fijC=FF*qq 
        ## L-J 
        movaps %xmm0,%xmm4
        mulps  %xmm0,%xmm4      ## xmm4=rinvsq 

        ## at this point mm5 contains vcoul and mm3 fijC 
        ## increment vcoul - then we can get rid of mm5 
        ## update vctot 
        addps  nb310_vctot(%esp),%xmm5

        movaps %xmm4,%xmm6
        mulps  %xmm4,%xmm6

        movaps %xmm5,nb310_vctot(%esp)

        mulps  %xmm4,%xmm6      ## xmm6=rinvsix 
        movaps %xmm6,%xmm4
        mulps  %xmm4,%xmm4      ## xmm4=rinvtwelve