grouprenderer.frm

MO+VB的很多个简单示例

VERSION 5.00
Object = "{9BD6A640-CE75-11D1-AF04-204C4F4F5020}#2.0#0"; "mo20.ocx"
Begin VB.Form Form1 
   Caption         =   "GroupRenderer对象实例"
   ClientHeight    =   4335
   ClientLeft      =   1830
   ClientTop       =   1470
   ClientWidth     =   7080
   LinkTopic       =   "Form1"
   PaletteMode     =   1  'UseZOrder
   ScaleHeight     =   4335
   ScaleWidth      =   7080
   Begin VB.CheckBox Check3 
      Caption         =   "是否显示底图"
      Height          =   375
      Left            =   120
      TabIndex        =   2
      Top             =   3720
      Width           =   2055
   End
   Begin VB.CommandButton Command2 
      Caption         =   "缩小"
      Height          =   495
      Left            =   5760
      TabIndex        =   1
      Top             =   3720
      Width           =   1215
   End
   Begin VB.CommandButton Command1 
      Caption         =   "全图显示"
      Height          =   495
      Left            =   4440
      TabIndex        =   0
      Top             =   3720
      Width           =   1215
   End
   Begin MapObjects2.Map Map1 
      Height          =   3495
      Left            =   120
      TabIndex        =   3
      Top             =   120
      Width           =   6855
      _Version        =   131072
      _ExtentX        =   12091
      _ExtentY        =   6165
      _StockProps     =   225
      BackColor       =   16777215
      BorderStyle     =   1
      Contents        =   "GroupRenderer.frx":0000
   End
End
Attribute VB_Name = "Form1"
Attribute VB_GlobalNameSpace = False
Attribute VB_Creatable = False
Attribute VB_PredeclaredId = True
Attribute VB_Exposed = False
Sub SetupLayers()
  '调入数据
  Dim dc As New DataConnection
  'MapObjects自带的USA地图
  '默认路径为C:\Program Files\ESRI\MapObjects2\Samples\Data\USA
  dc.Database = "C:\Program Files\ESRI\MapObjects2\Samples\Data\USA"
  '若连接地理数据库失败，则结束程序
  If Not dc.Connect Then End
  '调入图层states.shp
  Dim layer As New MapLayer
  Set layer.GeoDataset = dc.FindGeoDataset("states")
  Map1.Layers.Add layer
End Sub

Sub SetupRenderers()
  '建立ChartRenderer对象和ValueMapRenderer对象，并设置好其属性
  Dim ChartRendererX As New MapObjects2.ChartRenderer
  Dim ValueMapRendererX As New MapObjects2.ValueMapRenderer
  
  '设置ChartRenderer对象的属性
  '根据pop1990字段值显示统计图表
  With ChartRendererX
    .ChartType = moPie
    .FieldCount = 2
    .Field(0) = "White"
    .Field(1) = "Black"
    .Color(0) = moRed
    .Color(1) = moGreen
    .MinPieSize = 8
    .MaxPieSize = 24
    .SizeField = "pop1990"
    .NormalizationField = "area"
  End With
  
  Dim strs As New MapObjects2.Strings
  strs.Unique = True
  
  Dim recset As MapObjects2.Recordset
  Set recset = Map1.Layers("states").Records
  Do Until recset.EOF
    strs.Add recset.Fields("sub_region").ValueAsString
    recset.MoveNext
  Loop
  
  Dim s As Variant
  Dim i As Integer
    
  '设置ValueMapRenderer对象的属性
  With ValueMapRendererX
    .UseDefault = True
    .SymbolType = moFillSymbol
    .Field = "sub_region"
    .ValueCount = strs.Count
      
    i = 0
    For Each s In strs
      .Value(i) = s
      .Symbol(i).Color = QBColor(i + 1)
      i = i + 1
    Next
  End With

  '再建立GroupRenderer对象，将上述两个Renderer添加到其中
  Dim GroupRendererX As New MapObjects2.GroupRenderer
  GroupRendererX.Add ValueMapRendererX
  GroupRendererX.Add ChartRendererX

  '将GroupRenderer对象赋值给MapLayer
  Map1.Layers.Item("States").Renderer = GroupRendererX

End Sub

'"同时显示标注和底图"复选框鼠标单击事件响应代码
Private Sub Check3_Click()
  '设置是否同时显示文本标注和底图
  Set r = Map1.Layers("states").Renderer
  r.DrawBackground = Check3.Value = 1
  Map1.Refresh

End Sub

'"全图显示"按钮鼠标单击事件响应代码
Private Sub Command1_Click()
  '设置地图显示范围为全图
  Map1.Extent = Map1.FullExtent
End Sub

'"缩小"按钮鼠标单击事件响应代码
Private Sub Command2_Click()
  '将地图显示范围扩大1.5倍
  Set r = Map1.Extent
  r.ScaleRectangle 1.5
  Map1.Extent = r
End Sub

Private Sub Form_Load()
  SetupLayers
  SetupRenderers
End Sub

'Map Control控件MouseDown事件响应代码
Private Sub Map1_MouseDown(Button As Integer, Shift As Integer, _
                            x As Single, y As Single)
  '放大地图区域
  Set r = Map1.TrackRectangle
  If Not r Is Nothing Then Map1.Extent = r
End Sub