roadnav.iss

Powerful and Portable GPS application -- support Linux, Windows, Windows CE GPS navigation and Map m

[Setup]
AppName=Roadnav
AppVerName=Roadnav v$VERSION$
AppPublisher=Richard L. Lynch
AppSupportURL=http://roadnav.sourceforge.net/
DefaultDirName={pf}\Roadnav
DefaultGroupName=Roadnav
LicenseFile=..\..\COPYING
OutputBaseFilename=roadnav-$VERSION$-win32

[Tasks]
Name: "desktopicon"; Description: "Create &desktop icon"; GroupDescription: "Additional icons"
Name: "source"; Description: "Install &source code"; GroupDescription: "Additional files"; Flags: unchecked

[Run]
Filename: "{app}\roadnav.exe"; WorkingDir: "{app}"; Description: "Launch Roadnav"; Flags: nowait postinstall

[Files]
Source: "..\MSVC8\Release Unicode\roadnav.exe"; DestDir: "{app}"; Flags: ignoreversion; MinVersion: 0, 1
Source: "..\MSVC8\Release\roadnav.exe"; DestDir: "{app}"; Flags: ignoreversion; MinVersion: 1, 0
Source: "..\..\README"; DestDir: "{app}"; Flags: ignoreversion
Source: "..\..\COPYING"; DestDir: "{app}"; Flags: ignoreversion
Source: "..\..\AUTHORS"; DestDir: "{app}"; Flags: ignoreversion
Source: "..\..\ChangeLog"; DestDir: "{app}"; Flags: ignoreversion
Source: "..\..\INSTALL"; DestDir: "{app}"; Flags: ignoreversion
Source: "..\..\NEWS"; DestDir: "{app}"; Flags: ignoreversion
Source: "..\..\TODO"; DestDir: "{app}"; Flags: ignoreversion
Source: "..\..\data\*"; Excludes: "Makefile*"; DestDir: "{app}"
Source: "..\..\skins\*"; Excludes: "Makefile*"; DestDir: "{app}\skins"; Flags: recursesubdirs ignoreversion
Source: "..\..\*"; Excludes: "Output,roadnavprocessed.iss,Release,Release Unicode,Debug,Debug Unicode,Debug Unicode No GPSD,*.ncb,*.opt,*.plg,*.aps,*.exe,docs,build.log"; DestDir: "{app}\Source"; Flags: recursesubdirs ignoreversion; Tasks: source
Source: "C:\Program Files (x86)\Microsoft Visual Studio 8\vcredist_x86.exe"; DestDir: "{app}"; Flags: dontcopy

[Registry]
Root: HKCU; Subkey: "Software\Roadnav"; Flags: uninsdeletekey

[UninstallDelete]
Type: filesandordirs; Name: "{userappdata}\roadnavdata"
Type: files; Name: "{userappdata}\..\Roadnav.ini"

[Icons]
Name: "{group}\Roadnav"; Filename: "{app}\roadnav.exe"
Name: "{commondesktop}\Roadnav"; Filename: "{app}\roadnav.exe"; Tasks: desktopicon

;/////////////////////////////////////////////////////////////////////////////////////
; Pascal code related to the installation
;/////////////////////////////////////////////////////////////////////////////////////

[Code]
function NextButtonClick(CurPage: Integer): Boolean;
var
  ErrorCode: Integer;
  ProgressPage: TOutputProgressWizardPage;
begin
	case CurPage of
	wpReady:
		begin
			/////////////////////////////////////////////////////////////////////////////////////
			// this executes right before files are unpacked and the actual installation begins
			/////////////////////////////////////////////////////////////////////////////////////
			
			ProgressPage := CreateOutputProgressPage('Installing', 'Please wait while Setup installs Roadnav on your computer.');
			ProgressPage.Show;
			
			try
				ProgressPage.SetText('Installing Microsoft Visual C++ 2005 Redistributable Package...', '');
				ExtractTemporaryFile('vcredist_x86.exe')

				if not Exec(ExpandConstant('{tmp}\vcredist_x86.exe'), '/q:a', '', SW_SHOW, ewWaitUntilTerminated, ErrorCode) then
					MsgBox('Error installing Microsoft Visual C++ 2005 Redistributable Package', mbError, MB_OK);

			finally
				ProgressPage.Hide;
			end;

			BringToFrontAndRestore();
		end;
	end;
	
	Result := True;
end;