timer.hs

Cores are generated from Confluence a modern logic design language. Confluence is a simple, yet high

-- | General purpose timers.
module Language.Atom.Common.Timer
  ( Timer
  , timer
  , start
  , whenDone
  , periodicTimer
  ) where

import Language.Atom

-- | A Timer.
data Timer = Timer (Var Int)

-- | Creates a new timer, with a name and a count.
timer :: Name -> System Timer
timer name = scope name $ do
  timer <- int "timer" 0

  rule "decrement" $ do
    when $ value timer >. 0
    timer <== value timer - 1

  return $ Timer timer

-- | Starts a Timer.  A Timer can be restarted at any time.
start :: Timer -> Int -> Action ()
start (Timer t) time = do
  lift $ assert "positiveTime" $ time >= 0
  t <== intC (max 0 (time - 1))

-- | Guard condition enabled with Timer completes.
whenDone :: Timer -> Action ()
whenDone (Timer t) = when $ value t ==. 0

-- | Creates a periodic, free runnning timer.  Returns a guard condition when Timer resets.
periodicTimer :: Name -> Int -> System (Action ())
periodicTimer name count = scope name $ do
  assert "positiveNumber" $ count >= 0
  t <- timer name

  rule "reset" $ do
    whenDone t
    start t count

  return $ whenDone t