nb_kernel201_ia32_sse.s

来自「最著名最快的分子模拟软件」· S 代码 · 共 1,574 行 · 第 1/4 页

        movss  %xmm7,8(%edi,%eax,4)

        decl nb201_innerk(%esp)
        jz    _nb_kernel201_ia32_sse.nb201_updateouterdata
        jmp   _nb_kernel201_ia32_sse.nb201_odd_loop
_nb_kernel201_ia32_sse.nb201_updateouterdata: 
        movl  nb201_ii3(%esp),%ecx
        movl  nb201_faction(%ebp),%edi
        movl  nb201_fshift(%ebp),%esi
        movl  nb201_is3(%esp),%edx

        ## accumulate  Oi forces in xmm0, xmm1, xmm2 
        movaps nb201_fixO(%esp),%xmm0
        movaps nb201_fiyO(%esp),%xmm1
        movaps nb201_fizO(%esp),%xmm2

        movhlps %xmm0,%xmm3
        movhlps %xmm1,%xmm4
        movhlps %xmm2,%xmm5
        addps  %xmm3,%xmm0
        addps  %xmm4,%xmm1
        addps  %xmm5,%xmm2 ## sum is in 1/2 in xmm0-xmm2 

        movaps %xmm0,%xmm3
        movaps %xmm1,%xmm4
        movaps %xmm2,%xmm5

        shufps $1,%xmm3,%xmm3
        shufps $1,%xmm4,%xmm4
        shufps $1,%xmm5,%xmm5
        addss  %xmm3,%xmm0
        addss  %xmm4,%xmm1
        addss  %xmm5,%xmm2      ## xmm0-xmm2 has single force in pos0 

        ## increment i force 
        movss  (%edi,%ecx,4),%xmm3
        movss  4(%edi,%ecx,4),%xmm4
        movss  8(%edi,%ecx,4),%xmm5
        addss  %xmm0,%xmm3
        addss  %xmm1,%xmm4
        addss  %xmm2,%xmm5
        movss  %xmm3,(%edi,%ecx,4)
        movss  %xmm4,4(%edi,%ecx,4)
        movss  %xmm5,8(%edi,%ecx,4)

        ## accumulate force in xmm6/xmm7 for fshift 
        movaps %xmm0,%xmm6
        movss %xmm2,%xmm7
        movlhps %xmm1,%xmm6
        shufps $8,%xmm6,%xmm6 ## constant 00001000      

        ## accumulate H1i forces in xmm0, xmm1, xmm2 
        movaps nb201_fixH1(%esp),%xmm0
        movaps nb201_fiyH1(%esp),%xmm1
        movaps nb201_fizH1(%esp),%xmm2

        movhlps %xmm0,%xmm3
        movhlps %xmm1,%xmm4
        movhlps %xmm2,%xmm5
        addps  %xmm3,%xmm0
        addps  %xmm4,%xmm1
        addps  %xmm5,%xmm2 ## sum is in 1/2 in xmm0-xmm2 

        movaps %xmm0,%xmm3
        movaps %xmm1,%xmm4
        movaps %xmm2,%xmm5

        shufps $1,%xmm3,%xmm3
        shufps $1,%xmm4,%xmm4
        shufps $1,%xmm5,%xmm5
        addss  %xmm3,%xmm0
        addss  %xmm4,%xmm1
        addss  %xmm5,%xmm2      ## xmm0-xmm2 has single force in pos0 

        ## increment i force 
        movss  12(%edi,%ecx,4),%xmm3
        movss  16(%edi,%ecx,4),%xmm4
        movss  20(%edi,%ecx,4),%xmm5
        addss  %xmm0,%xmm3
        addss  %xmm1,%xmm4
        addss  %xmm2,%xmm5
        movss  %xmm3,12(%edi,%ecx,4)
        movss  %xmm4,16(%edi,%ecx,4)
        movss  %xmm5,20(%edi,%ecx,4)

        ## accumulate force in xmm6/xmm7 for fshift 
        addss %xmm2,%xmm7
        movlhps %xmm1,%xmm0
        shufps $8,%xmm0,%xmm0 ## constant 00001000      
        addps   %xmm0,%xmm6

        ## accumulate H2i forces in xmm0, xmm1, xmm2 
        movaps nb201_fixH2(%esp),%xmm0
        movaps nb201_fiyH2(%esp),%xmm1
        movaps nb201_fizH2(%esp),%xmm2

        movhlps %xmm0,%xmm3
        movhlps %xmm1,%xmm4
        movhlps %xmm2,%xmm5
        addps  %xmm3,%xmm0
        addps  %xmm4,%xmm1
        addps  %xmm5,%xmm2 ## sum is in 1/2 in xmm0-xmm2 

        movaps %xmm0,%xmm3
        movaps %xmm1,%xmm4
        movaps %xmm2,%xmm5

        shufps $1,%xmm3,%xmm3
        shufps $1,%xmm4,%xmm4
        shufps $1,%xmm5,%xmm5
        addss  %xmm3,%xmm0
        addss  %xmm4,%xmm1
        addss  %xmm5,%xmm2      ## xmm0-xmm2 has single force in pos0 

        ## increment i force 
        movss  24(%edi,%ecx,4),%xmm3
        movss  28(%edi,%ecx,4),%xmm4
        movss  32(%edi,%ecx,4),%xmm5
        addss  %xmm0,%xmm3
        addss  %xmm1,%xmm4
        addss  %xmm2,%xmm5
        movss  %xmm3,24(%edi,%ecx,4)
        movss  %xmm4,28(%edi,%ecx,4)
        movss  %xmm5,32(%edi,%ecx,4)

        ## accumulate force in xmm6/xmm7 for fshift 
        addss %xmm2,%xmm7
        movlhps %xmm1,%xmm0
        shufps $8,%xmm0,%xmm0 ## constant 00001000      
        addps   %xmm0,%xmm6

        ## increment fshift force  
        movlps  (%esi,%edx,4),%xmm3
        movss  8(%esi,%edx,4),%xmm4
        addps  %xmm6,%xmm3
        addss  %xmm7,%xmm4
        movlps  %xmm3,(%esi,%edx,4)
        movss  %xmm4,8(%esi,%edx,4)

        ## get n from stack
        movl nb201_n(%esp),%esi
        ## get group index for i particle 
        movl  nb201_gid(%ebp),%edx              ## base of gid[]
        movl  (%edx,%esi,4),%edx                ## ggid=gid[n]

        ## accumulate total potential energy and update it 
        movaps nb201_vctot(%esp),%xmm7
        ## accumulate 
        movhlps %xmm7,%xmm6
        addps  %xmm6,%xmm7      ## pos 0-1 in xmm7 have the sum now 
        movaps %xmm7,%xmm6
        shufps $1,%xmm6,%xmm6
        addss  %xmm6,%xmm7

        ## add earlier value from mem 
        movl  nb201_Vc(%ebp),%eax
        addss (%eax,%edx,4),%xmm7
        ## move back to mem 
        movss %xmm7,(%eax,%edx,4)

        ## finish if last 
        movl nb201_nn1(%esp),%ecx
        ## esi already loaded with n
        incl %esi
        subl %esi,%ecx
        jz _nb_kernel201_ia32_sse.nb201_outerend

        ## not last, iterate outer loop once more!  
        movl %esi,nb201_n(%esp)
        jmp _nb_kernel201_ia32_sse.nb201_outer
_nb_kernel201_ia32_sse.nb201_outerend: 
        ## check if more outer neighborlists remain
        movl  nb201_nri(%esp),%ecx
        ## esi already loaded with n above
        subl  %esi,%ecx
        jz _nb_kernel201_ia32_sse.nb201_end
        ## non-zero, do one more workunit
        jmp   _nb_kernel201_ia32_sse.nb201_threadloop
_nb_kernel201_ia32_sse.nb201_end: 
        emms

        movl nb201_nouter(%esp),%eax
        movl nb201_ninner(%esp),%ebx
        movl nb201_outeriter(%ebp),%ecx
        movl nb201_inneriter(%ebp),%edx
        movl %eax,(%ecx)
        movl %ebx,(%edx)

        movl nb201_salign(%esp),%eax
        addl %eax,%esp
        addl $744,%esp
        popl %edi
        popl %esi
        popl %edx
        popl %ecx
        popl %ebx
        popl %eax
        leave
        ret




.globl nb_kernel201nf_ia32_sse
.globl _nb_kernel201nf_ia32_sse
nb_kernel201nf_ia32_sse:        
_nb_kernel201nf_ia32_sse:       
.set nb201nf_p_nri, 8
.set nb201nf_iinr, 12
.set nb201nf_jindex, 16
.set nb201nf_jjnr, 20
.set nb201nf_shift, 24
.set nb201nf_shiftvec, 28
.set nb201nf_fshift, 32
.set nb201nf_gid, 36
.set nb201nf_pos, 40
.set nb201nf_faction, 44
.set nb201nf_charge, 48
.set nb201nf_p_facel, 52
.set nb201nf_argkrf, 56
.set nb201nf_argcrf, 60
.set nb201nf_Vc, 64
.set nb201nf_type, 68
.set nb201nf_p_ntype, 72
.set nb201nf_vdwparam, 76
.set nb201nf_Vvdw, 80
.set nb201nf_p_tabscale, 84
.set nb201nf_VFtab, 88
.set nb201nf_invsqrta, 92
.set nb201nf_dvda, 96
.set nb201nf_p_gbtabscale, 100
.set nb201nf_GBtab, 104
.set nb201nf_p_nthreads, 108
.set nb201nf_count, 112
.set nb201nf_mtx, 116
.set nb201nf_outeriter, 120
.set nb201nf_inneriter, 124
.set nb201nf_work, 128
        ## stack offsets for local variables  
        ## bottom of stack is cache-aligned for sse use 
.set nb201nf_ixO, 0
.set nb201nf_iyO, 16
.set nb201nf_izO, 32
.set nb201nf_ixH1, 48
.set nb201nf_iyH1, 64
.set nb201nf_izH1, 80
.set nb201nf_ixH2, 96
.set nb201nf_iyH2, 112
.set nb201nf_izH2, 128
.set nb201nf_iqO, 144
.set nb201nf_iqH, 160
.set nb201nf_qqO, 176
.set nb201nf_qqH, 192
.set nb201nf_vctot, 208
.set nb201nf_half, 224
.set nb201nf_three, 240
.set nb201nf_krf, 256
.set nb201nf_crf, 272
.set nb201nf_krsqO, 288
.set nb201nf_krsqH1, 304
.set nb201nf_krsqH2, 320
.set nb201nf_is3, 336
.set nb201nf_ii3, 340
.set nb201nf_innerjjnr, 344
.set nb201nf_innerk, 348
.set nb201nf_n, 352
.set nb201nf_nn1, 356
.set nb201nf_nri, 360
.set nb201nf_nouter, 364
.set nb201nf_ninner, 368
.set nb201nf_salign, 372
        pushl %ebp
        movl %esp,%ebp
        pushl %eax
        pushl %ebx
        pushl %ecx
        pushl %edx
        pushl %esi
        pushl %edi
        subl $376,%esp          ## local stack space 
        movl %esp,%eax
        andl $0xf,%eax
        subl %eax,%esp
        movl %eax,nb201nf_salign(%esp)

        emms

        ## Move args passed by reference to stack
        movl nb201nf_p_nri(%ebp),%ecx
        movl (%ecx),%ecx
        movl %ecx,nb201nf_nri(%esp)

        ## zero iteration counters
        movl $0,%eax
        movl %eax,nb201nf_nouter(%esp)
        movl %eax,nb201nf_ninner(%esp)

        movl nb201nf_argkrf(%ebp),%esi
        movl nb201nf_argcrf(%ebp),%edi
        movss (%esi),%xmm5
        movss (%edi),%xmm6
        shufps $0,%xmm5,%xmm5
        shufps $0,%xmm6,%xmm6
        movaps %xmm5,nb201nf_krf(%esp)
        movaps %xmm6,nb201nf_crf(%esp)

        ## assume we have at least one i particle - start directly 
        movl  nb201nf_iinr(%ebp),%ecx         ## ecx = pointer into iinr[]      
        movl  (%ecx),%ebx           ## ebx =ii 

        movl  nb201nf_charge(%ebp),%edx
        movss (%edx,%ebx,4),%xmm3
        movss 4(%edx,%ebx,4),%xmm4
        movl nb201nf_p_facel(%ebp),%esi
        movss (%esi),%xmm5
        mulss  %xmm5,%xmm3
        mulss  %xmm5,%xmm4

        shufps $0,%xmm3,%xmm3
        shufps $0,%xmm4,%xmm4
        movaps %xmm3,nb201nf_iqO(%esp)
        movaps %xmm4,nb201nf_iqH(%esp)

        ## create constant floating-point factors on stack
        movl $0x3f000000,%eax   ## constant 0.5 in IEEE (hex)
        movl %eax,nb201nf_half(%esp)
        movss nb201nf_half(%esp),%xmm1
        shufps $0,%xmm1,%xmm1  ## splat to all elements
        movaps %xmm1,%xmm2
        addps  %xmm2,%xmm2      ## constant 1.0
        movaps %xmm2,%xmm3
        addps  %xmm2,%xmm2      ## constant 2.0
        addps  %xmm2,%xmm3      ## constant 3.0
        movaps %xmm1,nb201nf_half(%esp)
        movaps %xmm3,nb201nf_three(%esp)

_nb_kernel201nf_ia32_sse.nb201nf_threadloop: 
        movl  nb201nf_count(%ebp),%esi            ## pointer to sync counter
        movl  (%esi),%eax
_nb_kernel201nf_ia32_sse.nb201nf_spinlock: 
        movl  %eax,%ebx                         ## ebx=*count=nn0
        addl  $1,%ebx                          ## ebx=nn1=nn0+10
        lock 
        cmpxchgl %ebx,(%esi)                    ## write nn1 to *counter,
                                                ## if it hasnt changed.
                                                ## or reread *counter to eax.
        pause                                   ## -> better p4 performance
        jnz _nb_kernel201nf_ia32_sse.nb201nf_spinlock

        ## if(nn1>nri) nn1=nri
        movl nb201nf_nri(%esp),%ecx
        movl %ecx,%edx
        subl %ebx,%ecx
        cmovlel %edx,%ebx                       ## if(nn1>nri) nn1=nri
        ## Cleared the spinlock if we got here.
        ## eax contains nn0, ebx contains nn1.
        movl %eax,nb201nf_n(%esp)
        movl %ebx,nb201nf_nn1(%esp)
        subl %eax,%ebx                          ## calc number of outer lists
        movl %eax,%esi                          ## copy n to esi
        jg  _nb_kernel201nf_ia32_sse.nb201nf_outerstart
        jmp _nb_kernel201nf_ia32_sse.nb201nf_end

_nb_kernel201nf_ia32_sse.nb201nf_outerstart: 
        ## ebx contains number of outer iterations
        addl nb201nf_nouter(%esp),%ebx
        movl %ebx,nb201nf_nouter(%esp)

_nb_kernel201nf_ia32_sse.nb201nf_outer: 
        movl  nb201nf_shift(%ebp),%eax        ## eax = pointer into shift[] 
        movl  (%eax,%esi,4),%ebx                ## ebx=shift[n] 

        leal  (%ebx,%ebx,2),%ebx    ## ebx=3*is 
        movl  %ebx,nb201nf_is3(%esp)            ## store is3 

        movl  nb201nf_shiftvec(%ebp),%eax     ## eax = base of shiftvec[] 

        movss (%eax,%ebx,4),%xmm0
        movss 4(%eax,%ebx,4),%xmm1
        movss 8(%eax,%ebx,4),%xmm2

        movl  nb201nf_iinr(%ebp),%ecx         ## ecx = pointer into iinr[]      
        movl  (%ecx,%esi,4),%ebx            ## ebx =ii 

        movaps %xmm0,%xmm3
        movaps %xmm1,%xmm4
        movaps %xmm2,%xmm5

        leal  (%ebx,%ebx,2),%ebx        ## ebx = 3*ii=ii3 
        movl  nb201nf_pos(%ebp),%eax      ## eax = base of pos[]  
        movl  %ebx,nb201nf_ii3(%esp)

        addss (%eax,%ebx,4),%xmm3
        addss 4(%eax,%ebx,4),%xmm4