delaytransition.hs

Cores are generated from Confluence a modern logic design language. Confluence is a simple, yet high

-- | Transition delays of boolean signal.
module Language.Atom.Common.DelayTransition
  ( delayRise
  , delayFall
  ) where

import Language.Atom
import Language.Atom.Common.OneShot
import Language.Atom.Common.Timer

-- | Delays the rise of a Term Bool by a given number of cycles.  A fall is immediate.
delayRise :: Name -> Int -> Term Bool -> System (Term Bool)
delayRise name num input = scope name $ do
  assert "positiveNumber" $ num >= 0
  t     <- timer "timer"
  state <- bool "state" False
  rise  <- oneShotRise "oneShot" input

  rule "start" $ do
    when rise
    start t num

  rule "set" $ do
    whenDone t
    when input
    state <== true

  rule "clear" $ do
    when $ inv input
    state <== false

  return $ input &&. value state

-- | Delays the fall of a Term Bool by a given number of cycles.  A rise is immediate.
delayFall :: Name -> Int -> Term Bool -> System (Term Bool)
delayFall name num input = do
  o <- delayRise name num $ inv input
  return $ inv o