nxclient.pro

linux下的终端管理工具源码

TARGET = nxclient

mac:RC_FILE = nx.icns

TEMPLATE = app
CONFIG += qt warn_on release thread create_prl link_prl
DEFINES += ENABLE_TEXT_PASSWORD

# the line below will be automaticly overwritten everytime
# configure script is run
DEFINES += NXCLIENT_VERSION=\"1.5.0-77\"

win32:DEFINES += NX_WIN32
mac:DEFINES += NX_MACOSX
unix:LIBS += -L/usr/X11R6/lib -lxkbfile
mac:LIBS += -L/usr/X11R6/lib -lX11 -lXext
DBFILE = nxclient.db
LANGUAGE = C++

QMAKE_CLEAN = Makefile .qmake.internal.cache *.swp *.ori *.orig .* *.ncb moc_*

HEADERS   = ComboSession.h \
            WndShareName.h \
            DetailsWindow.h \
            LoginDialog.h \
            ProgressDialog.h \
            NXClientVersion.h \
            WndReconnect.h \
            Pixmaps.h \
            SessionFactory.h \
            SessionSettings.h \
            Utility.h \
            WndSessionWizard.h \
            WndSessionSettings.h \
            WndSessionsAdmin.h \
            WndSessionsList.h \
            WndSessionSettingsVNC.h \
            WndSessionSettingsRDP.h \
            WndSessionSettingsCustom.h \
            WndSessionSettingsXDM.h \
            WndImageSettingsVNC.h \
            WndImageSettingsRDP.h \
            WndImageSettingsUnix.h \
            confsaveDialog.h \
            kb.h \
            Settings.h \
            md5.h \
            WndAbout.h \
            AlertMessageManager.h \
            PixmapView.h \
            nxprocess.h \
	    nxfilemonitor.h \
            nxprotocol.h \
            nxproxyprotocol.h \
            Share.h \
            WidgetShareMountPoint.h \
            WidgetSharePrinterConfig.h \
            WidgetShareCredentials.h \
            NXKeyboard.h \
            NXApplication.h \
            WndPrinterConfig.h \
	    NXReconnect.h \
	    NXProfile.h \
            WndRootLoginWarning.h \
	    WndFullScreenInfo.h \
	    WndProfileList.h \
            WndAskForSystemDir.h \
            WndAskForPersonalDir.h \
            WndKeyManager.h \
            WndPulldownDialog.h


SOURCES   = Main.cpp \
            ComboSession.cpp \
            WndShareName.cpp \
            DetailsWindow.cpp \
            LoginDialog.cpp \
            ProgressDialog.cpp \
            Pixmaps.cpp \
            PixmapView.cpp \
            SessionFactory.cpp \
            SessionSettings.cpp \
            Utility.cpp \
            WndSessionWizard.cpp \
            WndSessionSettings.cpp \
            WndSessionsAdmin.cpp \
            WndSessionsList.cpp \
            WndSessionSettingsVNC.cpp \
            WndSessionSettingsRDP.cpp \
            WndSessionSettingsCustom.cpp \
            WndSessionSettingsXDM.cpp \
            WndImageSettingsVNC.cpp \
            WndImageSettingsRDP.cpp \
            WndImageSettingsUnix.cpp \
            confsaveDialog.cpp \
            kb.cpp \
            Settings.cpp \
            md5.c \
            WndAbout.cpp \
            AlertMessageManager.cpp \
            WndReconnect.cpp \
            nxprocess.cpp \
            nxfilemonitor.cpp \
            nxprotocol.cpp \
            nxproxyprotocol.cpp \
            Share.cpp \
            NXKeyboard.cpp \
            NXApplication.cpp \
            WndPrinterConfig.cpp \
	    NXReconnect.cpp \
	    NXProfile.cpp \
	    WndRootLoginWarning.cpp \
	    WndFullScreenInfo.cpp \
	    WndProfileList.cpp \
            WndAskForSystemDir.cpp \
            WndAskForPersonalDir.cpp \
            WndKeyManager.cpp \
            WndPulldownDialog.cpp

FORMS =   DetailsDialog.ui \
          GuiShareName.ui  \
          GuiImageSettingsRDP.ui \
          GuiImageSettingsVNC.ui \
          GuiImageSettingsUnix.ui \
          GuiSessionSettingsVNC.ui \
          GuiSessionSettingsRDP.ui \
          GuiSessionSettingsXDM.ui \
          GuiSessionSettingsCustom.ui \
          GuiSessionWizard.ui \
          GuiSessionsList.ui \
          LoginWidget.ui \
          GuiProgressDialog.ui \
          saveconfigurationDialog.ui \
          GuiAbout.ui \
          GuiReconnect.ui \
          GuiShareMountPointWidget.ui \
          GuiSharePrinterConfigWidget.ui \
          GuiShareCredentials.ui \
          GuiPrinterConfig.ui \
	  GuiAskForDir.ui \
          GuiKeyManager.ui 

unix{
  HEADERS += nxprocess_unix.h 
  SOURCES += nxprocess_unix.cpp 
  FORMS   += GuiSessionSettings.ui
}

win32{
  HEADERS += nxprocess_win.h
  SOURCES += nxprocess_win.cpp
  FORMS   += GuiSessionSettings-win32.ui
}

macx{
  HEADERS += WndSelectXServer.h \
             nxcompsh/Display.h \
             nxcompsh/Timestamp.h \
             nxcompsh/System.h \
             nxcompsh/Logger.h \
             nxcompsh/Process.h \
             nxcompsh/Listener.h \
             nxcompsh/Connector.h \
             nxcompsh/Runnable.h \
             nxcompsh/Misc.h \
             nxcompsh/Socket.h

  SOURCES += WndSelectXServer.cpp \
             nxcompsh/Display.cpp \
             nxcompsh/System.cpp \
             nxcompsh/Logger.cpp \
             nxcompsh/Process.cpp \
             nxcompsh/Listener.cpp \
             nxcompsh/Connector.cpp \
             nxcompsh/Runnable.cpp \
             nxcompsh/Socket.cpp

  FORMS -= GuiSessionSettings.ui
  FORMS += GuiSessionSettings-macosx.ui
}