subc.vhd

Cadence的VHDL运算库包

-------------------------------------------------------------------------------
-- Title       : Parallel-prefix subtractor with carry-in, carry-out
-- Project     : VHDL Library of Arithmetic Units
-------------------------------------------------------------------------------
-- File        : SubC.vhd
-- Author      : Reto Zimmermann  <[e-mail]>
-- Company     : Integrated Systems Laboratory, ETH Zurich
-- Date        : 1997/11/04
-------------------------------------------------------------------------------
-- Copyright (c) 1998 Integrated Systems Laboratory, ETH Zurich
-------------------------------------------------------------------------------
-- Description :
-- Binary subtractor using parallel-prefix carry-lookahead logic with:
--   - carry-in (CI), subtracted
--   - carry-out (CO), '1' if subtraction result is negative
-------------------------------------------------------------------------------

library ieee;
use ieee.std_logic_1164.all;
library synergy;  use synergy.signed_arith.all;
library arith_lib;
use arith_lib.arith_lib.all;

-------------------------------------------------------------------------------

entity SubC is

  generic (width : positive := 8;  	-- word width
	   speed : speedType := fast);  -- performance parameter

  port (A, B : in std_logic_vector(width-1 downto 0);  -- operands
        CI : in std_logic;  		-- carry in (subtracted)
	S : out std_logic_vector(width-1 downto 0);  -- sum
        CO : out std_logic);  		-- carry out ('1' if S negative)

end SubC;

-------------------------------------------------------------------------------

architecture Behavioral of SubC is

  signal Auns, Buns, CIuns, Suns : unsigned(width downto 0);  -- unsigned

begin

  -- type conversion: std_logic_vector -> unsigned
  Auns <= conv_unsigned(A, width+1);
  Buns <= conv_unsigned(B, width+1);
  CIuns <= (0 => CI, others => '0');

  -- subtraction
  Suns <= Auns - Buns - CIuns;

  -- type conversion: unsigned -> std_logic_vector
  S <= std_logic_vector(Suns(width-1 downto 0));
  CO <= Suns(width);

end Behavioral;

-------------------------------------------------------------------------------

architecture Structural of SubC is 

  signal BI : std_logic_vector(width-1 downto 0);  -- B inverted
  signal CII : std_logic;		-- CI inverted
  signal GI, PI : std_logic_vector(width-1 downto 0);  -- prefix gen./prop. in
  signal GO, PO : std_logic_vector(width-1 downto 0);  -- prefix gen./prop. out
  signal PT : std_logic_vector(width-1 downto 0);  -- adder propagate temp

begin

  -- invert B and CI for subtraction
  BI <= not B;
  CII <= not CI;
  
  -- calculate prefix input generate/propagate signal (0)
  GI(0) <= (A(0) and BI(0)) or (A(0) and CII) or (BI(0) and CII);
  PI(0) <= '0';
  -- calculate adder propagate signal (0) (PT = A xor B)
  PT(0) <= A(0) xor BI(0);
  -- calculate prefix input generate/propagate signals (1 to width-1)
  preproc : for i in width-1 downto 1 generate
    GI(i) <= A(i) and BI(i);
    PI(i) <= A(i) or BI(i);
    -- calculate adder propagate signal (1 to width-1) (PT = A xor B)
    PT(i) <= not GI(i) and PI(i);
  end generate preproc;

  -- calculate prefix output generate/propagate signals
  prefix : PrefixAndOr
    generic map (width, speed)
    port map (GI, PI, GO, PO);

  -- calculate sum and carry-out bits
  S <= PT xor GO(width-2 downto 0) & CII;
  CO <= not GO(width-1);

end Structural;

-------------------------------------------------------------------------------