addmuluns.vhd

Cadence的VHDL运算库包

-------------------------------------------------------------------------------
-- Title       : Unsigned adder-multiplier
-- Project     : VHDL Library of Arithmetic Units
-------------------------------------------------------------------------------
-- File        : AddMulUns.vhd
-- Author      : Reto Zimmermann  <[e-mail]>
-- Company     : Integrated Systems Laboratory, ETH Zurich
-- Date        : 1997/11/19
-------------------------------------------------------------------------------
-- Copyright (c) 1998 Integrated Systems Laboratory, ETH Zurich
-------------------------------------------------------------------------------
-- Description :
-- Adder-multiplier for unsigned numbers (Brown). First adds two numbers, then
-- multiplies the result with the multiplicand. Can be used for multiplication
-- with an input operand in carry-save number format. Result is only valid if
-- sum does not overflow.
-------------------------------------------------------------------------------

library ieee;
use ieee.std_logic_1164.all;
library synergy;  use synergy.signed_arith.all;
library arith_lib;
use arith_lib.arith_lib.all;

-------------------------------------------------------------------------------

entity AddMulUns is

  generic (widthX : positive := 8;     -- word width of XS, XC (<= widthY)
	   widthY : positive := 8;     -- word width of Y
	   speed : speedType := fast);  -- performance parameter

  port (XS, XC : in std_logic_vector(widthX-1 downto 0);  -- multipliers
	Y : in std_logic_vector(widthY-1 downto 0);  -- multiplicand
        P : out std_logic_vector(widthX+widthY-1 downto 0));  -- product

end AddMulUns;

-------------------------------------------------------------------------------

architecture Behavioral of AddMulUns is

  signal XSuns, XCuns : unsigned(widthX-1 downto 0);  -- unsigned
  signal Yuns : unsigned(widthY-1 downto 0);  -- unsigned
  signal Puns : unsigned(widthX+widthY-1 downto 0);  -- unsigned

begin

  -- type conversion: std_logic_vector -> unsigned
  XSuns <= unsigned(XS);
  XCuns <= unsigned(XC);
  Yuns <= unsigned(Y);

  -- addition and multiplication
  Puns <= (XSuns + XCuns) * Yuns;

  -- type conversion: unsigned -> std_logic_vector
  P <= std_logic_vector(Puns);

end Behavioral;

-------------------------------------------------------------------------------

architecture Structural of AddMulUns is 

						-- partial products
  signal PP : std_logic_vector(widthX*(widthX+widthY)-1 downto 0);
						-- intermediate sum/carry bits
  signal ST, CT : std_logic_vector(widthX+widthY-1 downto 0); 

begin

  -- generation of partial products
  ppGen : AddMulPPGenUns
    generic map (widthX, widthY)
    port map (XS, XC, Y, PP);

  -- carry-save addition of partial products
  csvAdd : AddMopCsv
    generic map (widthX+widthY, widthX, speed)
    port map (PP, ST, CT);

  -- final carry-propagate addition
  cpAdd : Add
    generic map (widthX+widthY, speed)
    port map (ST, CT, P);

end Structural;

-------------------------------------------------------------------------------