nb_kernel202_ia32_sse.s

来自「最著名最快的分子模拟软件」· S 代码 · 共 1,957 行 · 第 1/5 页

##
## $Id: nb_kernel202_ia32_sse.s,v 1.1.2.2 2007/11/28 09:36:33 spoel Exp $
##
## Gromacs 4.0                         Copyright (c) 1991-2003 
## David van der Spoel, Erik Lindahl
##
## This program is free software; you can redistribute it and/or
## modify it under the terms of the GNU General Public License
## as published by the Free Software Foundation; either version 2
## of the License, or (at your option) any later version.
##
## To help us fund GROMACS development, we humbly ask that you cite
## the research papers on the package. Check out http://www.gromacs.org
## 
## And Hey:
## Gnomes, ROck Monsters And Chili Sauce
##




.globl nb_kernel202_ia32_sse
.globl _nb_kernel202_ia32_sse
nb_kernel202_ia32_sse:  
_nb_kernel202_ia32_sse: 
.set nb202_p_nri, 8
.set nb202_iinr, 12
.set nb202_jindex, 16
.set nb202_jjnr, 20
.set nb202_shift, 24
.set nb202_shiftvec, 28
.set nb202_fshift, 32
.set nb202_gid, 36
.set nb202_pos, 40
.set nb202_faction, 44
.set nb202_charge, 48
.set nb202_p_facel, 52
.set nb202_argkrf, 56
.set nb202_argcrf, 60
.set nb202_Vc, 64
.set nb202_type, 68
.set nb202_p_ntype, 72
.set nb202_vdwparam, 76
.set nb202_Vvdw, 80
.set nb202_p_tabscale, 84
.set nb202_VFtab, 88
.set nb202_invsqrta, 92
.set nb202_dvda, 96
.set nb202_p_gbtabscale, 100
.set nb202_GBtab, 104
.set nb202_p_nthreads, 108
.set nb202_count, 112
.set nb202_mtx, 116
.set nb202_outeriter, 120
.set nb202_inneriter, 124
.set nb202_work, 128
        ## stack offsets for local variables  
        ## bottom of stack is cache-aligned for sse use 
.set nb202_ixO, 0
.set nb202_iyO, 16
.set nb202_izO, 32
.set nb202_ixH1, 48
.set nb202_iyH1, 64
.set nb202_izH1, 80
.set nb202_ixH2, 96
.set nb202_iyH2, 112
.set nb202_izH2, 128
.set nb202_jxO, 144
.set nb202_jyO, 160
.set nb202_jzO, 176
.set nb202_jxH1, 192
.set nb202_jyH1, 208
.set nb202_jzH1, 224
.set nb202_jxH2, 240
.set nb202_jyH2, 256
.set nb202_jzH2, 272
.set nb202_dxOO, 288
.set nb202_dyOO, 304
.set nb202_dzOO, 320
.set nb202_dxOH1, 336
.set nb202_dyOH1, 352
.set nb202_dzOH1, 368
.set nb202_dxOH2, 384
.set nb202_dyOH2, 400
.set nb202_dzOH2, 416
.set nb202_dxH1O, 432
.set nb202_dyH1O, 448
.set nb202_dzH1O, 464
.set nb202_dxH1H1, 480
.set nb202_dyH1H1, 496
.set nb202_dzH1H1, 512
.set nb202_dxH1H2, 528
.set nb202_dyH1H2, 544
.set nb202_dzH1H2, 560
.set nb202_dxH2O, 576
.set nb202_dyH2O, 592
.set nb202_dzH2O, 608
.set nb202_dxH2H1, 624
.set nb202_dyH2H1, 640
.set nb202_dzH2H1, 656
.set nb202_dxH2H2, 672
.set nb202_dyH2H2, 688
.set nb202_dzH2H2, 704
.set nb202_qqOO, 720
.set nb202_qqOH, 736
.set nb202_qqHH, 752
.set nb202_vctot, 768
.set nb202_fixO, 784
.set nb202_fiyO, 800
.set nb202_fizO, 816
.set nb202_fixH1, 832
.set nb202_fiyH1, 848
.set nb202_fizH1, 864
.set nb202_fixH2, 880
.set nb202_fiyH2, 896
.set nb202_fizH2, 912
.set nb202_fjxO, 928
.set nb202_fjyO, 944
.set nb202_fjzO, 960
.set nb202_fjxH1, 976
.set nb202_fjyH1, 992
.set nb202_fjzH1, 1008
.set nb202_fjxH2, 1024
.set nb202_fjyH2, 1040
.set nb202_fjzH2, 1056
.set nb202_fjzH2b, 1060
.set nb202_fjzH2c, 1064
.set nb202_fjzH2d, 1068
.set nb202_half, 1072
.set nb202_three, 1088
.set nb202_rsqOO, 1104
.set nb202_rsqOH1, 1120
.set nb202_rsqOH2, 1136
.set nb202_rsqH1O, 1152
.set nb202_rsqH1H1, 1168
.set nb202_rsqH1H2, 1184
.set nb202_rsqH2O, 1200
.set nb202_rsqH2H1, 1216
.set nb202_rsqH2H2, 1232
.set nb202_rinvOO, 1248
.set nb202_rinvOH1, 1264
.set nb202_rinvOH2, 1280
.set nb202_rinvH1O, 1296
.set nb202_rinvH1H1, 1312
.set nb202_rinvH1H2, 1328
.set nb202_rinvH2O, 1344
.set nb202_rinvH2H1, 1360
.set nb202_rinvH2H2, 1376
.set nb202_two, 1392
.set nb202_krf, 1408
.set nb202_crf, 1424
.set nb202_is3, 1440
.set nb202_ii3, 1444
.set nb202_innerjjnr, 1448
.set nb202_innerk, 1452
.set nb202_n, 1456
.set nb202_nn1, 1460
.set nb202_nri, 1464
.set nb202_nouter, 1468
.set nb202_ninner, 1472
.set nb202_salign, 1476
        pushl %ebp
        movl %esp,%ebp
        pushl %eax
        pushl %ebx
        pushl %ecx
        pushl %edx
        pushl %esi
        pushl %edi
        subl $1480,%esp         ## local stack space 
        movl %esp,%eax
        andl $0xf,%eax
        subl %eax,%esp
        movl %eax,nb202_salign(%esp)

        emms

        ## Move args passed by reference to stack
        movl nb202_p_nri(%ebp),%ecx
        movl (%ecx),%ecx
        movl %ecx,nb202_nri(%esp)

        ## zero iteration counters
        movl $0,%eax
        movl %eax,nb202_nouter(%esp)
        movl %eax,nb202_ninner(%esp)


        movl nb202_argkrf(%ebp),%esi
        movl nb202_argcrf(%ebp),%edi
        movss (%esi),%xmm5
        movss (%edi),%xmm6
        shufps $0,%xmm5,%xmm5
        shufps $0,%xmm6,%xmm6
        movaps %xmm5,nb202_krf(%esp)
        movaps %xmm6,nb202_crf(%esp)

        ## assume we have at least one i particle - start directly 
        movl  nb202_iinr(%ebp),%ecx         ## ecx = pointer into iinr[]        
        movl  (%ecx),%ebx           ## ebx =ii 

        movl  nb202_charge(%ebp),%edx
        movss (%edx,%ebx,4),%xmm3
        movss %xmm3,%xmm4
        movss 4(%edx,%ebx,4),%xmm5
        movl nb202_p_facel(%ebp),%esi
        movss (%esi),%xmm6
        mulss  %xmm3,%xmm3
        mulss  %xmm5,%xmm4
        mulss  %xmm5,%xmm5
        mulss  %xmm6,%xmm3
        mulss  %xmm6,%xmm4
        mulss  %xmm6,%xmm5
        shufps $0,%xmm3,%xmm3
        shufps $0,%xmm4,%xmm4
        shufps $0,%xmm5,%xmm5
        movaps %xmm3,nb202_qqOO(%esp)
        movaps %xmm4,nb202_qqOH(%esp)
        movaps %xmm5,nb202_qqHH(%esp)

        ## create constant floating-point factors on stack
        movl $0x3f000000,%eax   ## constant 0.5 in IEEE (hex)
        movl %eax,nb202_half(%esp)
        movss nb202_half(%esp),%xmm1
        shufps $0,%xmm1,%xmm1  ## splat to all elements
        movaps %xmm1,%xmm2
        addps  %xmm2,%xmm2      ## constant 1.0
        movaps %xmm2,%xmm3
        addps  %xmm2,%xmm2      ## constant 2.0
        addps  %xmm2,%xmm3      ## constant 3.0
        movaps %xmm1,nb202_half(%esp)
        movaps %xmm2,nb202_two(%esp)
        movaps %xmm3,nb202_three(%esp)

_nb_kernel202_ia32_sse.nb202_threadloop: 
        movl  nb202_count(%ebp),%esi            ## pointer to sync counter
        movl  (%esi),%eax
_nb_kernel202_ia32_sse.nb202_spinlock: 
        movl  %eax,%ebx                         ## ebx=*count=nn0
        addl  $1,%ebx                          ## ebx=nn1=nn0+10
        lock 
        cmpxchgl %ebx,(%esi)                    ## write nn1 to *counter,
                                                ## if it hasnt changed.
                                                ## or reread *counter to eax.
        pause                                   ## -> better p4 performance
        jnz _nb_kernel202_ia32_sse.nb202_spinlock

        ## if(nn1>nri) nn1=nri
        movl nb202_nri(%esp),%ecx
        movl %ecx,%edx
        subl %ebx,%ecx
        cmovlel %edx,%ebx                       ## if(nn1>nri) nn1=nri
        ## Cleared the spinlock if we got here.
        ## eax contains nn0, ebx contains nn1.
        movl %eax,nb202_n(%esp)
        movl %ebx,nb202_nn1(%esp)
        subl %eax,%ebx                          ## calc number of outer lists
        movl %eax,%esi                          ## copy n to esi
        jg  _nb_kernel202_ia32_sse.nb202_outerstart
        jmp _nb_kernel202_ia32_sse.nb202_end

_nb_kernel202_ia32_sse.nb202_outerstart: 
        ## ebx contains number of outer iterations
        addl nb202_nouter(%esp),%ebx
        movl %ebx,nb202_nouter(%esp)

_nb_kernel202_ia32_sse.nb202_outer: 
        movl  nb202_shift(%ebp),%eax        ## eax = pointer into shift[] 
        movl  (%eax,%esi,4),%ebx        ## ebx=shift[n] 

        leal  (%ebx,%ebx,2),%ebx    ## ebx=3*is 
        movl  %ebx,nb202_is3(%esp)      ## store is3 

        movl  nb202_shiftvec(%ebp),%eax     ## eax = base of shiftvec[] 

        movss (%eax,%ebx,4),%xmm0
        movss 4(%eax,%ebx,4),%xmm1
        movss 8(%eax,%ebx,4),%xmm2

        movl  nb202_iinr(%ebp),%ecx         ## ecx = pointer into iinr[]        
        movl  (%ecx,%esi,4),%ebx            ## ebx =ii 

        leal  (%ebx,%ebx,2),%ebx        ## ebx = 3*ii=ii3 
        movl  nb202_pos(%ebp),%eax      ## eax = base of pos[]  
        movl  %ebx,nb202_ii3(%esp)

        movaps %xmm0,%xmm3
        movaps %xmm1,%xmm4
        movaps %xmm2,%xmm5
        addss (%eax,%ebx,4),%xmm3
        addss 4(%eax,%ebx,4),%xmm4
        addss 8(%eax,%ebx,4),%xmm5
        shufps $0,%xmm3,%xmm3
        shufps $0,%xmm4,%xmm4
        shufps $0,%xmm5,%xmm5
        movaps %xmm3,nb202_ixO(%esp)
        movaps %xmm4,nb202_iyO(%esp)
        movaps %xmm5,nb202_izO(%esp)

        movss %xmm0,%xmm3
        movss %xmm1,%xmm4
        movss %xmm2,%xmm5
        addss 12(%eax,%ebx,4),%xmm0
        addss 16(%eax,%ebx,4),%xmm1
        addss 20(%eax,%ebx,4),%xmm2
        addss 24(%eax,%ebx,4),%xmm3
        addss 28(%eax,%ebx,4),%xmm4
        addss 32(%eax,%ebx,4),%xmm5

        shufps $0,%xmm0,%xmm0
        shufps $0,%xmm1,%xmm1
        shufps $0,%xmm2,%xmm2
        shufps $0,%xmm3,%xmm3
        shufps $0,%xmm4,%xmm4
        shufps $0,%xmm5,%xmm5
        movaps %xmm0,nb202_ixH1(%esp)
        movaps %xmm1,nb202_iyH1(%esp)
        movaps %xmm2,nb202_izH1(%esp)
        movaps %xmm3,nb202_ixH2(%esp)
        movaps %xmm4,nb202_iyH2(%esp)
        movaps %xmm5,nb202_izH2(%esp)

        ## clear vctot and i forces 
        xorps %xmm4,%xmm4
        movaps %xmm4,nb202_vctot(%esp)
        movaps %xmm4,nb202_fixO(%esp)
        movaps %xmm4,nb202_fiyO(%esp)
        movaps %xmm4,nb202_fizO(%esp)
        movaps %xmm4,nb202_fixH1(%esp)
        movaps %xmm4,nb202_fiyH1(%esp)
        movaps %xmm4,nb202_fizH1(%esp)
        movaps %xmm4,nb202_fixH2(%esp)
        movaps %xmm4,nb202_fiyH2(%esp)
        movaps %xmm4,nb202_fizH2(%esp)

        movl  nb202_jindex(%ebp),%eax
        movl  (%eax,%esi,4),%ecx                ## jindex[n] 
        movl  4(%eax,%esi,4),%edx               ## jindex[n+1] 
        subl  %ecx,%edx                         ## number of innerloop atoms 

        movl  nb202_pos(%ebp),%esi
        movl  nb202_faction(%ebp),%edi
        movl  nb202_jjnr(%ebp),%eax
        shll  $2,%ecx
        addl  %ecx,%eax
        movl  %eax,nb202_innerjjnr(%esp)       ## pointer to jjnr[nj0] 
        movl  %edx,%ecx
        subl  $4,%edx
        addl  nb202_ninner(%esp),%ecx
        movl  %ecx,nb202_ninner(%esp)
        addl  $0,%edx
        movl  %edx,nb202_innerk(%esp)      ## number of innerloop atoms 
        jge   _nb_kernel202_ia32_sse.nb202_unroll_loop
        jmp   _nb_kernel202_ia32_sse.nb202_single_check
_nb_kernel202_ia32_sse.nb202_unroll_loop: 
        ## quad-unroll innerloop here 
        movl  nb202_innerjjnr(%esp),%edx       ## pointer to jjnr[k] 

        movl  (%edx),%eax
        movl  4(%edx),%ebx
        movl  8(%edx),%ecx
        movl  12(%edx),%edx           ## eax-edx=jnr1-4 

        addl $16,nb202_innerjjnr(%esp)             ## advance pointer (unrolled 4) 

        movl nb202_pos(%ebp),%esi        ## base of pos[] 

        leal  (%eax,%eax,2),%eax     ## replace jnr with j3 
        leal  (%ebx,%ebx,2),%ebx
        leal  (%ecx,%ecx,2),%ecx     ## replace jnr with j3 
        leal  (%edx,%edx,2),%edx

        ## move j coordinates to local temp variables 
        movlps (%esi,%eax,4),%xmm2
        movlps 12(%esi,%eax,4),%xmm3
        movlps 24(%esi,%eax,4),%xmm4

        movlps (%esi,%ebx,4),%xmm5
        movlps 12(%esi,%ebx,4),%xmm6
        movlps 24(%esi,%ebx,4),%xmm7

        movhps (%esi,%ecx,4),%xmm2
        movhps 12(%esi,%ecx,4),%xmm3
        movhps 24(%esi,%ecx,4),%xmm4

        movhps (%esi,%edx,4),%xmm5
        movhps 12(%esi,%edx,4),%xmm6
        movhps 24(%esi,%edx,4),%xmm7

        ## current state:       
        ## xmm2= jxOa  jyOa  jxOc  jyOc 
        ## xmm3= jxH1a jyH1a jxH1c jyH1c