nb_kernel201_ia32_sse.s

来自「最著名最快的分子模拟软件」· S 代码 · 共 1,574 行 · 第 1/4 页

##
## $Id: nb_kernel201_ia32_sse.s,v 1.1.2.2 2007/11/28 09:36:33 spoel Exp $
##
## Gromacs 4.0                         Copyright (c) 1991-2003 
## David van der Spoel, Erik Lindahl
##
## This program is free software; you can redistribute it and/or
## modify it under the terms of the GNU General Public License
## as published by the Free Software Foundation; either version 2
## of the License, or (at your option) any later version.
##
## To help us fund GROMACS development, we humbly ask that you cite
## the research papers on the package. Check out http://www.gromacs.org
## 
## And Hey:
## Gnomes, ROck Monsters And Chili Sauce
##




.globl nb_kernel201_ia32_sse
.globl _nb_kernel201_ia32_sse
nb_kernel201_ia32_sse:  
_nb_kernel201_ia32_sse: 
.set nb201_p_nri, 8
.set nb201_iinr, 12
.set nb201_jindex, 16
.set nb201_jjnr, 20
.set nb201_shift, 24
.set nb201_shiftvec, 28
.set nb201_fshift, 32
.set nb201_gid, 36
.set nb201_pos, 40
.set nb201_faction, 44
.set nb201_charge, 48
.set nb201_p_facel, 52
.set nb201_argkrf, 56
.set nb201_argcrf, 60
.set nb201_Vc, 64
.set nb201_type, 68
.set nb201_p_ntype, 72
.set nb201_vdwparam, 76
.set nb201_Vvdw, 80
.set nb201_p_tabscale, 84
.set nb201_VFtab, 88
.set nb201_invsqrta, 92
.set nb201_dvda, 96
.set nb201_p_gbtabscale, 100
.set nb201_GBtab, 104
.set nb201_p_nthreads, 108
.set nb201_count, 112
.set nb201_mtx, 116
.set nb201_outeriter, 120
.set nb201_inneriter, 124
.set nb201_work, 128
        ## stack offsets for local variables  
        ## bottom of stack is cache-aligned for sse use 
.set nb201_ixO, 0
.set nb201_iyO, 16
.set nb201_izO, 32
.set nb201_ixH1, 48
.set nb201_iyH1, 64
.set nb201_izH1, 80
.set nb201_ixH2, 96
.set nb201_iyH2, 112
.set nb201_izH2, 128
.set nb201_iqO, 144
.set nb201_iqH, 160
.set nb201_dxO, 176
.set nb201_dyO, 192
.set nb201_dzO, 208
.set nb201_dxH1, 224
.set nb201_dyH1, 240
.set nb201_dzH1, 256
.set nb201_dxH2, 272
.set nb201_dyH2, 288
.set nb201_dzH2, 304
.set nb201_qqO, 320
.set nb201_qqH, 336
.set nb201_vctot, 352
.set nb201_fixO, 384
.set nb201_fiyO, 400
.set nb201_fizO, 416
.set nb201_fixH1, 432
.set nb201_fiyH1, 448
.set nb201_fizH1, 464
.set nb201_fixH2, 480
.set nb201_fiyH2, 496
.set nb201_fizH2, 512
.set nb201_fjx, 528
.set nb201_fjy, 544
.set nb201_fjz, 560
.set nb201_half, 576
.set nb201_three, 592
.set nb201_two, 608
.set nb201_krf, 624
.set nb201_crf, 640
.set nb201_krsqO, 656
.set nb201_krsqH1, 672
.set nb201_krsqH2, 688
.set nb201_is3, 704
.set nb201_ii3, 708
.set nb201_innerjjnr, 712
.set nb201_innerk, 716
.set nb201_n, 720
.set nb201_nn1, 724
.set nb201_nri, 728
.set nb201_nouter, 732
.set nb201_ninner, 736
.set nb201_salign, 740
        pushl %ebp
        movl %esp,%ebp
        pushl %eax
        pushl %ebx
        pushl %ecx
        pushl %edx
        pushl %esi
        pushl %edi
        subl $744,%esp          ## local stack space 
        movl %esp,%eax
        andl $0xf,%eax
        subl %eax,%esp
        movl %eax,nb201_salign(%esp)

        emms

        ## Move args passed by reference to stack
        movl nb201_p_nri(%ebp),%ecx
        movl (%ecx),%ecx
        movl %ecx,nb201_nri(%esp)

        ## zero iteration counters
        movl $0,%eax
        movl %eax,nb201_nouter(%esp)
        movl %eax,nb201_ninner(%esp)


        movl nb201_argkrf(%ebp),%esi
        movl nb201_argcrf(%ebp),%edi
        movss (%esi),%xmm5
        movss (%edi),%xmm6
        shufps $0,%xmm5,%xmm5
        shufps $0,%xmm6,%xmm6
        movaps %xmm5,nb201_krf(%esp)
        movaps %xmm6,nb201_crf(%esp)

        ## assume we have at least one i particle - start directly 
        movl  nb201_iinr(%ebp),%ecx         ## ecx = pointer into iinr[]        
        movl  (%ecx),%ebx           ## ebx =ii 

        movl  nb201_charge(%ebp),%edx
        movss (%edx,%ebx,4),%xmm3
        movss 4(%edx,%ebx,4),%xmm4
        movl nb201_p_facel(%ebp),%esi
        movss (%esi),%xmm5
        mulss  %xmm5,%xmm3
        mulss  %xmm5,%xmm4

        shufps $0,%xmm3,%xmm3
        shufps $0,%xmm4,%xmm4
        movaps %xmm3,nb201_iqO(%esp)
        movaps %xmm4,nb201_iqH(%esp)

        ## create constant floating-point factors on stack
        movl $0x3f000000,%eax   ## constant 0.5 in IEEE (hex)
        movl %eax,nb201_half(%esp)
        movss nb201_half(%esp),%xmm1
        shufps $0,%xmm1,%xmm1  ## splat to all elements
        movaps %xmm1,%xmm2
        addps  %xmm2,%xmm2      ## constant 1.0
        movaps %xmm2,%xmm3
        addps  %xmm2,%xmm2      ## constant 2.0
        addps  %xmm2,%xmm3      ## constant 3.0
        movaps %xmm1,nb201_half(%esp)
        movaps %xmm2,nb201_two(%esp)
        movaps %xmm3,nb201_three(%esp)


_nb_kernel201_ia32_sse.nb201_threadloop: 
        movl  nb201_count(%ebp),%esi            ## pointer to sync counter
        movl  (%esi),%eax
_nb_kernel201_ia32_sse.nb201_spinlock: 
        movl  %eax,%ebx                         ## ebx=*count=nn0
        addl  $1,%ebx                          ## ebx=nn1=nn0+10
        lock 
        cmpxchgl %ebx,(%esi)                    ## write nn1 to *counter,
                                                ## if it hasnt changed.
                                                ## or reread *counter to eax.
        pause                                   ## -> better p4 performance
        jnz _nb_kernel201_ia32_sse.nb201_spinlock

        ## if(nn1>nri) nn1=nri
        movl nb201_nri(%esp),%ecx
        movl %ecx,%edx
        subl %ebx,%ecx
        cmovlel %edx,%ebx                       ## if(nn1>nri) nn1=nri
        ## Cleared the spinlock if we got here.
        ## eax contains nn0, ebx contains nn1.
        movl %eax,nb201_n(%esp)
        movl %ebx,nb201_nn1(%esp)
        subl %eax,%ebx                          ## calc number of outer lists
        movl %eax,%esi                          ## copy n to esi
        jg  _nb_kernel201_ia32_sse.nb201_outerstart
        jmp _nb_kernel201_ia32_sse.nb201_end

_nb_kernel201_ia32_sse.nb201_outerstart: 
        ## ebx contains number of outer iterations
        addl nb201_nouter(%esp),%ebx
        movl %ebx,nb201_nouter(%esp)

_nb_kernel201_ia32_sse.nb201_outer: 
        movl  nb201_shift(%ebp),%eax        ## eax = pointer into shift[] 
        movl  (%eax,%esi,4),%ebx        ## ebx=shift[n] 

        leal  (%ebx,%ebx,2),%ebx    ## ebx=3*is 
        movl  %ebx,nb201_is3(%esp)      ## store is3 

        movl  nb201_shiftvec(%ebp),%eax     ## eax = base of shiftvec[] 

        movss (%eax,%ebx,4),%xmm0
        movss 4(%eax,%ebx,4),%xmm1
        movss 8(%eax,%ebx,4),%xmm2

        movl  nb201_iinr(%ebp),%ecx         ## ecx = pointer into iinr[]        
        movl  (%ecx,%esi,4),%ebx    ## ebx =ii 

        movaps %xmm0,%xmm3
        movaps %xmm1,%xmm4
        movaps %xmm2,%xmm5

        leal  (%ebx,%ebx,2),%ebx        ## ebx = 3*ii=ii3 
        movl  nb201_pos(%ebp),%eax      ## eax = base of pos[]  
        movl  %ebx,nb201_ii3(%esp)

        addss (%eax,%ebx,4),%xmm3
        addss 4(%eax,%ebx,4),%xmm4
        addss 8(%eax,%ebx,4),%xmm5
        shufps $0,%xmm3,%xmm3
        shufps $0,%xmm4,%xmm4
        shufps $0,%xmm5,%xmm5
        movaps %xmm3,nb201_ixO(%esp)
        movaps %xmm4,nb201_iyO(%esp)
        movaps %xmm5,nb201_izO(%esp)

        movss %xmm0,%xmm3
        movss %xmm1,%xmm4
        movss %xmm2,%xmm5
        addss 12(%eax,%ebx,4),%xmm0
        addss 16(%eax,%ebx,4),%xmm1
        addss 20(%eax,%ebx,4),%xmm2
        addss 24(%eax,%ebx,4),%xmm3
        addss 28(%eax,%ebx,4),%xmm4
        addss 32(%eax,%ebx,4),%xmm5

        shufps $0,%xmm0,%xmm0
        shufps $0,%xmm1,%xmm1
        shufps $0,%xmm2,%xmm2
        shufps $0,%xmm3,%xmm3
        shufps $0,%xmm4,%xmm4
        shufps $0,%xmm5,%xmm5
        movaps %xmm0,nb201_ixH1(%esp)
        movaps %xmm1,nb201_iyH1(%esp)
        movaps %xmm2,nb201_izH1(%esp)
        movaps %xmm3,nb201_ixH2(%esp)
        movaps %xmm4,nb201_iyH2(%esp)
        movaps %xmm5,nb201_izH2(%esp)

        ## clear vctot and i forces 
        xorps %xmm4,%xmm4
        movaps %xmm4,nb201_vctot(%esp)
        movaps %xmm4,nb201_fixO(%esp)
        movaps %xmm4,nb201_fiyO(%esp)
        movaps %xmm4,nb201_fizO(%esp)
        movaps %xmm4,nb201_fixH1(%esp)
        movaps %xmm4,nb201_fiyH1(%esp)
        movaps %xmm4,nb201_fizH1(%esp)
        movaps %xmm4,nb201_fixH2(%esp)
        movaps %xmm4,nb201_fiyH2(%esp)
        movaps %xmm4,nb201_fizH2(%esp)

        movl  nb201_jindex(%ebp),%eax
        movl  (%eax,%esi,4),%ecx             ## jindex[n] 
        movl  4(%eax,%esi,4),%edx            ## jindex[n+1] 
        subl  %ecx,%edx              ## number of innerloop atoms 

        movl  nb201_pos(%ebp),%esi
        movl  nb201_faction(%ebp),%edi
        movl  nb201_jjnr(%ebp),%eax
        shll  $2,%ecx
        addl  %ecx,%eax
        movl  %eax,nb201_innerjjnr(%esp)       ## pointer to jjnr[nj0] 
        movl  %edx,%ecx
        subl  $4,%edx
        addl  nb201_ninner(%esp),%ecx
        movl  %ecx,nb201_ninner(%esp)
        addl  $0,%edx
        movl  %edx,nb201_innerk(%esp)      ## number of innerloop atoms 
        jge   _nb_kernel201_ia32_sse.nb201_unroll_loop
        jmp   _nb_kernel201_ia32_sse.nb201_odd_inner
_nb_kernel201_ia32_sse.nb201_unroll_loop: 
        ## quad-unroll innerloop here 
        movl  nb201_innerjjnr(%esp),%edx       ## pointer to jjnr[k] 
        movl  (%edx),%eax
        movl  4(%edx),%ebx
        movl  8(%edx),%ecx
        movl  12(%edx),%edx           ## eax-edx=jnr1-4 

        addl $16,nb201_innerjjnr(%esp)             ## advance pointer (unrolled 4) 

        movl nb201_charge(%ebp),%esi     ## base of charge[] 

        movss (%esi,%eax,4),%xmm3
        movss (%esi,%ecx,4),%xmm4
        movss (%esi,%ebx,4),%xmm6
        movss (%esi,%edx,4),%xmm7

        shufps $0,%xmm6,%xmm3
        shufps $0,%xmm7,%xmm4
        shufps $136,%xmm4,%xmm3 ## constant 10001000 ;# all charges in xmm3  
        movaps %xmm3,%xmm4           ## and in xmm4 
        mulps  nb201_iqO(%esp),%xmm3
        mulps  nb201_iqH(%esp),%xmm4

        movaps  %xmm3,nb201_qqO(%esp)
        movaps  %xmm4,nb201_qqH(%esp)

        movl nb201_pos(%ebp),%esi        ## base of pos[] 

        leal  (%eax,%eax,2),%eax     ## replace jnr with j3 
        leal  (%ebx,%ebx,2),%ebx
        leal  (%ecx,%ecx,2),%ecx     ## replace jnr with j3 
        leal  (%edx,%edx,2),%edx

        ## move four coordinates to xmm0-xmm2   
        movlps (%esi,%eax,4),%xmm4
        movlps (%esi,%ecx,4),%xmm5
        movss 8(%esi,%eax,4),%xmm2
        movss 8(%esi,%ecx,4),%xmm6

        movhps (%esi,%ebx,4),%xmm4
        movhps (%esi,%edx,4),%xmm5

        movss 8(%esi,%ebx,4),%xmm0
        movss 8(%esi,%edx,4),%xmm1

        shufps $0,%xmm0,%xmm2
        shufps $0,%xmm1,%xmm6

        movaps %xmm4,%xmm0
        movaps %xmm4,%xmm1

        shufps $136,%xmm6,%xmm2 ## constant 10001000

        shufps $136,%xmm5,%xmm0 ## constant 10001000
        shufps $221,%xmm5,%xmm1 ## constant 11011101            

        ## move ixO-izO to xmm4-xmm6 
        movaps nb201_ixO(%esp),%xmm4
        movaps nb201_iyO(%esp),%xmm5
        movaps nb201_izO(%esp),%xmm6

        ## calc dr 
        subps %xmm0,%xmm4
        subps %xmm1,%xmm5
        subps %xmm2,%xmm6

        ## store dr 
        movaps %xmm4,nb201_dxO(%esp)
        movaps %xmm5,nb201_dyO(%esp)
        movaps %xmm6,nb201_dzO(%esp)
        ## square it 
        mulps %xmm4,%xmm4
        mulps %xmm5,%xmm5
        mulps %xmm6,%xmm6
        addps %xmm5,%xmm4
        addps %xmm6,%xmm4
        movaps %xmm4,%xmm7
        ## rsqO in xmm7 

        ## move ixH1-izH1 to xmm4-xmm6 
        movaps nb201_ixH1(%esp),%xmm4
        movaps nb201_iyH1(%esp),%xmm5
        movaps nb201_izH1(%esp),%xmm6

        ## calc dr 
        subps %xmm0,%xmm4
        subps %xmm1,%xmm5
        subps %xmm2,%xmm6

        ## store dr 
        movaps %xmm4,nb201_dxH1(%esp)
        movaps %xmm5,nb201_dyH1(%esp)
        movaps %xmm6,nb201_dzH1(%esp)