p364game.asl

<B>Award BIOS(Basic Input/Output System)(电脑启动时所必需)的源码</B>

Device(GAME) 	
{
        Name(_HID, EISAID("PNPB02F")) 	// PnP Device ID Game Type
        Method(_STA,0)
        {
                Store(0x0B,LDN_)
                If(ACTR) 
                {
                        Return(0x0F)
                }	
                Else	
                {
                        If(LOr(IOAH,IOAL)) 
                        {	
                                Return(0x0D)
                        }
                        else
                        {
                                Return(0)	      		
                        }
                }	
        }	// end _STA method

        Method(_DIS,0)
        {
                Store(0x0B, LDN_)
                Store(Zero, ACTR)
                DISD(0x04)		//R02
        }	// end _DIS method

        Method(_CRS,0)			// Current Resource
        {				
                Name(BUF1,Buffer()
                {
                        0x47,		// IO Port Descriptor
                        0x01, 		// 16 bit decode
                        0x00, 		// IO Port Range Minimum Base Low
                        0x00, 		// IO Port Range Minimum Base High
                        0x00, 		// IO Port Range Maximum Base LOW
                        0x00, 		// IO Port Range Maximum Base High
                        0x01, 		// Base Alignment
                        0x0F, 		// R01 Length of contiguous IO Ports
                        0x47,		// IO Port Descriptor
                        0x01, 		// 16 bit decode
                        0x00, 		// IO Port Range Minimum Base Low
                        0x00, 		// IO Port Range Minimum Base High
                        0x00, 		// IO Port Range Maximum Base LOW
                        0x00, 		// IO Port Range Maximum Base High
                        0x00, 		// Base Alignment
                        0x01, 		// Length of contiguous IO Ports

                                0x79, 		// end tag
                        0x00, 		// Checksum = 0 Treat as if the
                })
        
                CreateByteField (BUF1, 0x02, IOLO) 	// IO Port Low
                CreateByteField (BUF1, 0x03, IOHI) 	// IO Port High
                CreateByteField (BUF1, 0x04, IORL) 	// IO Port Low
                CreateByteField (BUF1, 0x05, IORH) 	// IO Port High

                CreateByteField (BUF1, 0x0A, IO21) 	// IO Port Low
                CreateByteField (BUF1, 0x0B, IO22) 	// IO Port High
                CreateByteField (BUF1, 0x0C, IO31) 	// IO Port Low
                CreateByteField (BUF1, 0x0D, IO32) 	// IO Port High

                Store(0x0B,LDN_) 		// Logical device number for serial port 1
                Add(IOAL, 0x1, IOLO)		//R01
                Add(IOAL, 0x1, IORL)		//R01
                Store(IOAH,IOHI)
                Store(IOAH,IORH)
                Store(IOAL,IO21)
                Store(IOAL,IO31)
                Store(IOAH,IO22)
                Store(IOAH,IO32)

                Return(BUF1)			// Return Buf1
        } 					// end _CRS method

        Name(_PRS,Buffer()
        {
                0x30, 			// Start Dependent Function

                0x47, 			// IO Port Descriptor
                0x01, 			// 16 bit decode
                0x01, 			// R01 IO Port Range Minimum Base Low
                0x02, 			// IO Port Range Minimum Base High
                0x01, 			// R01 IO Port Range Minimum Base Low
                0x02, 			// IO Port Range Maximum Base High
                0x01, 			// Base Alignment
                0x0F, 			// R01 Length of contiguous IO Ports

                0x47, 			// IO Port Descriptor
                0x01, 			// 16 bit decode
                0x00, 			// R01 IO Port Range Minimum Base Low
                0x02, 			// IO Port Range Minimum Base High
                0x00, 			// R01 IO Port Range Minimum Base Low
                0x02, 			// IO Port Range Maximum Base High
                0x00, 			// R01 Base Alignment
                0x01, 			// Length of contiguous IO Ports



                0x38, 			// End Dependent Function

                0x79, 			// end tag
                0x00, 			// Checksum = 0 Treat as if the
        })

        Method(_SRS,1)	
        {
                CreateByteField (Arg0, 0x02, IOLO)	// IO Port Low
                CreateByteField (Arg0, 0x03, IOHI)	// IO Port High
                CreateWordField (Arg0, 0x02, IOAD)	//R02

                Store(0x0B, LDN_)
                Store(One, ACTR)
                Store(IOLO, IOAL)
                Store(IOHI, IOAH)
                CKIO(IOAD,0x04)		//R02
        }	// End of _SRS Method
}	// end of GAME device