⭐ 欢迎来到虫虫下载站！ | 📦 资源下载 📁 资源专辑 ℹ️ 关于我们
⭐ 虫虫下载站
📤 上传资源

📄 arrivefreight_confirm_operate.asp

📁 在线医药销售管理系统
💻 ASP
字号:
🔍 
<%@ Language=VBScript %>
<%'******************************************************
  '功能：到货确认操作页
  '入口参数：   
  '          1,发货单号
  '          2,人员编号
  '出口参数：
  '作者：钟宇    日期：2001年6月20日
  '******************************************************
%>
<HTML>
<HEAD>
<META NAME="GENERATOR" Content="Microsoft Visual Studio 6.0">
</HEAD>
<BODY>
<FORM action="ArriveFreight_Confirm.asp" name=form1 id=form1 method=post> 
<%
Dim DBConn,Rs,LStr_Sql,TStr_DlvID,TStr_StfID
Dim LStr_ArrayAll,LInt_i,LStr_Array,LStr_ArrayTemp
Dim LStr_SalQty,LStr_OutID,LStr_SalID,TStr_DlvArvDate
Dim TStr_ArrYear,TStr_ArrMonth,TStr_ArrDay
TStr_StfID=Session("Gs_StaffID")
TStr_DlvID=Trim(Request.Form("CheckBox1"))
TStr_FreightBillNo=Trim(Request.Form("FreightBillNo"))
TStr_ArrYear=Trim(Request.Form("Select1"))
TStr_ArrMonth=Trim(Request.Form("Select2"))
TStr_ArrDay=Trim(Request.Form("Select3"))
TStr_DlvArvDate=TStr_ArrYear & "-" & TStr_ArrMonth & "-" & TStr_ArrDay
If TStr_DlvID="" Or TStr_StfID="" Or TStr_DlvArvDate="" Then
  Response.Write "网页已经过期，添加操作被取消，请重新登录系统！"
  Response.End 
End If
LStr_Array=Split(TStr_DlvID,",")
Redim LStr_ArrayAll(UBound(LStr_Array),2) 
For LInt_i=0 To UBound(LStr_Array)
   LStr_ArrayTemp=Split(LStr_Array(LInt_i),"&")
   LStr_ArrayAll(LInt_i,0)=LStr_ArrayTemp(0)
   LStr_ArrayAll(LInt_i,1)=LStr_ArrayTemp(1)
   LStr_ArrayAll(LInt_i,2)=LStr_ArrayTemp(2)
Next

Set DBConn=Server.CreateObject("ADODB.Connection")
DBconn.ConnectionTimeout =application("Connection2_Connectiontimeout")
DBconn.cursorlocation=Application("Connection2_Cursorlocation")
DBconn.OPEN Application("Connection2_ConnectionString")
'DBConn.Open "Provider=SQLOLEDB.1;Persist Security Info=False;User ID=sa;Initial Catalog=CMS;Data Source=FileServer","sa","" 
Set Rs=Server.CreateObject("ADODB.Recordset")
For LInt_i=0 To UBound(LStr_Array)
  DBConn.BeginTrans
  '***修改选中的各笔发货单的到货数量和损坏数量，修改发货状态为"已到货"***
  LStr_Sql="UPDATE Warehouse_Deliver "
  LStr_Sql=LStr_Sql + "SET Whs_DlvArvQty=" & Trim(LStr_ArrayAll(LInt_i,1))
  LStr_Sql=LStr_Sql + ",Whs_DlvArvQtyDmg=" & Trim(LStr_ArrayAll(LInt_i,2))
  LStr_Sql=LStr_Sql + ",Whs_DlvFlag='已到货',Whs_DlvArvDate='"& TStr_DlvArvDate & "'"
  LStr_Sql=LStr_Sql + ",Whs_DlvArvHandler='"& TStr_StfID &"' "
  LStr_Sql=LStr_Sql + "WHERE Whs_DlvID='"& Trim(LStr_ArrayAll(LInt_i,0)) &"'"
  DBConn.Execute LStr_Sql
  '***判断发货单对应的出库单的出库类型是否为"销售出库"***
  LStr_Sql="SELECT Warehouse_Out.Whs_OutType,Warehouse_Deliver.Cst_ID,Warehouse_Deliver.Ctg_ID,Whs_DlvNum "
  LStr_Sql=LStr_Sql + "FROM Warehouse_Deliver,Warehouse_Out "
  LStr_Sql=LStr_Sql + "WHERE ( Warehouse_Out.Whs_OutID = Warehouse_Deliver.Whs_OutID ) AND "
  LStr_Sql=LStr_Sql + "( Warehouse_Deliver.Whs_DlvID = '"& Trim(LStr_ArrayAll(LInt_i,0)) &"')"
  Rs.Open LStr_Sql,DBConn
  If Not(Rs.EOF And Rs.BOF) Then
   '  If Trim(Rs("Whs_OutType"))="销售出库" Then
       '***是销售出库就修改客户品种的库存量***
       LStr_Sql="UPDATE FlowUse_StockCst "
       LStr_Sql=LStr_Sql + "SET FU_StkQty=FU_StkQty+" & Trim(LStr_ArrayAll(LInt_i,1))
       LStr_Sql=LStr_Sql + ",FU_StkQtyIn=FU_StkQtyIn+" & Trim(LStr_ArrayAll(LInt_i,1))
       LStr_Sql=LStr_Sql + " WHERE Cst_ID='" & Trim(Rs("Cst_ID")) &"' AND Ctg_ID='" & Trim(Rs("Ctg_ID")) &"'"
       DBConn.Execute LStr_Sql
       '***查看并记录发货单对应的定单的定单数量***
       LStr_Sql="SELECT Sale_Sale.Sal_SalQty,Warehouse_Out.Whs_OutID,"
       LStr_Sql=LStr_Sql+"Sale_Sale.Sal_SalID "
       LStr_Sql=LStr_Sql+"FROM Warehouse_Deliver,Warehouse_Out,"
       LStr_Sql=LStr_Sql+"Warehouse_OutNotice,Sale_Sale "
       LStr_Sql=LStr_Sql+"WHERE ( Warehouse_Deliver.Whs_OutID = Warehouse_Out.Whs_OutID ) AND "
       LStr_Sql=LStr_Sql+"(Warehouse_Out.Whs_OutNID = Warehouse_OutNotice.Whs_OutNID ) AND "
       LStr_Sql=LStr_Sql+"(Warehouse_OutNotice.Sal_SalID = Sale_Sale.Sal_SalID ) AND "
       LStr_Sql=LStr_Sql+"(Warehouse_Deliver.Whs_DlvID = '"& Trim(LStr_ArrayAll(LInt_i,0)) &"')"
       Rs.Close 
       Rs.Open LStr_Sql,DBConn
       '***记录定单数量，出库单号和定单号***
       If Not(Rs.EOF And Rs.BOF) Then
         LStr_SalQty=Trim(Rs("Sal_SalQty"))
         LStr_OutID=Trim(Rs("Whs_OutID"))
         LStr_SalID=Trim(Rs("Sal_SalID"))
       Else
         LStr_SalQty="0"
         LStr_OutID=""
         LStr_SalID=""
       End If
       '***统计货运单对应的同一出库单的所有发货单的到货数量和损坏数量之和***
       LStr_Sql="SELECT (Sum(Whs_DlvArvQty)+Sum(Whs_DlvArvQtyDmg)) As Result "
       LStr_Sql=LStr_Sql+"FROM Warehouse_Deliver "
       LStr_Sql=LStr_Sql+"WHERE Warehouse_Deliver.Whs_OutID = '"& LStr_OutID &"'"
       Rs.Close 
       Rs.Open LStr_Sql,DBConn
       '***比较发货单的到货统计和定单的定货数量***
       If CSng(LStr_SalQty)=CSng(Trim(Rs("Result"))) Then
         '***相同就修改定单的状态为"已到货"***
         LStr_Sql="UPDATE Sale_Sale "
         LStr_Sql=LStr_Sql+"SET Sal_SalFlgDeal='已到货' "
         LStr_Sql=LStr_Sql+"WHERE Sal_SalID='"& LStr_SalID &"'"
         DBConn.Execute LStr_Sql
       End If
       Rs.Close 
    ' End If 
  End If
  
  If DBConn.Errors.Count =0 Then
     DBConn.CommitTrans 
     LInt_Suc=LInt_Suc+1 
  Else 
     DBConn.RollbackTrans 
     If LStr_NoSuc<>"" Then
        LStr_NoSuc=LStr_NoSuc+","+Trim(LStr_ArrayAll(LInt_i,0))
     Else
        LStr_NoSuc=Trim(LStr_ArrayAll(LInt_i,0))
     End If     
     LInt_NoSuc=LInt_NoSuc+1
  End If
Next
DBConn.Close 
Set Rs=Nothing
Set DBConn=Nothing
If LInt_NoSuc=0 Then
   If LInt_Suc>0 Then
%>
<SCRIPT LANGUAGE=vbscript>
   MsgBox "已成功完成操作！",,"CMS系统提示" 
</SCRIPT>
<%
   Else
%>
<SCRIPT LANGUAGE=vbscript>
   MsgBox "数据操作可能有误，请查询确认！",,"CMS系统提示" 
</SCRIPT>
<%   
   End If 
Else
%>
<SCRIPT LANGUAGE=vbscript>
   MsgBox "对不起！你所选择的发货单号：<%=LStr_NoSuc%>确认是有误！",,"CMS系统提示" 
</SCRIPT>
<%
End If 
%>
<INPUT type=hidden id=select1 name=select1 value=<%=TStr_FreightBillNo%>>
</FORM>
<SCRIPT LANGUAGE=javascript>
<!--
/*提交操作，返回上一页*/
 form1.submit()
//-->
</SCRIPT>
</BODY>
</HTML>

⌨️ 快捷键说明

复制代码 Ctrl + C
搜索代码 Ctrl + F
全屏模式 F11
切换主题 Ctrl + Shift + D
显示快捷键 ?
增大字号 Ctrl + =
减小字号 Ctrl + -