f2812_ezdsp_flash_lnk.cmd

许继的2812开发全套驱动程序，很全很实用的.rar

/*
//###########################################################################
//
// FILE:    F2812_EzDSP_RAM_lnk.cmd
//
// TITLE:   Linker Command File For F2812 eZdsp examples that run out of RAM
//          This linker file assumes the user is booting up in Jump to H0 mode
//
//###########################################################################
//
//  Ver | dd mmm yyyy | Who  | Description of changes
// =====|=============|======|===============================================
//  1.00| 11 Sep 2003 | L.H. | Changes since previous version (v.58 Alpha)
//      |             |      | Added BEGIN section to the start of H0
//      |             |      | Removed .bss, .const and .sysmem
//      |             |      |    These are for a small memory model.  All examples
//      |             |      |    use the large model.
//      |             |      | Added .esysmem section
//      |             |      | Changed ramfuncs section to load and run from RAM
//      |             |      |    (previously this was type DSECT)
//      |             |      | Moved peripheral register files to DSP28_Headers_BIOS.cmd
//      |             |      |    and DSP28_Headers_nonBIOS.cmd
//      |             |      | Added CSM_RSVD memory section in FLASHA - this region
//      |             |      |    should be programmed with all 0x0000 when using the CSM
// -----|-------------|------|-----------------------------------------------
//###########################################################################
*/

/* ======================================================
// For Code Composer Studio V2.2 and later
// ---------------------------------------
// In addition to this memory linker command file, 
// add the header linker command file directly to the project. 
// The header linker command file is required to link the
// peripheral structures to the proper locations within 
// the memory map.
//
// The header linker files are found in <base>\DSP281x_Headers\cmd
//   
// For BIOS applications add:      DSP281x_Headers_nonBIOS.cmd
// For nonBIOS applications add:   DSP281x_Headers_nonBIOS.cmd    
========================================================= */

/* ======================================================
// For Code Composer Studio prior to V2.2
// --------------------------------------
// 1) Use one of the following -l statements to include the 
// header linker command file in the project. The header linker
// file is required to link the peripheral structures to the proper 
// locations within the memory map                                    */

/* Uncomment this line to include file only for non-BIOS applications */
/* -l DSP281x_Headers_nonBIOS.cmd */

/* Uncomment this line to include file only for BIOS applications */
/* -l DSP281x_Headers_BIOS.cmd */

/* 2) In your project add the path to <base>\DSP281x_headers\cmd to the
   library search path under project->build options, linker tab, 
   library search path (-i).
/*========================================================= */



MEMORY
{
PAGE 0 :
   /* RESET is loaded with the reset vector only if           */
   /* the boot is from XINTF Zone 7.  Otherwise reset vector  */
   /* is fetched from boot ROM. See .reset section below      */
   
   BOOTROM 		: origin = 0x3FF000, length = 0x000FC0   /* boot ROM availabel if MP/MCn=0 */
   RESET   		: origin = 0x3FFFC0, length = 0x000002   /* part of boot ROM (MP/MCn=0) or XINTF zone 7 (MP/MCn=1) */        
   VECTORS 		: origin = 0x3FFFC2, length = 0x00003E   /* part of boot ROM (MP/MCn=0) or XINTF zone 7 (MP/MCn=1) */
   RAML0        : origin = 0x008000, length = 0x001000
      
   OTP          : origin = 0x3D7800, length = 0x000800     /* on-chip OTP */
   FLASH_IJ     : origin = 0x3D8000, length = 0x004000     /* on-chip FLASH */
   FLASH_GH     : origin = 0x3DC000, length = 0x008000     /* on-chip FLASH */
   FLASH_EF     : origin = 0x3E4000, length = 0x008000     /* on-chip FLASH */
   FLASH_CD     : origin = 0x3EC000, length = 0x008000     /* on-chip FLASH */
   FLASH_AB     : origin = 0x3F4000, length = 0x003F80     /* on-chip FLASH */
   CSM_RSVD     : origin = 0x3F7F80, length = 0x000076     /* Part of FLASHA.  Reserved when CSM is in use. */
   BEGIN_FLASH  : origin = 0x3F7FF6, length = 0x000002     /* Part of FLASHA.  Used for "boot to flash" bootloader mode. */
   PASSWORDS    : origin = 0x3F7FF8, length = 0x000008     /* Part of FLASHA.  CSM password locations. */
            
PAGE 1 :

   RAMM0        : origin = 0x000000, length = 0x000400
   RAMM1        : origin = 0x000400, length = 0x000400
   RAML1        : origin = 0x009000, length = 0x001000
   RAMH0        : origin = 0x3F8000, length = 0x002000      
   EXTRAM       : origin = 0x170000, length = 0x00C000
}
 
 
SECTIONS
{
   /* Setup for "boot to external ram" mode: 
      The codestart section (found in DSP28_CodeStartBranch.asm)
      re-directs execution to the start of user code. */
         
   .text            : load = FLASH_AB,    PAGE = 0
   .cinit           : load = FLASH_CD,    PAGE = 0
   .pinit           : load = FLASH_CD,    PAGE = 0
   .switch          : load = FLASH_CD,    PAGE = 0
   .const			: load = FLASH_CD,    PAGE = 0
   .econst			: load = FLASH_CD,    PAGE = 0
   .reset           : load = RESET,       PAGE = 0, TYPE = DSECT 
   vectors          : load = VECTORS,     PAGE = 0, TYPE = DSECT   
   
   IQmathTables     : load = BOOTROM,     PAGE = 0, TYPE = NOLOAD
   IQmath           : load = FLASH_CD,    PAGE = 0
   
   .stack           : load = RAMM1,       PAGE = 1   
   .cio             : load = RAMM0,       PAGE = 1
   .bss             : load = RAMH0,       PAGE = 1 /* Should be empty with large memory model */
   .ebss            : load = RAMH0,       PAGE = 1      
   .sysmem 			: load = RAMM0,		  PAGE = 1 /* Should be empty with large memory model */
   .esysmem         : load = RAMM0,       PAGE = 1

/* User Defined Sections */
   codestart        : load = BEGIN_FLASH, PAGE = 0
   csm_rsvd         : load = CSM_RSVD,    PAGE = 0 /* Used by file CSMPasswords.asm */
   csmpasswds       : load = PASSWORDS,   PAGE = 0 /* Used by file CSMPasswords.asm */
   ramfuncs    		: LOAD = FLASH_AB,    PAGE = 0 /* Used by InitFlash() in SysCtrl.c */ 
                      RUN  = RAML0, 	  PAGE = 0 
                      LOAD_START(_ramfuncs_loadstart),
                      LOAD_END(_ramfuncs_loadend),
                      RUN_START(_ramfuncs_runstart)  
}