shopgoods.as

1.配置java环境

/**
 * @(#)ShopGoods.as
 * 
 * @author soda E-mail:[e-mail]
 * @version 1.0
 * <br>Program Name: NetGame for Blue
 * <br>Date: 2007-5-9
 */
import org.game.context.Session;
import org.blue.net.ConnectJavaServer;
import mx.soda.util.Map;
/**
 * 显示商店物品
 */
class org.game.window.ShopGoods extends MovieClip 
{
	private var itemName:String = "default";
	private var info:String;
	private var connect:ConnectJavaServer;
	private var session:Session;
	private var closeBtn:Button;
	
	public function ShopGoods()
	{
		trace("===ShopGoods====被加载了");
		session = Session.getSession();
		connect = ConnectJavaServer.getConnectJavaServer();
		this.onLoad = function()
		{
			readGoods();
		};
		//关闭物品栏
		closeBtn.onRelease = function()
		{
			this._parent.unloadMovie();
		};
	}
	
	public function setItemName(itemName:String):Void
	{
		this.itemName = itemName;
	}
	
	public function setInfo(info:String):Void
	{
		this.info = info;
	}
	
	public function readGoods()
	{
		trace("开始呼叫服务器了!!!");
		var obj:Object = new Object();
		var par = this;
		var num = 100;
		obj.onResult = function(map:Map)
		{
			var ary:Array = map.values();
			var len:Number = ary.length;
			for(var i:Number = 0; i < len; i++)
			{
				var mc:MovieClip = par.attachMovie("goodsTitleMC", "goodsTitleMC" + i, 16000 + i); 
				mc.setGoods(ary[i].get("goodsName"),ary[i].get("goodsProperty"),ary[i].get("goodsPrice"));
				mc.goodsMC.gotoAndStop(ary[i].get("goodsImage"));
				mc._x = 26;
				mc._y = 42 + i * 56;
			}
		};
		connect.call("NpcEvents","shopGoods",obj,itemName);
	}
}