coutputlink.cls

Data monkey是一个强大的是数据传输和转换应用程序。使用DataMonkey用户可以把复杂的文本文件格式

VERSION 1.0 CLASS
BEGIN
  MultiUse = -1  'True
  Persistable = 0  'NotPersistable
  DataBindingBehavior = 0  'vbNone
  DataSourceBehavior  = 0  'vbNone
  MTSTransactionMode  = 0  'NotAnMTSObject
END
Attribute VB_Name = "COutputLink"
Attribute VB_GlobalNameSpace = False
Attribute VB_Creatable = True
Attribute VB_PredeclaredId = False
Attribute VB_Exposed = False
Attribute VB_Ext_KEY = "SavedWithClassBuilder" ,"Yes"
Attribute VB_Ext_KEY = "Top_Level" ,"No"
Attribute VB_Ext_KEY = "SavedWithClassBuilder6" ,"Yes"
' DataMonkey Data Conversion Application. Written by Theodore L. Ward
' Copyright (C) 2002 AstroComma Incorporated.
'
' This program is free software; you can redistribute it and/or
' modify it under the terms of the GNU General Public License
' as published by the Free Software Foundation; either version 2
' of the License, or (at your option) any later version.
'
' This program is distributed in the hope that it will be useful,
' but WITHOUT ANY WARRANTY; without even the implied warranty of
' MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
' GNU General Public License for more details.
'
' You should have received a copy of the GNU General Public License
' along with this program; if not, write to the Free Software
' Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA  02111-1307, USA.
' The author may be contacted at:
' [e-mail] or [e-mail]

Option Explicit

Private mLinkFromTable As String
Private mLinkFromField As String
Private mLinkToTable As String
Private mLinkToField As String
Private mUniqueID As String
Private mIndex As Integer
Private mIgnoreMe As Boolean

Public Function Copy() As COutputLink
    On Error GoTo eHandler
    Set Copy = Nothing

    Dim newObj As COutputLink
    Set newObj = New COutputLink

    newObj.LinkFromTable = Me.LinkFromTable
    newObj.LinkFromField = Me.LinkFromField
    newObj.LinkToField = Me.LinkToField
    newObj.LinkToTable = Me.LinkToTable
    
    Set Copy = newObj
    Set newObj = Nothing
    Exit Function

eHandler:
    LogError "COutputLink", "Copy", Error(Err), False

End Function

Public Property Let index(NewIndex As Integer)
    mIndex = NewIndex
End Property

Public Property Get index() As Integer
    index = mIndex
End Property

Public Function GetID() As String
    GetID = mUniqueID
End Function

Public Function GetDescription() As String
    GetDescription = "Link '" & mLinkFromTable & _
                        ", " & mLinkFromField & _
                        "' To '" & mLinkToTable & _
                        ", " & mLinkToField & "'"
End Function

Public Property Let LinkToTable(ByVal vData As String)
    mLinkToTable = vData
End Property

Public Property Get LinkToTable() As String
    LinkToTable = mLinkToTable
End Property
Public Property Let LinkToField(ByVal vData As String)
    mLinkToField = vData
End Property

Public Property Get LinkToField() As String
    LinkToField = mLinkToField
End Property

Public Property Let LinkFromTable(ByVal vData As String)
    mLinkFromTable = vData
End Property

Public Property Get LinkFromTable() As String
    LinkFromTable = mLinkFromTable
End Property

Public Property Let LinkFromField(ByVal vData As String)
    mLinkFromField = vData
End Property

Public Property Get LinkFromField() As String
    LinkFromField = mLinkFromField
End Property

Public Property Get IgnoreMe() As Boolean
    IgnoreMe = mIgnoreMe
End Property

Public Property Let IgnoreMe(newVal As Boolean)
    mIgnoreMe = newVal
End Property

Public Function Load(ByRef arc As CArchive) As Boolean

    On Error GoTo eHandler
    
    Load = False
    Dim item As String, value As Variant, retVal As Integer
    
    ' Get the next line from the input file.
    Do
        retVal = arc.GetNextItem(item, value)
        
        ' Error, log it, then exit with error.
        If retVal = ArcRetType.cERROR Then
            arc.AddError
            GoTo done
            
        ' We are done with this object, leave.
        ElseIf retVal = ArcRetType.cENDITEM Then
            Exit Do
        End If
        
        Select Case item
            Case "LINKFROMTABLE"
                mLinkFromTable = value
            Case "LINKFROMFIELD"
                mLinkFromField = value
            Case "LINKTOTABLE"
                mLinkToTable = value
            Case "LINKTOFIELD"
                mLinkToField = value
            
            Case Else
                ' This line contains an unrecognized item.
                arc.AddError
                
        End Select
    Loop While True
    
    Load = True
done:
    Exit Function
    
eHandler:
    LogError "COutputLink", "Load", Error(Err)
End Function

Public Function Save(ByRef arc As CArchive) As Boolean

    On Error GoTo eHandler
    
    Save = False
        
    arc.SaveItem aiBEGINOUTPUTLINK
    arc.SaveItem aiVALUE, "LINKFROMTABLE", mLinkFromTable
    arc.SaveItem aiVALUE, "LINKFROMFIELD", mLinkFromField
    arc.SaveItem aiVALUE, "LINKTOTABLE", mLinkToTable
    arc.SaveItem aiVALUE, "LINKTOFIELD", mLinkToField
    arc.SaveItem aiENDITEM
    
    Save = True
    Exit Function
    
eHandler:
    LogError "COutputLink", "Save", Error(Err)
    Exit Function
    
End Function

Private Sub Class_Initialize()
    mUniqueID = GetUniqueID
    mIgnoreMe = False
End Sub