nb_kernel310_ia32_sse.s

来自「最著名最快的分子模拟软件」· S 代码 · 共 1,824 行 · 第 1/4 页

        ## update fj 

        movss   (%edi,%eax,4),%xmm3
        movss   4(%edi,%eax,4),%xmm4
        movss   8(%edi,%eax,4),%xmm5
        subss   %xmm0,%xmm3
        subss   %xmm1,%xmm4
        subss   %xmm2,%xmm5
        movss   %xmm3,(%edi,%eax,4)
        movss   %xmm4,4(%edi,%eax,4)
        movss   %xmm5,8(%edi,%eax,4)
_nb_kernel310_ia32_sse.nb310_updateouterdata: 
        movl  nb310_ii3(%esp),%ecx
        movl  nb310_faction(%ebp),%edi
        movl  nb310_fshift(%ebp),%esi
        movl  nb310_is3(%esp),%edx

        ## accumulate i forces in xmm0, xmm1, xmm2 
        movaps nb310_fix(%esp),%xmm0
        movaps nb310_fiy(%esp),%xmm1
        movaps nb310_fiz(%esp),%xmm2

        movhlps %xmm0,%xmm3
        movhlps %xmm1,%xmm4
        movhlps %xmm2,%xmm5
        addps  %xmm3,%xmm0
        addps  %xmm4,%xmm1
        addps  %xmm5,%xmm2 ## sum is in 1/2 in xmm0-xmm2 

        movaps %xmm0,%xmm3
        movaps %xmm1,%xmm4
        movaps %xmm2,%xmm5

        shufps $1,%xmm3,%xmm3
        shufps $1,%xmm4,%xmm4
        shufps $1,%xmm5,%xmm5
        addss  %xmm3,%xmm0
        addss  %xmm4,%xmm1
        addss  %xmm5,%xmm2      ## xmm0-xmm2 has single force in pos0 

        ## increment i force 
        movss  (%edi,%ecx,4),%xmm3
        movss  4(%edi,%ecx,4),%xmm4
        movss  8(%edi,%ecx,4),%xmm5
        addss  %xmm0,%xmm3
        addss  %xmm1,%xmm4
        addss  %xmm2,%xmm5
        movss  %xmm3,(%edi,%ecx,4)
        movss  %xmm4,4(%edi,%ecx,4)
        movss  %xmm5,8(%edi,%ecx,4)

        ## increment fshift force  
        movss  (%esi,%edx,4),%xmm3
        movss  4(%esi,%edx,4),%xmm4
        movss  8(%esi,%edx,4),%xmm5
        addss  %xmm0,%xmm3
        addss  %xmm1,%xmm4
        addss  %xmm2,%xmm5
        movss  %xmm3,(%esi,%edx,4)
        movss  %xmm4,4(%esi,%edx,4)
        movss  %xmm5,8(%esi,%edx,4)

        ## get n from stack
        movl nb310_n(%esp),%esi
        ## get group index for i particle 
        movl  nb310_gid(%ebp),%edx              ## base of gid[]
        movl  (%edx,%esi,4),%edx                ## ggid=gid[n]

        ## accumulate total potential energy and update it 
        movaps nb310_vctot(%esp),%xmm7
        ## accumulate 
        movhlps %xmm7,%xmm6
        addps  %xmm6,%xmm7      ## pos 0-1 in xmm7 have the sum now 
        movaps %xmm7,%xmm6
        shufps $1,%xmm6,%xmm6
        addss  %xmm6,%xmm7

        ## add earlier value from mem 
        movl  nb310_Vc(%ebp),%eax
        addss (%eax,%edx,4),%xmm7
        ## move back to mem 
        movss %xmm7,(%eax,%edx,4)

        ## accumulate total lj energy and update it 
        movaps nb310_Vvdwtot(%esp),%xmm7
        ## accumulate 
        movhlps %xmm7,%xmm6
        addps  %xmm6,%xmm7      ## pos 0-1 in xmm7 have the sum now 
        movaps %xmm7,%xmm6
        shufps $1,%xmm6,%xmm6
        addss  %xmm6,%xmm7

        ## add earlier value from mem 
        movl  nb310_Vvdw(%ebp),%eax
        addss (%eax,%edx,4),%xmm7
        ## move back to mem 
        movss %xmm7,(%eax,%edx,4)

        ## finish if last 
        movl nb310_nn1(%esp),%ecx
        ## esi already loaded with n
        incl %esi
        subl %esi,%ecx
        jz _nb_kernel310_ia32_sse.nb310_outerend

        ## not last, iterate outer loop once more!  
        movl %esi,nb310_n(%esp)
        jmp _nb_kernel310_ia32_sse.nb310_outer
_nb_kernel310_ia32_sse.nb310_outerend: 
        ## check if more outer neighborlists remain
        movl  nb310_nri(%esp),%ecx
        ## esi already loaded with n above
        subl  %esi,%ecx
        jz _nb_kernel310_ia32_sse.nb310_end
        ## non-zero, do one more workunit
        jmp   _nb_kernel310_ia32_sse.nb310_threadloop
_nb_kernel310_ia32_sse.nb310_end: 
        emms

        movl nb310_nouter(%esp),%eax
        movl nb310_ninner(%esp),%ebx
        movl nb310_outeriter(%ebp),%ecx
        movl nb310_inneriter(%ebp),%edx
        movl %eax,(%ecx)
        movl %ebx,(%edx)

        movl nb310_salign(%esp),%eax
        addl %eax,%esp
        addl $404,%esp
        popl %edi
        popl %esi
        popl %edx
        popl %ecx
        popl %ebx
        popl %eax
        leave
        ret



.globl nb_kernel310nf_ia32_sse
.globl _nb_kernel310nf_ia32_sse
nb_kernel310nf_ia32_sse:        
_nb_kernel310nf_ia32_sse:       
.set nb310nf_p_nri, 8
.set nb310nf_iinr, 12
.set nb310nf_jindex, 16
.set nb310nf_jjnr, 20
.set nb310nf_shift, 24
.set nb310nf_shiftvec, 28
.set nb310nf_fshift, 32
.set nb310nf_gid, 36
.set nb310nf_pos, 40
.set nb310nf_faction, 44
.set nb310nf_charge, 48
.set nb310nf_p_facel, 52
.set nb310nf_argkrf, 56
.set nb310nf_argcrf, 60
.set nb310nf_Vc, 64
.set nb310nf_type, 68
.set nb310nf_p_ntype, 72
.set nb310nf_vdwparam, 76
.set nb310nf_Vvdw, 80
.set nb310nf_p_tabscale, 84
.set nb310nf_VFtab, 88
.set nb310nf_invsqrta, 92
.set nb310nf_dvda, 96
.set nb310nf_p_gbtabscale, 100
.set nb310nf_GBtab, 104
.set nb310nf_p_nthreads, 108
.set nb310nf_count, 112
.set nb310nf_mtx, 116
.set nb310nf_outeriter, 120
.set nb310nf_inneriter, 124
.set nb310nf_work, 128
        ## stack offsets for local variables  
        ## bottom of stack is cache-aligned for sse use 
.set nb310nf_ix, 0
.set nb310nf_iy, 16
.set nb310nf_iz, 32
.set nb310nf_iq, 48
.set nb310nf_tsc, 64
.set nb310nf_qq, 80
.set nb310nf_c6, 96
.set nb310nf_c12, 112
.set nb310nf_vctot, 128
.set nb310nf_Vvdwtot, 144
.set nb310nf_half, 160
.set nb310nf_three, 176
.set nb310nf_is3, 192
.set nb310nf_ii3, 196
.set nb310nf_ntia, 200
.set nb310nf_innerjjnr, 204
.set nb310nf_innerk, 208
.set nb310nf_n, 212
.set nb310nf_nn1, 216
.set nb310nf_nri, 220
.set nb310nf_facel, 224
.set nb310nf_ntype, 228
.set nb310nf_nouter, 232
.set nb310nf_ninner, 236
.set nb310nf_salign, 240
        pushl %ebp
        movl %esp,%ebp
        pushl %eax
        pushl %ebx
        pushl %ecx
        pushl %edx
        pushl %esi
        pushl %edi
        subl $244,%esp          ## local stack space 
        movl %esp,%eax
        andl $0xf,%eax
        subl %eax,%esp
        movl %eax,nb310nf_salign(%esp)

        emms

        ## Move args passed by reference to stack
        movl nb310nf_p_nri(%ebp),%ecx
        movl nb310nf_p_facel(%ebp),%esi
        movl nb310nf_p_ntype(%ebp),%edi
        movl (%ecx),%ecx
        movl (%esi),%esi
        movl (%edi),%edi
        movl %ecx,nb310nf_nri(%esp)
        movl %esi,nb310nf_facel(%esp)
        movl %edi,nb310nf_ntype(%esp)

        ## zero iteration counters
        movl $0,%eax
        movl %eax,nb310nf_nouter(%esp)
        movl %eax,nb310nf_ninner(%esp)


        ## create constant floating-point factors on stack
        movl $0x3f000000,%eax   ## constant 0.5 in IEEE (hex)
        movl %eax,nb310nf_half(%esp)
        movss nb310nf_half(%esp),%xmm1
        shufps $0,%xmm1,%xmm1  ## splat to all elements
        movaps %xmm1,%xmm2
        addps  %xmm2,%xmm2      ## constant 1.0
        movaps %xmm2,%xmm3
        addps  %xmm2,%xmm2      ## constant 2.0
        addps  %xmm2,%xmm3      ## constant 3.0
        movaps %xmm1,nb310nf_half(%esp)
        movaps %xmm3,nb310nf_three(%esp)
        movl nb310nf_p_tabscale(%ebp),%eax
        movss (%eax),%xmm5
        shufps $0,%xmm5,%xmm5
        movaps %xmm5,nb310nf_tsc(%esp)

_nb_kernel310nf_ia32_sse.nb310nf_threadloop: 
        movl  nb310nf_count(%ebp),%esi            ## pointer to sync counter
        movl  (%esi),%eax
_nb_kernel310nf_ia32_sse.nb310nf_spinlock: 
        movl  %eax,%ebx                         ## ebx=*count=nn0
        addl  $1,%ebx                          ## ebx=nn1=nn0+10
        lock 
        cmpxchgl %ebx,(%esi)                    ## write nn1 to *counter,
                                                ## if it hasnt changed.
                                                ## or reread *counter to eax.
        pause                                   ## -> better p4 performance
        jnz _nb_kernel310nf_ia32_sse.nb310nf_spinlock

        ## if(nn1>nri) nn1=nri
        movl nb310nf_nri(%esp),%ecx
        movl %ecx,%edx
        subl %ebx,%ecx
        cmovlel %edx,%ebx                       ## if(nn1>nri) nn1=nri
        ## Cleared the spinlock if we got here.
        ## eax contains nn0, ebx contains nn1.
        movl %eax,nb310nf_n(%esp)
        movl %ebx,nb310nf_nn1(%esp)
        subl %eax,%ebx                          ## calc number of outer lists
        movl %eax,%esi                          ## copy n to esi
        jg  _nb_kernel310nf_ia32_sse.nb310nf_outerstart
        jmp _nb_kernel310nf_ia32_sse.nb310nf_end

_nb_kernel310nf_ia32_sse.nb310nf_outerstart: 
        ## ebx contains number of outer iterations
        addl nb310nf_nouter(%esp),%ebx
        movl %ebx,nb310nf_nouter(%esp)

_nb_kernel310nf_ia32_sse.nb310nf_outer: 
        movl  nb310nf_shift(%ebp),%eax        ## eax = pointer into shift[] 
        movl  (%eax,%esi,4),%ebx                ## ebx=shift[n] 

        leal  (%ebx,%ebx,2),%ebx    ## ebx=3*is 
        movl  %ebx,nb310nf_is3(%esp)            ## store is3 

        movl  nb310nf_shiftvec(%ebp),%eax     ## eax = base of shiftvec[] 

        movss (%eax,%ebx,4),%xmm0
        movss 4(%eax,%ebx,4),%xmm1
        movss 8(%eax,%ebx,4),%xmm2

        movl  nb310nf_iinr(%ebp),%ecx         ## ecx = pointer into iinr[]      
        movl  (%ecx,%esi,4),%ebx            ## ebx =ii 

        movl  nb310nf_charge(%ebp),%edx
        movss (%edx,%ebx,4),%xmm3
        mulss nb310nf_facel(%esp),%xmm3
        shufps $0,%xmm3,%xmm3

        movl  nb310nf_type(%ebp),%edx
        movl  (%edx,%ebx,4),%edx
        imull nb310nf_ntype(%esp),%edx
        shll  %edx
        movl  %edx,nb310nf_ntia(%esp)

        leal  (%ebx,%ebx,2),%ebx        ## ebx = 3*ii=ii3 
        movl  nb310nf_pos(%ebp),%eax      ## eax = base of pos[]  

        addss (%eax,%ebx,4),%xmm0
        addss 4(%eax,%ebx,4),%xmm1
        addss 8(%eax,%ebx,4),%xmm2

        movaps %xmm3,nb310nf_iq(%esp)

        shufps $0,%xmm0,%xmm0
        shufps $0,%xmm1,%xmm1
        shufps $0,%xmm2,%xmm2

        movaps %xmm0,nb310nf_ix(%esp)
        movaps %xmm1,nb310nf_iy(%esp)
        movaps %xmm2,nb310nf_iz(%esp)

        movl  %ebx,nb310nf_ii3(%esp)

        ## clear vctot and i forces 
        xorps %xmm4,%xmm4
        movaps %xmm4,nb310nf_vctot(%esp)
        movaps %xmm4,nb310nf_Vvdwtot(%esp)

        movl  nb310nf_jindex(%ebp),%eax
        movl  (%eax,%esi,4),%ecx             ## jindex[n] 
        movl  4(%eax,%esi,4),%edx            ## jindex[n+1] 
        subl  %ecx,%edx              ## number of innerloop atoms 

        movl  nb310nf_pos(%ebp),%esi
        movl  nb310nf_jjnr(%ebp),%eax
        shll  $2,%ecx
        addl  %ecx,%eax
        movl  %eax,nb310nf_innerjjnr(%esp)       ## pointer to jjnr[nj0] 
        movl  %edx,%ecx
        subl  $4,%edx
        addl  nb310nf_ninner(%esp),%ecx
        movl  %ecx,nb310nf_ninner(%esp)
        addl  $0,%edx
        movl  %edx,nb310nf_innerk(%esp)      ## number of innerloop atoms 
        jge   _nb_kernel310nf_ia32_sse.nb310nf_unroll_loop
        jmp   _nb_kernel310nf_ia32_sse.nb310nf_finish_inner
_nb_kernel310nf_ia32_sse.nb310nf_unroll_loop: 
        ## quad-unroll innerloop here 
        movl  nb310nf_innerjjnr(%esp),%edx       ## pointer to jjnr[k] 
        movl  (%edx),%eax
        movl  4(%edx),%ebx
        movl  8(%edx),%ecx
        movl  12(%edx),%edx           ## eax-edx=jnr1-4 
        addl $16,nb310nf_innerjjnr(%esp)             ## advance pointer (unrolled 4) 

        movl nb310nf_charge(%ebp),%esi     ## base of charge[] 

        movss (%esi,%eax,4),%xmm3
        movss (%esi,%ecx,4),%xmm4
        movss (%esi,%ebx,4),%xmm6
        movss (%esi,%edx,4),%xmm7

        movaps nb310nf_iq(%esp),%xmm2
        shufps $0,%xmm6,%xmm3
        shufps $0,%xmm7,%xmm4
        shufps $136,%xmm4,%xmm3 ## constant 10001000 ;# all charges in xmm3  
        movd  %eax,%mm0         ## use mmx registers as temp storage 
        movd  %ebx,%mm1
        mulps  %xmm2,%xmm3
        movd  %ecx,%mm2
        movd  %edx,%mm3

        movaps %xmm3,nb310nf_qq(%esp)

        movl nb310nf_type(%ebp),%esi
        movl (%esi,%eax,4),%eax
        movl (%esi,%ebx,4),%ebx
        movl (%esi,%ecx,4),%ecx
        movl (%esi,%edx,4),%edx
        movl nb310nf_vdwparam(%ebp),%esi
        shll %eax
        shll %ebx
        shll %ecx
        shll %edx
        movl nb310nf_ntia(%esp),%edi
        addl %edi,%eax
        addl %edi,%ebx
        addl %edi,%ecx
        addl %edi,%edx

        movlps (%esi,%eax,4),%xmm6
        movlps (%esi,%ecx,4),%xmm7
        movhps (%esi,%ebx,4),%xmm6
        movhps (%esi,%edx,4),%xmm7

        movaps %xmm6,%xmm4
        shufps $136,%xmm7,%xmm4 ## constant 10001000
        shufps $221,%xmm7,%xmm6 ## constant 11011101

        movd  %mm0,%eax
        movd  %mm1,%ebx
        movd  %mm2,%ecx
        movd  %mm3,%edx

        movaps %xmm4,nb310nf_c6(%esp)
        movaps %xmm6,nb310nf_c12(%esp)

        movl nb310nf_pos(%ebp),%esi        ## base of pos[] 

        leal  (%eax,%eax,2),%eax     ## replace jnr with j3 
        leal  (%ebx,%ebx,2),%ebx

        leal  (%ecx,%ecx,2),%ecx     ## replace jnr with j3 
        leal  (%edx,%edx,2),%edx

        ## move four coordinates to xmm0-xmm2   

        movlps (%esi,%eax,4),%xmm4
        movlps (%esi,%ecx,4),%xmm5
        movss 8(%esi,%eax,4),%xmm2
        movss 8(%esi,%ecx,4),%xmm6

        movhps (%esi,%ebx,4),%xmm4
        movhps (%esi,%edx,4),%xmm5

        movss 8(%esi,%ebx,4),%xmm0
        movss 8(%esi,%edx,4),%xmm1

        shufps $0,%xmm0,%xmm2
        shufps $0,%xmm1,%xmm6

        movaps %xmm4,%xmm0
        movaps %xmm4,%xmm1

        shufps $136,%xmm6,%xmm2 ## constant 10001000

        shufps $136,%xmm5,%xmm0 ## constant 10001000
        shufps $221,%xmm5,%xmm1 ## constant 11011101            

        ## move ix-iz to xmm4-xmm6 
        movaps nb310nf_ix(%esp),%xmm4
        movaps nb310nf_iy(%esp),%xmm5
        movaps nb310nf_iz(%esp),%xmm6

        ## calc dr 
        subps %xmm0,%xmm4
        subps %xmm1,%xmm5
        subps %xmm2,%xmm6