ccmdskiplines.cls

Data monkey是一个强大的是数据传输和转换应用程序。使用DataMonkey用户可以把复杂的文本文件格式

VERSION 1.0 CLASS
BEGIN
  MultiUse = -1  'True
  Persistable = 0  'NotPersistable
  DataBindingBehavior = 0  'vbNone
  DataSourceBehavior  = 0  'vbNone
  MTSTransactionMode  = 0  'NotAnMTSObject
END
Attribute VB_Name = "CCmdSkipLines"
Attribute VB_GlobalNameSpace = False
Attribute VB_Creatable = True
Attribute VB_PredeclaredId = False
Attribute VB_Exposed = False
Attribute VB_Ext_KEY = "SavedWithClassBuilder" ,"Yes"
Attribute VB_Ext_KEY = "Top_Level" ,"Yes"
Attribute VB_Ext_KEY = "SavedWithClassBuilder6" ,"Yes"
' DataMonkey Data Conversion Application. Written by Theodore L. Ward
' Copyright (C) 2002 AstroComma Incorporated.
'
' This program is free software; you can redistribute it and/or
' modify it under the terms of the GNU General Public License
' as published by the Free Software Foundation; either version 2
' of the License, or (at your option) any later version.
'
' This program is distributed in the hope that it will be useful,
' but WITHOUT ANY WARRANTY; without even the implied warranty of
' MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
' GNU General Public License for more details.
'
' You should have received a copy of the GNU General Public License
' along with this program; if not, write to the Free Software
' Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA  02111-1307, USA.
' The author may be contacted at:
' [e-mail] or [e-mail]

Option Explicit
Private mIndex As Integer 'local copy
Private mLinesToSkip As Long
Private mUniqueID As String

Public Function Copy() As CCmdSkipLines
    On Error GoTo eHandler
    Set Copy = Nothing

    Dim cmd As New CCmdSkipLines
    
    cmd.NumLinesToSkip = Me.NumLinesToSkip
    Set Copy = cmd
    Set cmd = Nothing
    Exit Function

eHandler:
    LogError "CCmdSkipLines", "Copy", Error(Err), False

End Function

Public Function GetID() As String
    GetID = mUniqueID
End Function

Public Function EditProperties(NameForCaption As String, Optional ByRef Import As CImport = Nothing) As Integer
    
    frmCMDSkipLinesProperties.Initialize Me, NameForCaption
    frmCMDSkipLinesProperties.Show vbModal
    EditProperties = GFormReturnValue
End Function

Public Function GetSpecificDescription() As String
    Dim x As String
    
    x = "Skip the next " & CStr(mLinesToSkip) & " line" & _
            IIf(mLinesToSkip = 1, "", "s") & " of input"

    GetSpecificDescription = x
End Function
Public Property Let index(ByVal vData As Integer)
    mIndex = vData
End Property

Public Property Get index() As Integer
    index = mIndex
End Property

Public Function CmdType() As Integer
    CmdType = eCmdTypes.cmdSkipLines
End Function

Public Function GetApplications() As eCmdApplications
    GetApplications = GCmdHelper.CMDGetApplications(CmdType())
End Function

Public Property Let NumLinesToSkip(vData As Long)
    mLinesToSkip = vData
End Property
Public Property Get NumLinesToSkip() As Long
    NumLinesToSkip = mLinesToSkip
End Property

Public Function Execute(Optional ByRef value As Variant, Optional CnvType As Integer = -1) As Boolean
    Execute = False
    GImport.SkipLines = mLinesToSkip
    Execute = True
End Function

Public Function Load(arc As CArchive) As Boolean

    On Error GoTo eHandler
    
    Load = False
    Dim item As String, value As Variant, retVal As Integer
    
    '***************************************
    ' Get the next line from the input file.
    '***************************************
    
    Do
        retVal = arc.GetNextItem(item, value)

        ' Error, log it, then exit with error.
        If retVal = ArcRetType.cERROR Then
            arc.AddError
            GoTo done
            
        ' We are done with this object, leave.
        ElseIf retVal = ArcRetType.cENDITEM Then
            Exit Do
        End If
        
        Select Case item
            Case "INDEX"
                mIndex = value
            Case "SKIPLINES"
                mLinesToSkip = value
            Case Else
                ' This line contains an unrecognized item.
                arc.AddError
        End Select
    Loop While True
    
    Load = True
    
done:
    Exit Function
    
eHandler:
    LogError "CCmdSkipLines", "Load", Error(Err)
    Exit Function

End Function

Public Function Save(arc As CArchive) As Boolean
    
    On Error GoTo eHandler
    
    Save = False

    arc.SaveItem aiBEGINACTION, GCmdHelper.GetName(CmdType())
    arc.SaveItem aiVALUE, "INDEX", mIndex
    arc.SaveItem aiVALUE, "SKIPLINES", mLinesToSkip
    
    arc.SaveItem aiENDITEM, GCmdHelper.GetName(CmdType())

    Save = True
    Exit Function
    
eHandler:
    LogError "CCmdSkipLines", "Save", Error(Err)
    Exit Function
    
End Function

Private Sub Class_Initialize()
    mLinesToSkip = 0
    mUniqueID = GetUniqueID
End Sub