nb_kernel202_ia32_sse.s

来自「最著名最快的分子模拟软件」· S 代码 · 共 1,957 行 · 第 1/5 页

        jmp   _nb_kernel202_ia32_sse.nb202_threadloop
_nb_kernel202_ia32_sse.nb202_end: 
        emms

        movl nb202_nouter(%esp),%eax
        movl nb202_ninner(%esp),%ebx
        movl nb202_outeriter(%ebp),%ecx
        movl nb202_inneriter(%ebp),%edx
        movl %eax,(%ecx)
        movl %ebx,(%edx)

        movl nb202_salign(%esp),%eax
        addl %eax,%esp
        addl $1480,%esp
        popl %edi
        popl %esi
        popl %edx
        popl %ecx
        popl %ebx
        popl %eax
        leave
        ret








.globl nb_kernel202nf_ia32_sse
.globl _nb_kernel202nf_ia32_sse
nb_kernel202nf_ia32_sse:        
_nb_kernel202nf_ia32_sse:       
.set nb202nf_p_nri, 8
.set nb202nf_iinr, 12
.set nb202nf_jindex, 16
.set nb202nf_jjnr, 20
.set nb202nf_shift, 24
.set nb202nf_shiftvec, 28
.set nb202nf_fshift, 32
.set nb202nf_gid, 36
.set nb202nf_pos, 40
.set nb202nf_faction, 44
.set nb202nf_charge, 48
.set nb202nf_p_facel, 52
.set nb202nf_argkrf, 56
.set nb202nf_argcrf, 60
.set nb202nf_Vc, 64
.set nb202nf_type, 68
.set nb202nf_p_ntype, 72
.set nb202nf_vdwparam, 76
.set nb202nf_Vvdw, 80
.set nb202nf_p_tabscale, 84
.set nb202nf_VFtab, 88
.set nb202nf_invsqrta, 92
.set nb202nf_dvda, 96
.set nb202nf_p_gbtabscale, 100
.set nb202nf_GBtab, 104
.set nb202nf_p_nthreads, 108
.set nb202nf_count, 112
.set nb202nf_mtx, 116
.set nb202nf_outeriter, 120
.set nb202nf_inneriter, 124
.set nb202nf_work, 128
        ## stack offsets for local variables  
        ## bottom of stack is cache-aligned for sse use 
.set nb202nf_ixO, 0
.set nb202nf_iyO, 16
.set nb202nf_izO, 32
.set nb202nf_ixH1, 48
.set nb202nf_iyH1, 64
.set nb202nf_izH1, 80
.set nb202nf_ixH2, 96
.set nb202nf_iyH2, 112
.set nb202nf_izH2, 128
.set nb202nf_jxO, 144
.set nb202nf_jyO, 160
.set nb202nf_jzO, 176
.set nb202nf_jxH1, 192
.set nb202nf_jyH1, 208
.set nb202nf_jzH1, 224
.set nb202nf_jxH2, 240
.set nb202nf_jyH2, 256
.set nb202nf_jzH2, 272
.set nb202nf_qqOO, 288
.set nb202nf_qqOH, 304
.set nb202nf_qqHH, 320
.set nb202nf_vctot, 336
.set nb202nf_half, 352
.set nb202nf_three, 368
.set nb202nf_rsqOO, 384
.set nb202nf_rsqOH1, 400
.set nb202nf_rsqOH2, 416
.set nb202nf_rsqH1O, 432
.set nb202nf_rsqH1H1, 448
.set nb202nf_rsqH1H2, 464
.set nb202nf_rsqH2O, 480
.set nb202nf_rsqH2H1, 496
.set nb202nf_rsqH2H2, 512
.set nb202nf_rinvOO, 528
.set nb202nf_rinvOH1, 544
.set nb202nf_rinvOH2, 560
.set nb202nf_rinvH1O, 576
.set nb202nf_rinvH1H1, 592
.set nb202nf_rinvH1H2, 608
.set nb202nf_rinvH2O, 624
.set nb202nf_rinvH2H1, 640
.set nb202nf_rinvH2H2, 656
.set nb202nf_krf, 672
.set nb202nf_crf, 688
.set nb202nf_is3, 704
.set nb202nf_ii3, 708
.set nb202nf_innerjjnr, 712
.set nb202nf_innerk, 716
.set nb202nf_n, 720
.set nb202nf_nn1, 724
.set nb202nf_nri, 728
.set nb202nf_nouter, 732
.set nb202nf_ninner, 736
.set nb202nf_salign, 740
        pushl %ebp
        movl %esp,%ebp
        pushl %eax
        pushl %ebx
        pushl %ecx
        pushl %edx
        pushl %esi
        pushl %edi
        subl $744,%esp          ## local stack space 
        movl %esp,%eax
        andl $0xf,%eax
        subl %eax,%esp
        movl %eax,nb202nf_salign(%esp)

        emms

        ## Move args passed by reference to stack
        movl nb202nf_p_nri(%ebp),%ecx
        movl (%ecx),%ecx
        movl %ecx,nb202nf_nri(%esp)

        ## zero iteration counters
        movl $0,%eax
        movl %eax,nb202nf_nouter(%esp)
        movl %eax,nb202nf_ninner(%esp)


        movl nb202nf_argkrf(%ebp),%esi
        movl nb202nf_argcrf(%ebp),%edi
        movss (%esi),%xmm5
        movss (%edi),%xmm6
        shufps $0,%xmm5,%xmm5
        shufps $0,%xmm6,%xmm6
        movaps %xmm5,nb202nf_krf(%esp)
        movaps %xmm6,nb202nf_crf(%esp)

        ## assume we have at least one i particle - start directly 
        movl  nb202nf_iinr(%ebp),%ecx         ## ecx = pointer into iinr[]      
        movl  (%ecx),%ebx           ## ebx =ii 

        movl  nb202nf_charge(%ebp),%edx
        movss (%edx,%ebx,4),%xmm3
        movss %xmm3,%xmm4
        movss 4(%edx,%ebx,4),%xmm5
        movl nb202nf_p_facel(%ebp),%esi
        movss (%esi),%xmm6
        mulss  %xmm3,%xmm3
        mulss  %xmm5,%xmm4
        mulss  %xmm5,%xmm5
        mulss  %xmm6,%xmm3
        mulss  %xmm6,%xmm4
        mulss  %xmm6,%xmm5
        shufps $0,%xmm3,%xmm3
        shufps $0,%xmm4,%xmm4
        shufps $0,%xmm5,%xmm5
        movaps %xmm3,nb202nf_qqOO(%esp)
        movaps %xmm4,nb202nf_qqOH(%esp)
        movaps %xmm5,nb202nf_qqHH(%esp)


        ## create constant floating-point factors on stack
        movl $0x3f000000,%eax   ## constant 0.5 in IEEE (hex)
        movl %eax,nb202nf_half(%esp)
        movss nb202nf_half(%esp),%xmm1
        shufps $0,%xmm1,%xmm1  ## splat to all elements
        movaps %xmm1,%xmm2
        addps  %xmm2,%xmm2      ## constant 1.0
        movaps %xmm2,%xmm3
        addps  %xmm2,%xmm2      ## constant 2.0
        addps  %xmm2,%xmm3      ## constant 3.0
        movaps %xmm1,nb202nf_half(%esp)
        movaps %xmm3,nb202nf_three(%esp)

_nb_kernel202nf_ia32_sse.nb202nf_threadloop: 
        movl  nb202nf_count(%ebp),%esi            ## pointer to sync counter
        movl  (%esi),%eax
_nb_kernel202nf_ia32_sse.nb202nf_spinlock: 
        movl  %eax,%ebx                         ## ebx=*count=nn0
        addl  $1,%ebx                          ## ebx=nn1=nn0+10
        lock 
        cmpxchgl %ebx,(%esi)                    ## write nn1 to *counter,
                                                ## if it hasnt changed.
                                                ## or reread *counter to eax.
        pause                                   ## -> better p4 performance
        jnz _nb_kernel202nf_ia32_sse.nb202nf_spinlock

        ## if(nn1>nri) nn1=nri
        movl nb202nf_nri(%esp),%ecx
        movl %ecx,%edx
        subl %ebx,%ecx
        cmovlel %edx,%ebx                       ## if(nn1>nri) nn1=nri
        ## Cleared the spinlock if we got here.
        ## eax contains nn0, ebx contains nn1.
        movl %eax,nb202nf_n(%esp)
        movl %ebx,nb202nf_nn1(%esp)
        subl %eax,%ebx                          ## calc number of outer lists
        movl %eax,%esi                          ## copy n to esi
        jg  _nb_kernel202nf_ia32_sse.nb202nf_outerstart
        jmp _nb_kernel202nf_ia32_sse.nb202nf_end

_nb_kernel202nf_ia32_sse.nb202nf_outerstart: 
        ## ebx contains number of outer iterations
        addl nb202nf_nouter(%esp),%ebx
        movl %ebx,nb202nf_nouter(%esp)

_nb_kernel202nf_ia32_sse.nb202nf_outer: 
        movl  nb202nf_shift(%ebp),%eax        ## eax = pointer into shift[] 
        movl  (%eax,%esi,4),%ebx                ## ebx=shift[n] 

        leal  (%ebx,%ebx,2),%ebx    ## ebx=3*is 
        movl  %ebx,nb202nf_is3(%esp)            ## store is3 

        movl  nb202nf_shiftvec(%ebp),%eax     ## eax = base of shiftvec[] 

        movss (%eax,%ebx,4),%xmm0
        movss 4(%eax,%ebx,4),%xmm1
        movss 8(%eax,%ebx,4),%xmm2

        movl  nb202nf_iinr(%ebp),%ecx         ## ecx = pointer into iinr[]      
        movl  (%ecx,%esi,4),%ebx            ## ebx =ii 

        leal  (%ebx,%ebx,2),%ebx        ## ebx = 3*ii=ii3 
        movl  nb202nf_pos(%ebp),%eax      ## eax = base of pos[]  
        movl  %ebx,nb202nf_ii3(%esp)

        movaps %xmm0,%xmm3
        movaps %xmm1,%xmm4
        movaps %xmm2,%xmm5
        addss (%eax,%ebx,4),%xmm3
        addss 4(%eax,%ebx,4),%xmm4
        addss 8(%eax,%ebx,4),%xmm5
        shufps $0,%xmm3,%xmm3
        shufps $0,%xmm4,%xmm4
        shufps $0,%xmm5,%xmm5
        movaps %xmm3,nb202nf_ixO(%esp)
        movaps %xmm4,nb202nf_iyO(%esp)
        movaps %xmm5,nb202nf_izO(%esp)

        movss %xmm0,%xmm3
        movss %xmm1,%xmm4
        movss %xmm2,%xmm5
        addss 12(%eax,%ebx,4),%xmm0
        addss 16(%eax,%ebx,4),%xmm1
        addss 20(%eax,%ebx,4),%xmm2
        addss 24(%eax,%ebx,4),%xmm3
        addss 28(%eax,%ebx,4),%xmm4
        addss 32(%eax,%ebx,4),%xmm5

        shufps $0,%xmm0,%xmm0
        shufps $0,%xmm1,%xmm1
        shufps $0,%xmm2,%xmm2
        shufps $0,%xmm3,%xmm3
        shufps $0,%xmm4,%xmm4
        shufps $0,%xmm5,%xmm5
        movaps %xmm0,nb202nf_ixH1(%esp)
        movaps %xmm1,nb202nf_iyH1(%esp)
        movaps %xmm2,nb202nf_izH1(%esp)
        movaps %xmm3,nb202nf_ixH2(%esp)
        movaps %xmm4,nb202nf_iyH2(%esp)
        movaps %xmm5,nb202nf_izH2(%esp)

        ## clear vctot and i forces 
        xorps %xmm4,%xmm4
        movaps %xmm4,nb202nf_vctot(%esp)

        movl  nb202nf_jindex(%ebp),%eax
        movl  (%eax,%esi,4),%ecx             ## jindex[n] 
        movl  4(%eax,%esi,4),%edx            ## jindex[n+1] 
        subl  %ecx,%edx              ## number of innerloop atoms 

        movl  nb202nf_pos(%ebp),%esi
        movl  nb202nf_jjnr(%ebp),%eax
        shll  $2,%ecx
        addl  %ecx,%eax
        movl  %eax,nb202nf_innerjjnr(%esp)       ## pointer to jjnr[nj0] 
        movl  %edx,%ecx
        subl  $4,%edx
        addl  nb202nf_ninner(%esp),%ecx
        movl  %ecx,nb202nf_ninner(%esp)
        addl  $0,%edx
        movl  %edx,nb202nf_innerk(%esp)      ## number of innerloop atoms 
        jge   _nb_kernel202nf_ia32_sse.nb202nf_unroll_loop
        jmp   _nb_kernel202nf_ia32_sse.nb202nf_single_check
_nb_kernel202nf_ia32_sse.nb202nf_unroll_loop: 
        ## quad-unroll innerloop here 
        movl  nb202nf_innerjjnr(%esp),%edx       ## pointer to jjnr[k] 

        movl  (%edx),%eax
        movl  4(%edx),%ebx
        movl  8(%edx),%ecx
        movl  12(%edx),%edx           ## eax-edx=jnr1-4 

        addl $16,nb202nf_innerjjnr(%esp)             ## advance pointer (unrolled 4) 

        movl nb202nf_pos(%ebp),%esi        ## base of pos[] 

        leal  (%eax,%eax,2),%eax     ## replace jnr with j3 
        leal  (%ebx,%ebx,2),%ebx
        leal  (%ecx,%ecx,2),%ecx     ## replace jnr with j3 
        leal  (%edx,%edx,2),%edx

        ## move j coordinates to local temp variables 
        movlps (%esi,%eax,4),%xmm2
        movlps 12(%esi,%eax,4),%xmm3
        movlps 24(%esi,%eax,4),%xmm4

        movlps (%esi,%ebx,4),%xmm5
        movlps 12(%esi,%ebx,4),%xmm6
        movlps 24(%esi,%ebx,4),%xmm7

        movhps (%esi,%ecx,4),%xmm2
        movhps 12(%esi,%ecx,4),%xmm3
        movhps 24(%esi,%ecx,4),%xmm4

        movhps (%esi,%edx,4),%xmm5
        movhps 12(%esi,%edx,4),%xmm6
        movhps 24(%esi,%edx,4),%xmm7

        ## current state:       
        ## xmm2= jxOa  jyOa  jxOc  jyOc 
        ## xmm3= jxH1a jyH1a jxH1c jyH1c 
        ## xmm4= jxH2a jyH2a jxH2c jyH2c 
        ## xmm5= jxOb  jyOb  jxOd  jyOd 
        ## xmm6= jxH1b jyH1b jxH1d jyH1d 
        ## xmm7= jxH2b jyH2b jxH2d jyH2d 

        movaps %xmm2,%xmm0
        movaps %xmm3,%xmm1
        unpcklps %xmm5,%xmm0    ## xmm0= jxOa  jxOb  jyOa  jyOb 
        unpcklps %xmm6,%xmm1    ## xmm1= jxH1a jxH1b jyH1a jyH1b 
        unpckhps %xmm5,%xmm2    ## xmm2= jxOc  jxOd  jyOc  jyOd 
        unpckhps %xmm6,%xmm3    ## xmm3= jxH1c jxH1d jyH1c jyH1d 
        movaps %xmm4,%xmm5
        movaps   %xmm0,%xmm6
        unpcklps %xmm7,%xmm4    ## xmm4= jxH2a jxH2b jyH2a jyH2b                
        unpckhps %xmm7,%xmm5    ## xmm5= jxH2c jxH2d jyH2c jyH2d 
        movaps   %xmm1,%xmm7
        movlhps  %xmm2,%xmm0    ## xmm0= jxOa  jxOb  jxOc  jxOd 
        movaps %xmm0,nb202nf_jxO(%esp)
        movhlps  %xmm6,%xmm2    ## xmm2= jyOa  jyOb  jyOc  jyOd 
        movaps %xmm2,nb202nf_jyO(%esp)
        movlhps  %xmm3,%xmm1
        movaps %xmm1,nb202nf_jxH1(%esp)
        movhlps  %xmm7,%xmm3
        movaps   %xmm4,%xmm6
        movaps %xmm3,nb202nf_jyH1(%esp)
        movlhps  %xmm5,%xmm4
        movaps %xmm4,nb202nf_jxH2(%esp)
        movhlps  %xmm6,%xmm5
        movaps %xmm5,nb202nf_jyH2(%esp)

        movss  8(%esi,%eax,4),%xmm0
        movss  20(%esi,%eax,4),%xmm1
        movss  32(%esi,%eax,4),%xmm2

        movss  8(%esi,%ecx,4),%xmm3
        movss  20(%esi,%ecx,4),%xmm4
        movss  32(%esi,%ecx,4),%xmm5

        movhps 4(%esi,%ebx,4),%xmm0
        movhps 16(%esi,%ebx,4),%xmm1
        movhps 28(%esi,%ebx,4),%xmm2

        movhps 4(%esi,%edx,4),%xmm3
        movhps 16(%esi,%edx,4),%xmm4
        movhps 28(%esi,%edx,4),%xmm5

        shufps $204,%xmm3,%xmm0 ##