mail_fun.asp

同学录的设计

<%
Rem		Jmail发送函数，返回值参考：1成功，2失败，0不支持
Function SendJmail(Email,Topic,MailBody,sendmail)

	Dim JMail
	on error resume next
	Set JMail = Server.CreateObject("JMail.SMTPMail")
	if not isobject(Jmail) Then
		SendJmail=0
		exit function
	end if
	JMail.Logging = True
	JMail.Charset = "gb2312"
	JMail.ContentType  =  "text/html"
	'JMail.ServerAddress = "smtp.sina.com.cn" '发送服务器
	JMail.Sender = sendmail '发送人邮箱地址
	JMail.Subject = Topic
	JMail.Body = MailBody
	JMail.AddRecipient Email
	JMail.Priority =3
	
	If JMail.Execute() = false Then
		SendJmail = 2
	Else
		SendJmail = 1
	End If
	JMail.Close
	Set JMail = Nothing

End Function


Rem		EasyMail发送函数，返回值参考：1成功，2失败，0不支持
Function SendEasyMail(Email,Topic,MailBody,TextBody,sendmail)

	on error resume next
	dim Mailsend
	set Mailsend = Server.CreateObject("easymail.Mailsend")
	if not isobject(Mailsend) Then
		SendEasyMail=0
		exit function
	end if
	Dim Tid,Un
	Un = "[e-mail]"  '您的邮件服务器登录名，不需要密码

	Dim EI
	Set EI = server.CreateObject("easymail.Users")
	Tid = EI.Login(un)
	Set EI = Nothing
	Mailsend.createnew Un,Tid '邮箱账号,临时ID
	Mailsend.CharSet = "gb2312"  '编码
	Mailsend.MailName = sendmail  '发件人名

	Mailsend.EM_BackAddress = "" '邮件回复地址
	Mailsend.EM_Bcc = "" '暗送地址
	Mailsend.EM_Cc = "" '抄送地址
	Mailsend.EM_OrMailName = "" '原邮件名
	Mailsend.EM_Priority = "Normal" '邮件重要度	
	Mailsend.EM_ReadBack = false '是否读取确认,挂号信(限本系统内用户)	
	Mailsend.EM_SignNo = -1  '使用签名的序号
	
	Mailsend.EM_Subject = Topic '主题
	Mailsend.EM_Text = TextBody '内容
	Mailsend.EM_HTML_Text = MailBody 'HTML邮件内容
	Mailsend.useRichEditer = true '发送的是否为HTML格式邮件

	Mailsend.EM_TimerSend = ""  '定时发送的时间
	Mailsend.EM_To = Email '收件人地址
	Mailsend.ForwardAttString = "" '转发邮件时的原附件

	Mailsend.AddFromAttFileString = "" '添加自网络存储中的文件名

	Mailsend.SystemMessage = false '是否是系统邮件

	Mailsend.SendBackup = false '是否保存发送邮件
	
	If Mailsend.Send() = false Then
		SendEasyMail = 2
	Else
		SendEasyMail = 1
	End If
	Set Mailsend = nothing

End Function


Rem	CDOMail发送函数，返回值参考：1成功，2失败，0不支持
Function SendCDOMail(Email,Topic,TextBody,sendmail)
	on error resume next
	dim  objCDOMail
	Set objCDOMail = Server.CreateObject("CDONTS.NewMail")
	if not isobject(objCDOMail) Then
		SendCDOMail=0
		exit function
	end if
	objCDOMail.From =sendmail '改为你的邮箱
	objCDOMail.To = Email
	objCDOMail.Subject = Topic

	objCDOMail.MailFormat=0		'说明是以MIME发送
	objCDOMail.BodyFormat=0		'可以包含html代码
	objCDOMail.Importance=0		'邮件的优先级别0-1-2
	objCDOMail.Body = TextBody

	objCDOMail.Send
	Set objCDOMail = Nothing
	SendCDOMail = 1
End Function
%>