configure.in

system c 是在C环境下的硬件描述语言,比VHDL 等语言具有更强的抽象能力,内有system C的开发支持库和一些VC下的开发例程

dnl ***************************************************************************
dnl
dnl  The following code is released by Synopsys, Inc., Copyright (c) 1996-2001,
dnl  Synopsys, Inc., CoWare, Inc., Frontier Design, Inc. and others.
dnl  All Rights reserved.
dnl
dnl  The contents of this file are subject to the restrictions and limitations
dnl  set forth in the SystemC Open Source License Version 2.2 (the "License");
dnl  You may not use this file except in compliance with such restrictions and
dnl  limitations. You may obtain instructions on how to receive a copy of the
dnl  License at http://www.systemc.org/. Software distributed by Contributors
dnl  under the License is distributed on an "AS IS" basis, WITHOUT WARRANTY OF
dnl  ANY KIND, either express or implied. See the License for the specific
dnl  language governing rights and limitations under the License.
dnl
dnl ***************************************************************************
dnl
dnl  configure.in --
dnl  Process this file with autoconf to produce a configure script.
dnl
dnl  Original Author: Martin Janssen, Synopsys, Inc., 2001-05-21
dnl
dnl ***************************************************************************
dnl
dnl  MODIFICATION LOG - modifiers, enter your name, affiliation, date and
dnl  changes you are making here.
dnl
dnl      Name, Affiliation, Date:
dnl  Description of Modification:
dnl
dnl ***************************************************************************

dnl
dnl Initialization.
dnl

AC_INIT(NEWS)
AC_CONFIG_AUX_DIR(config)

dnl
dnl Some simple checks.
dnl

AC_CANONICAL_SYSTEM
AM_INIT_AUTOMAKE(package,version,do-no-define)

AC_PROG_CC
AC_PROG_CXX
AC_PROG_RANLIB
AC_PROG_INSTALL

dnl
dnl Set the compiler flags and target architecture.
dnl

CXX_COMP=`basename $CXX`
AR_TOOL="ar cru"

case "$target" in
    sparc-sun-solaris*) 
        case "$CXX_COMP" in
            CC)
                EXTRA_CXXFLAGS=""
                DEBUG_CXXFLAGS="-g "
                OPT_CXXFLAGS="-O3"
                TARGET_ARCH=sparcOS5
		AR_TOOL="CC -xar -o"
        	CC="cc"
        	CFLAGS="-xO2"
                ;;
            c++ | g++)
                EXTRA_CXXFLAGS="-Wall"
                DEBUG_CXXFLAGS="-g -O0"
                OPT_CXXFLAGS="-O3"
                TARGET_ARCH=gccsparcOS5
        	CC="gcc -ansi -Wall -pedantic"
        	CFLAGS="-O2"
                ;;
            *)
                AC_MSG_ERROR("sorry...compiler not supported")
		;;
        esac
        QT_ARCH="sparc-os2"
        ;;
    *linux*)
        case "$CXX_COMP" in
            c++ | g++)
                EXTRA_CXXFLAGS="-Wall"
                DEBUG_CXXFLAGS="-g -O0"
                OPT_CXXFLAGS="-O3"
                TARGET_ARCH=linux
        	CC="gcc -ansi -Wall -pedantic"
        	CFLAGS="-O2"
                ;;
            *)
                AC_MSG_ERROR("sorry...compiler not supported")
		;;
        esac
        QT_ARCH="iX86"
        ;;
    *hpux10*)
        case "$CXX_COMP" in
            aCC)
                EXTRA_CXXFLAGS="-Aa +DA2.0 +DS2.0"
                DEBUG_CXXFLAGS="-g "
                OPT_CXXFLAGS="+O1"
                TARGET_ARCH=hpux10
		CC="cc -Ae +DA2.0 +DS2.0"
        	CFLAGS="-O"
                ;;
            c++ | g++)
                EXTRA_CXXFLAGS="-Wall"
                DEBUG_CXXFLAGS="-g -O0"
                OPT_CXXFLAGS="-O3"
                TARGET_ARCH=gcchpux10
        	CC="gcc -ansi -Wall -pedantic"
        	CFLAGS="-O2"
                ;;
            *)
                AC_MSG_ERROR("sorry...compiler not supported")
		;;
        esac
        QT_ARCH="hppa"
        ;;
    *hpux11*)
        case "$CXX_COMP" in
            aCC)
                EXTRA_CXXFLAGS="-Aa +DA2.0 +DS2.0"
                DEBUG_CXXFLAGS="-g "
                OPT_CXXFLAGS="+O1"
                TARGET_ARCH=hpux11
		CC="cc -Ae +DA2.0 +DS2.0"
        	CFLAGS="-O"
                ;;
            *)
                AC_MSG_ERROR("sorry...compiler not supported")
		;;
        esac
        QT_ARCH="hppa"
        ;;
    *)
        AC_MSG_ERROR("sorry...architecture not supported")
        ;;
esac

dnl
dnl The fixed-point datatypes "package" (default included).
dnl

SYSTEMC_CORE_DIR="systemc_core"
AC_ARG_WITH(systemc_core,
[  --with-systemc-core=""         location of systemc core libraries],[
    if test "x$with_systemc_core" != x ; then
        SYSTEMC_CORE_DIR=$with_systemc_core;
	EXTRA_CXXFLAGS="$EXTRA_CXXFLAGS -I${SYSTEMC_CORE_DIR}/include/";
    fi
])

CXXFLAGS="$EXTRA_CXXFLAGS $OPT_CXXFLAGS"

dnl
dnl Set the default prefix and make sure the prefix is absolute.
dnl

test "x$prefix" = xNONE && prefix=$srcdir
current_dir=`pwd`; cd $prefix; prefix=`pwd`; cd $current_dir

dnl
dnl Substitution variables.
dnl

AC_SUBST(EXTRA_CXXFLAGS)
AC_SUBST(DEBUG_CXXFLAGS)
AC_SUBST(OPT_CXXFLAGS)
AC_SUBST(TARGET_ARCH)
AC_SUBST(FX_DIR)
AC_SUBST(QT_ARCH)
AC_SUBST(AR_TOOL)

dnl
dnl Create the Makefiles.
dnl

AC_OUTPUT(Makefile src/Makefile src/sc_ms/Makefile examples/Makefile examples/sc_ms/Makefile)

dnl Taf!