inv_checkin_d.pas

一个MRPII系统源代码版本

unit Inv_CheckIn_D;

Interface

uses
  Windows, Messages, SysUtils, Classes, Graphics, Controls, Forms, Dialogs,
  Base_Entry_Detail, Db, AdODB, ExtCtrls, StdCtrls, ExtEdit;

Type
  TFrm_Inv_CheckIn_D = Class(TFrm_Base_Entry_Detail)
    Label2: TLabel;
    Label3: TLabel;
    Label4: TLabel;
    Label5: TLabel;
    Label8: TLabel;
    Lbl_ItemName: TLabel;
    Edt_BatchNo: TEdit;
    Edt_PoLineNo: TEdit;
    Label1: TLabel;
    Lbl_PoNo: TLabel;
    Lbl_UomName: TLabel;
    Lbl_ItemCode: TLabel;
    Label6: TLabel;
    Edt_RemArk: TEdit;
    Label7: TLabel;
    Edt_BillQty: TEdit;
    procedure Edt_BillQtyExit(Sender: TObject);
    procedure FormCreate(Sender: TObject);
    procedure Edt_PoLineNoExit(Sender: TObject);
    procedure Edt_PoLineNoKeyDown(Sender: TObject; var Key: Word;
      Shift: TShiftState);
    procedure Edt_BatchNoExit(Sender: TObject);
    procedure Edt_BatchNoKeyDown(Sender: TObject; var Key: Word;
      Shift: TShiftState);
    procedure btn_okClick(Sender: TObject);
  private
    { Private declarations }
    LineCount:Integer;
    flag:integer;
    FBillTypeCode:String;//根据采购订单的类型确定对应的单据类型是什么
    FWhPositionCode:String;//该变量记录的是某仓库“待检”属性的货位的代码
    Ffdays:Integer;//比订单要求的“约定交货期”提前多少天到货可以接受
    Fbdays:Integer;//比订单要求的“约定交货期”滞后多少天到货可以接受
    Foqty:Double;//比订单要求的“约定交货量”超过百分之多少可以接受
  public
    { Public declarations }
    procedure InitControls; Override;
    procedure SaveBodyData; Override;
    procedure SetStatus(CurrentStatus:String;var EnableControls:String); Override;
    procedure SetFormParam(FrmParam1,FrmParam2,FrmParam3,FrmParam4,FrmParam5,
      FrmParam6:String);Override;
  end;

var
  Frm_Inv_CheckIn_D: TFrm_Inv_CheckIn_D;

implementation

uses Sys_Global,Inv_CheckInPoHint,Inv_Global;

{$R *.DFM}

{ TFrm_Inv_SaleMaterial_D }

procedure TFrm_Inv_CheckIn_D.InitControls;
begin            
  if Param1='Over' then
    Caption:='待检超订单入库制单'
  else
    Caption:='待检入库单制单';
  SetFocus_Control:=Edt_PoLineNo;
  inherited;
  Lbl_PoNo.Caption:=AdoQry_Head.fieldbyname('PoNo').AsString;
  with AdoQry_Body do
  begin
    Edt_PoLineNo.Text:=fieldbyname('POLineNo').AsString;
    Lbl_ItemCode.Caption:=fieldbyname('ItemCode').AsString;
    Lbl_ItemName.Caption:=fieldbyname('ItemName').AsString;
    Lbl_UomName.Caption:=fieldbyname('UomName').AsString;
    Edt_RemArk.Text:=fieldbyname('BillLineRemArk').AsString;
    if (Status='Add')and(AdoQry_Body.IsEmpty) then
    begin
      Edt_BillQty.Text:='0';
      Edt_BatchNo.Text:='';
    end
    else
    begin
      Edt_BillQty.Text:=fieldbyname('OnCheckQty').AsString;
      Edt_BatchNo.Text:=fieldbyname('BatchNo').AsString;
    end;
  end;
  flag:=0;
end;

procedure TFrm_Inv_CheckIn_D.SaveBodyData;
begin//把Form的控件值写入缓存,要Post
  inherited;
  with AdoQry_Body do
  begin
    fieldbyname('POLineNo').AsString:=Edt_PoLineNo.Text;
    fieldbyname('ItemCode').AsString:=Lbl_ItemCode.Caption;
    fieldbyname('ItemName').AsString:=Lbl_ItemName.Caption;
    fieldbyname('UomName').AsString:=Lbl_UomName.Caption;
    fieldbyname('OnCheckQty').AsString:=Edt_BillQty.Text;
    fieldbyname('BatchNo').AsString:=Edt_BatchNo.Text;
    fieldbyname('BillLineRemArk').AsString:=Edt_RemArk.Text;
    Post;
  end;
end;

procedure TFrm_Inv_CheckIn_D.SetStatus(CurrentStatus: String;
  var EnableControls: String);
begin
  inherited;
  if CurrentStatus='Add' then
  begin
    if LineCount=-1 then
    begin
      AdoQry_Tmp.Close;
      AdoQry_Tmp.SQL.Text:='Select BillLines'
        +' From BillType'
        +' Where BillTypeCode='''+'1102'+'''';
      AdoQry_Tmp.Open;
      LineCount:=AdoQry_Tmp.fieldbyname('BillLines').AsInteger;
    end;
    if AdoQry_Body.RecordCount>=LineCount then
    begin
      EnableControls:='None';
      DispInfo('本单据最多只允许输入'+IntToStr(LineCount)+'条单据行！',3);
    end;
  end;
end;

procedure TFrm_Inv_CheckIn_D.Edt_BillQtyExit(Sender: TObject);
var
  FloatTemp1,FloatTemp2:Double;
begin
  inherited;
  if(ActiveControl.Name='btn_Cancel')then
    Abort;
  FloatCheck(Sender);
  if StrToFloat(TEdit(Sender).Text)<=0 then
  begin
    DispInfo(' 入库数量不能小于等于零！',3);
    TWinControl(Sender).SetFocus;
    Abort;
  end;
  AdoQry_Tmp.Close;
  AdoQry_Tmp.SQL.Text:='Select PoQty,PoRealInQty+PoInQty As SumQty'
    +' From PoLine'
    +' Where PoNo='''+Lbl_PoNo.Caption+''''
    +' And PoLineNo='''+Edt_PoLineNo.Text+'''';
  AdoQry_Tmp.Open;
  if Param1<>'Over' then
  begin
    FloatTemp1:=Round(AdoQry_Tmp.fieldbyname('PoQty').AsFloat*(1+Foqty/100));
    FloatTemp2:=Round(AdoQry_Tmp.fieldbyname('SumQty').AsFloat+StrToFloat(TEdit(Sender).Text));
    if FloatTemp1<FloatTemp2 then
    begin
      TWinControl(Sender).SetFocus;
      DispInfo(' 累计交货数量超过规定的限额，拒绝收货！ ',3);
      Abort;
    end;
  end;
end;

procedure TFrm_Inv_CheckIn_D.FormCreate(Sender: TObject);
begin
  inherited;
  LineCount:=-1;
  flag:=0;
end;

procedure TFrm_Inv_CheckIn_D.Edt_PoLineNoExit(Sender: TObject);
var
  BookMArk:TBookMArk;
  FloatTemp1,FloatTemp2:Double;
begin
  inherited;
  if(ActiveControl.Name='btn_Cancel')then
    Abort;
  IntegerCheck(Sender);
  AdoQry_Tmp.Close;
  AdoQry_Tmp.SQL.Text:='Select poline.PoNo,poline.PoLineDate,poline.ItemCode,poline.PoLineStatus,Item.iScheck'
                      +',PoLine.PoQty-PoLine.PoRealInQty-PoLine.PoInQty as qty'
                      +' From PoLine,Item'
                      +' Where poline.ItemCode=Item.ItemCode'
                      +' and poline.PoNo='''+Lbl_PoNo.Caption+''''
                      +' And poline.PoLineNo='+Trim(Edt_PoLineNo.Text)+'';
                      // +' and Item.iScheck=1';
  AdoQry_Tmp.Open;
  Lbl_ItemCode.Caption:=AdoQry_Tmp.fieldbyname('ItemCode').AsString;
  if (AdoQry_Tmp.fieldbyname('PoNo').AsString='')or
    (AdoQry_Tmp.fieldbyname('PoLineStatus').AsString<>'6')then
  begin
    DispInfo('该订单行不存在或不处于下达状态',3);
    TWinControl(Sender).SetFocus;
    Abort;
  end;
  if AdoQry_Tmp.fieldbyname('iScheck').asinteger=0 then
  begin
    DispInfo('物料代码必须是非免检,请重新输入！',3);
    TWinControl(Sender).SetFocus;
    abort;
  end;
  if Param1<>'Over' then
  begin
    if AdoQry_Tmp.fieldbyname('qty').Asfloat=0 then
    begin
      TWinControl(Sender).SetFocus;
      DispInfo('可待检入库量为零，请用使用超订单功能 ！ ',3);
      Abort;
    end;
    if(AdoQry_Head.fieldbyname('OnCheckDate').AsDateTime+Ffdays<
      AdoQry_Tmp.fieldbyname('PoLineDate').AsDateTime)then
    begin
      TWinControl(Sender).SetFocus;
      DispInfo(' 交货日期早于规定的时间，拒绝收货！ ',3);
      Abort;
    end;
    if(AdoQry_Head.fieldbyname('OnCheckDate').AsDateTime-Fbdays>
      AdoQry_Tmp.fieldbyname('PoLineDate').AsDateTime)then
    begin
      TWinControl(Sender).SetFocus;
      DispInfo(' 交货日期晚于规定的时间，拒绝收货！ ',3);
      Abort;
    end;
  end
  else
  begin
    if(AdoQry_Head.fieldbyname('OnCheckDate').AsDateTime+Ffdays>=
      AdoQry_Tmp.fieldbyname('PoLineDate').AsDateTime)
      and(AdoQry_Head.fieldbyname('OnCheckDate').AsDateTime-Fbdays<=
      AdoQry_Tmp.fieldbyname('PoLineDate').AsDateTime)then
    begin
      AdoQry_Tmp.Close;
      AdoQry_Tmp.SQL.Text:='Select PoQty,PoRealInQty+PoInQty As SumQty'
        +' From PoLine'
        +' Where PoNo='''+Lbl_PoNo.Caption+''''
        +' And PoLineNo='''+Trim(Edt_PoLineNo.Text)+'''';
      AdoQry_Tmp.Open;
      if Param1='Over' then
      begin
        FloatTemp1:=Round(AdoQry_Tmp.fieldbyname('PoQty').AsFloat*(1+Foqty/100));
        FloatTemp2:=Round(AdoQry_Tmp.fieldbyname('SumQty').AsFloat);
        if FloatTemp1>FloatTemp2 then
        begin
          DispInfo('该订单行交货期,交货数量正常,不应使用超订单功能!',3);
          Abort;
        end;
      end;
    end;
  end;
  if (AdoQry_Body.fieldbyname('POLineNo').AsString<>TEdit(Sender).Text)or(Status='Add') then
  begin
    BookMArk:=AdoQry_Body.GetBookmArk;
    AdoQry_Body.First;
    while not AdoQry_Body.Eof do
    begin
      if AdoQry_Body.fieldbyname('POLineNo').AsString=TEdit(Sender).Text then
      begin
        AdoQry_Body.GotoBookmArk(BookmArk);
        AdoQry_Body.FreeBookmArk(BookmArk);
        TWinControl(Sender).SetFocus;
        DispInfo(' 同一张单据中不能有相同的采购订单行号！ ',3);
        Abort;
      end;
      AdoQry_Body.Next;
    end;
    AdoQry_Body.GotoBookmArk(BookmArk);
    AdoQry_Body.FreeBookmArk(BookmArk);
  end;
  if not DefaultWHCheck(AdoQry_Tmp,AdoQry_Head.fieldbyname('WHCode').AsString,
    Lbl_ItemCode.Caption) then
  begin
    TWinControl(Sender).SetFocus;
    Abort;
  end;
  AdoQry_Tmp.Close;
  AdoQry_Tmp.SQL.Text:='Select ItemName,UomName'
    +' From Item Join Uom On Item.UomCode=Uom.UomCode'
    +' Where Item.ItemCode='''+Lbl_ItemCode.Caption+'''';
  AdoQry_Tmp.Open;
  Lbl_ItemName.Caption:=AdoQry_Tmp.fieldbyname('ItemName').AsString;
  Lbl_UomName.Caption:=AdoQry_Tmp.fieldbyname('UomName').AsString;
  if flag=0 then
  begin
    with AdoQry_tmp do
    begin
      Close;
      sql.clear;
      sql.text:='Select poline.PoNo,poline.POQty-poline.POInQty  as qty,Item.iScheck'
               +' From PoLine,Item'
               +' Where poline.ItemCode=Item.ItemCode'
               +' and poline.PoNo='''+Lbl_PoNo.Caption+''''
               +' And poline.PoLineNo='+Trim(Edt_PoLineNo.Text)+''
               +' and Item.iScheck=1';
      open;
      Edt_BillQty.text:=fieldbyname('qty').asstring;
    end;
  end;
  if not BatchCtrl(AdoQry_Tmp,Lbl_ItemCode.Caption) then
  begin
    Edt_BatchNo.Text:='';
    Edt_BatchNo.ReadOnly:=True;
  end
  else
  begin
    Edt_BatchNo.ReadOnly:=False;
  end;
end;

procedure TFrm_Inv_CheckIn_D.Edt_PoLineNoKeyDown(Sender: TObject;
  var Key: Word; Shift: TShiftState);
begin
  inherited;
  if(Key=120)then
  begin
    with TFrm_Inv_CheckInPoHint.Create(Self) do
    begin
      InitForm(DBConnect,Lbl_PoNo.Caption,TEdit(Sender).Text,
        AdoQry_Head.fieldbyname('OnCheckDate').AsDateTime-Fbdays,
        AdoQry_Head.fieldbyname('OnCheckDate').AsDateTime+Ffdays,1+Foqty/100);
      if ShowModal=mrOk then
        TEdit(Sender).Text:=POLineNo;
      Release;
    end;
    TWinControl(Sender).SetFocus;
  end;
end;

procedure TFrm_Inv_CheckIn_D.SetFormParam(FrmParam1, FrmParam2, FrmParam3,
  FrmParam4, FrmParam5, FrmParam6: String);
begin
  inherited;
  FBillTypeCode:=FrmParam1;
  FWhPositionCode:=FrmParam2;
  Ffdays:=StrToInt(FrmParam3);
  Fbdays:=StrToInt(FrmParam4);
  Foqty:=StrToFloat(FrmParam5);
end;

procedure TFrm_Inv_CheckIn_D.Edt_BatchNoExit(Sender: TObject);
begin
  inherited;
  if(ActiveControl.Name='btn_Cancel')then
    Abort;
  if (TEdit(Sender).ReadOnly=False)and(TEdit(Sender).Text<>'') then
  begin
    if not BatchNoCheck(AdoQry_Tmp,TEdit(Sender).Text,Lbl_ItemCode.Caption
      ,AdoQry_Head.fieldbyname('VendorCode').AsString
      ,AdoQry_Head.fieldbyname('OnCheckDate').AsString) then
    begin
      TWinControl(Sender).SetFocus;
      Abort;
    end;
  end;
end;

procedure TFrm_Inv_CheckIn_D.Edt_BatchNoKeyDown(Sender: TObject;
  var Key: Word; Shift: TShiftState);
begin
  inherited;
  if (Key=120)and(TEdit(Sender).ReadOnly=False) then
    TEdit(Sender).Text:=BatchHint(DBConnect,Lbl_ItemCode.Caption
      ,AdoQry_Head.fieldbyname('VendorCode').AsString
      ,AdoQry_Head.fieldbyname('WHCode').AsString
      ,FWhPositionCode);
end;

procedure TFrm_Inv_CheckIn_D.btn_okClick(Sender: TObject);
begin
  flag:=1;
  inherited;
  flag:=0;

end;

end.