chkinput.asp

方舟网免费空间申请程序(自助建站系统) v3.0 1 界面美观 2 后台管理功能强大：A 可以设置多种参数

<%
function IsValidEmail(email)
dim names, name, i, c
IsValidEmail = true
names = Split(email, "@")
if UBound(names) <> 1 then
   IsValidEmail = false
   exit function
end if
for each name in names
   if Len(name) <= 0 then
     IsValidEmail = false
     exit function
   end if
   for i = 1 to Len(name)
     c = Lcase(Mid(name, i, 1))
     if InStr("abcdefghijklmnopqrstuvwxyz_-.", c) <= 0 and not IsNumeric(c) then
       IsValidEmail = false
       exit function
     end if
   next
   if Left(name, 1) = "." or Right(name, 1) = "." then
      IsValidEmail = false
      exit function
   end if
next
if InStr(names(1), ".") <= 0 then
   IsValidEmail = false
   exit function
end if
i = Len(names(1)) - InStrRev(names(1), ".")
if i <> 2 and i <> 3 then
   IsValidEmail = false
   exit function
end if
if InStr(email, "..") > 0 then
   IsValidEmail = false
end if

end function

function strLength(str)
       ON ERROR RESUME NEXT
       dim WINNT_CHINESE
       WINNT_CHINESE    = (len("论坛")=2)
       if WINNT_CHINESE then
          dim l,t,c
          dim i
          l=len(str)
          t=l
          for i=1 to l
             c=asc(mid(str,i,1))
             if c<0 then c=c+65536
             if c>255 then
                t=t+1
             end if
          next
          strLength=t
       else 
          strLength=len(str)
       end if
       if err.number<>0 then err.clear
end function

Function CheckChar(testchar,testpathyes) 
CheckChar=true 
	dim char,pathyes
	char=testchar
	pathyes=testpathyes
	if len(pathyes)=1 then char=replace(char,pathyes,"")
	if Instr(char,"=")>0 _
	  	or Instr(char,"\")>0 _
	  	or Instr(char,"/")>0 _
	  	or Instr(char,"%")>0 _
	  	or Instr(char,chr(32))>0 _
	  	or Instr(char,"?")>0 _
	  	or Instr(char,"&")>0 _
	  	or Instr(char,"$")>0 _
	  	or Instr(char,";")>0 _
	  	or Instr(char,",")>0 _
	  	or Instr(char,"'")>0 _
	  	or Instr(char,chr(34))>0 _
	  	or Instr(char,chr(9))>0 _
	  	or Instr(char,"*")>0 _
	  	or Instr(char,">")>0 _
	  	or Instr(char,"<")>0 _
	  	or Instr(char,"|")>0  _
	  	or Instr(char,":")>0 _
	  	or Instr(char,"#")>0 then CheckChar=false
End function %>