main.pas

CRC运算

end;

///////////////////////////////////////////////////////////
// 8位CRC：通过查表快速计算，速度快，占用空间多
// 注：数据流是低位先行，与16位CRC相反
// 要预先生成CRC8Tab[256]查表数据
///////////////////////////////////////////////////////////
function QuickCRC8(data, crc: Byte): Word;
begin
  crc := CRC8Tab[crc xor data];
  Result := crc;
{
; MCS51的CRC-8快速查表计算函数
; 要预先生成CRC8查表数据，起始地址CRC8Tab，按顺序存放(256字节)
; 调用：B=原CRC8值(8位，初始值为00h)，A=待计算数据(8位)
; 结果：B=计算后的CRC8值(8位)
QuickCRC8:
        push  dph             ; Save DPH
        push  dpl             ; Save DPL
        push  acc             ; Save Acc
        mov   dptr,#CRC8Tab   ; Point To Table
        xrl   a,b             ; XOR In CRC
        movc  a,@a+dptr       ; Get New CRC Byte
        mov   b,a             ; Store Back
        pop   acc             ; Recover Acc
        pop   dpl             ; Recover DPL
        pop   dph             ; Recover DPH
        ret
}
end;









///////////////////////////////////////////////////////////
// 32位CRC：按位计算，速度最慢，占用空间最少
// 注：数据流是低位先行，与16位CRC相反
///////////////////////////////////////////////////////////
function CalCRC32(data, crc, genpoly: DWord): DWord;
var i: Integer;
begin
  if HighFirst then // 数据流高位先行
  begin
    crc := crc xor (data shl 24);
    for i:=0 to 7 do
      if (crc and $80000000) <> 0 then // 只测试最高位
        crc := (crc shl 1) xor genpoly // 最高位为1，移位和异或处理
      else crc := crc shl 1; // 否则只移位（乘2）
    Result := crc;
  end
  else // 数据流低位先行
  begin
    crc := crc xor data;
    for i:=0 to 7 do
      if (crc and $01) <> 0 then // 只测试最低位
        crc := (crc shr 1) xor genpoly // 最低位为1，移位和异或处理
      else crc := crc shr 1; // 否则只移位（除2）
    Result := crc;
  end;
end;

///////////////////////////////////////////////////////////
// 32位CRC：生成CRC32表(256项)，用于快速查表计算
// 在程序初始化时就先调用，预先生成CRC32Tab[256]查表数据
///////////////////////////////////////////////////////////
procedure InitCRC32Table(genpoly: DWord);
var i: Integer;
begin
  for i:=0 to 255 do
    CRC32Tab[i] := CalCRC32(i,0,genpoly);
end;

///////////////////////////////////////////////////////////
// 32位CRC：通过查表快速计算，速度快，占用空间多
// 注：数据流是低位先行，与16位CRC相反
// 要预先生成CRC32Tab[256]查表数据
///////////////////////////////////////////////////////////
function QuickCRC32(data, crc: DWord): DWord;
begin
  if HighFirst then // 数据流高位先行
  begin
    crc := CRC32Tab[(crc shr 24) xor data] xor (crc shl 8);
    Result := crc;
  end
  else // 数据流低位先行
  begin
    crc := CRC32Tab[Byte(crc xor data)] xor (crc shr 8);
    Result := crc;
  end;

end;










///////////////////////////////////////////////////////////
// 测试比较CRC16/CRC8/CRC32的不同算法
// 若CRC初始值为0，则结果与快速查表表格数据相同
///////////////////////////////////////////////////////////
procedure TForm1.TestCRC16BtnClick(Sender: TObject);
var data, crc, crcstart: Word;
begin
  HighFirst := HighFirstRB.Checked;
  GenPoly16 := StrToIntDef(GenPoly16Edit.Text,0);
  InitCRC16Table(GenPoly16); // 先生成CRC16表(256项)，用于快速查表计算
  crcstart := StrToIntDef(CRCStartEdit.Text,0); // CRC初始值

  Memo1.Clear;
  Memo1.Lines.Add('16bit CRC');
  for data:=0 to 255 do
  begin
    if BitCalcRB.Checked then
      crc := CalCRC16(data,crcstart,GenPoly16) // 按位计算CRC
    else
      crc := QuickCRC16(data,crcstart); // 按字节查表计算CRC
    Memo1.Text := Memo1.Text + IntToHex(crc, 4) + ' ';
  end;
end;

procedure TForm1.TestCRC8BtnClick(Sender: TObject);
var data, crc, crcstart: Byte;
begin
  HighFirst := HighFirstRB.Checked;
  GenPoly8 := StrToIntDef(GenPoly8Edit.Text,0);
  InitCRC8Table(GenPoly8); // 先生成CRC8表(256项)，用于快速查表计算
  crcstart := StrToIntDef(CRCStartEdit.Text,0); // CRC初始值

  Memo1.Clear;
  Memo1.Lines.Add('8bit CRC');
  for data:=0 to 255 do
  begin
    if BitCalcRB.Checked then
      crc := CalCRC8(data,crcstart,GenPoly8) // 按位计算CRC
    else
      crc := QuickCRC8(data,crcstart); // 按字节查表计算CRC
    Memo1.Text := Memo1.Text + IntToHex(crc, 2) + '   ';
  end;
end;

procedure TForm1.TestCRC32BtnClick(Sender: TObject);
var data, crc, crcstart: DWord;
begin
  HighFirst := HighFirstRB.Checked;
  GenPoly32 := StrToIntDef(GenPoly32Edit.Text,0);
  InitCRC32Table(GenPoly32); // 先生成CRC32表(256项)，用于快速查表计算
  crcstart := StrToIntDef(CRCStartEdit.Text,0); // CRC初始值

  Memo1.Clear;
  Memo1.Lines.Add('32bit CRC');
  for data:=0 to 255 do
  begin
    if BitCalcRB.Checked then
      crc := CalCRC32(data,crcstart,GenPoly32) // 按位计算CRC
    else
      crc := QuickCRC32(data,crcstart); // 按字节查表计算CRC
    Memo1.Text := Memo1.Text + IntToHex(crc, 8) + '  ';
  end;
end;

///////////////////////////////////////////////////////////
// 从文本字串中分解出16进制的数据，返回这些8位数据组成的字串
// 文本字串分解规则：
// 1.数据是用16进制表示的8位数据(如FC,3D等)
// 2.每个数据只取最后两个16进制字符，如1F3D只取3D，前面多余部分抛弃
// 3.每个数据之间用空格或回车换行等格式符号隔开
///////////////////////////////////////////////////////////
function GetDataFromText(str: String): String;
var i, p1, p2: Integer;
begin
  Result := '';
  while str <> '' do
  begin
    i := 0;
    p1 := Pos(' ',str);
    p2 := Pos(#13#10,str);

    if p1=1 then // 空格在最前面
    begin Delete(str,1,1); continue; end;
    if p2=1 then // #13#10在最前面
    begin Delete(str,1,2); continue; end;

    if (p1=0) and (p2=0) and (str<>'') then // 都没有找到，结束
    begin
      i := StrToIntDef('$'+str,0);
      Delete(str,1,Length(str));
    end;
    if ((p1>0) and (p2=0)) or // 找到空格
       ((p1>0) and (p2>0) and (p1<p2)) then // 或都找到，但空格在前
    begin
      i := StrToIntDef('$'+Copy(str,1,p1-1),0);
      Delete(str,1,p1);
    end;
    if ((p1=0) and (p2>0)) or // 找到#13#10
       ((p1>0) and (p2>0) and (p1>p2)) then // 或都找到，但空格在后
    begin
      i := StrToIntDef('$'+Copy(str,1,p2-1),0);
      Delete(str,1,p2+1);
    end;
    Result := Result + Chr(i); // 8位数据转为字符
  end; // while
end;

///////////////////////////////////////////////////////////
// 计算一组数据的CRC16/CRC8/CRC32结果
// 数据来源于文本框中的数据字串
///////////////////////////////////////////////////////////
procedure TForm1.CalCRC16BtnClick(Sender: TObject);
var
  i: Integer;
  databuf: String;
  data, crc: Word;
begin
  HighFirst := HighFirstRB.Checked;
  GenPoly16 := StrToIntDef(GenPoly16Edit.Text,0);
  InitCRC16Table(GenPoly16); // 先生成CRC16表(256项)，用于快速查表计算
  crc := StrToIntDef(CRCStartEdit.Text,0); // CRC初始值

  databuf := GetDataFromText(Memo1.Text); // 从文本中读取数据
  for i:=1 to Length(databuf) do
  begin
    data := Ord(databuf[i]); // 字符转为8位数据
    if BitCalcRB.Checked then
      crc := CalCRC16(data,crc,GenPoly16) // 按位计算CRC
    else
      crc := QuickCRC16(data,crc); // 快速查表计算CRC
  end;
  CRC16ResultEdit.Text := '$' + IntToHex(crc,4); // 显示结果
end;

procedure TForm1.CalCRC8BtnClick(Sender: TObject);
var
  i: Integer;
  databuf: String;
  data, crc: Byte;
begin
  HighFirst := HighFirstRB.Checked;
  GenPoly8 := StrToIntDef(GenPoly8Edit.Text,0);
  InitCRC8Table(GenPoly8); // 先生成CRC8表(256项)，用于快速查表计算
  crc := StrToIntDef(CRCStartEdit.Text,0); // CRC初始值

  databuf := GetDataFromText(Memo1.Text); // 从文本中读取数据
  for i:=1 to Length(databuf) do
  begin
    data := Ord(databuf[i]); // 字符转为8位数据
    if BitCalcRB.Checked then
      crc := CalCRC8(data,crc,GenPoly8) // 按位计算CRC
    else
      crc := QuickCRC8(data,crc); // 快速查表计算CRC
  end;
  CRC8ResultEdit.Text := '$' + IntToHex(crc,2); // 显示结果
end;

procedure TForm1.CalCRC32BtnClick(Sender: TObject);
var
  i: Integer;
  databuf: String;
  data, crc: DWord;
begin
  HighFirst := HighFirstRB.Checked;
  GenPoly32 := StrToIntDef(GenPoly32Edit.Text,0);
  InitCRC32Table(GenPoly32); // 先生成CRC32表(256项)，用于快速查表计算
  crc := StrToIntDef(CRCStartEdit.Text,0); // CRC初始值

  databuf := GetDataFromText(Memo1.Text); // 从文本中读取数据
  for i:=1 to Length(databuf) do
  begin
    data := Ord(databuf[i]); // 字符转为8位数据
    if BitCalcRB.Checked then
      crc := CalCRC32(data,crc,GenPoly32) // 按位计算CRC
    else
      crc := QuickCRC32(data,crc); // 快速查表计算CRC
  end;
  if FlipResultCB.Checked then crc := not crc;
  CRC32ResultEdit.Text := '$' + IntToHex(crc,8); // 显示结果
  // 由于是低位先行，计算得到的CRC-32也要按低字节在先的顺序排列
  // 比如数据12 34，计算CRC-32=59408466，结果要按66 84 40 59顺序
  // 最后验证数据正确性时，12 34 66 84 40 59的CRC-32=0
end;

end.