render.dcl

Autocad-2005-简体中文-解密版.zip

// Dialog to edit the currently selected Spot light definition.

avis_spotlight : dialog {
    key = "dialog";
    dialog_kind = "spot";
    : row {
        ave_basic_lights;
        : column {
            alignment = top;
            fixed_height = true;
            ave_spot_lights;
            attenuation_panel;
            shadow_panel;
            spacer_0;
        }
    }
    spacer_1_ok_cancel_help_errtile;
}

//***************************************************************************
// Dialog to edit distant lights (sun).

avis_distant_light : dialog {
    key = "dialog";
    dialog_kind = "distant";
    : row {
        : column {
            distant_light_parameters_panel;
            shadow_panel;
            : button {
                key = "sa_calc";
                label = "Sun Angle Calculator...";
                mnemonic = "S";
                fixed_width = true;
                alignment = centered;
            }
        }
        : column {
            azimuth_altitude_panel;
            light_source_panel;
        }
    }
    spacer_1_ok_cancel_help_errtile;
}

sun_angle_calculator_panel : column {
    : boxed_column {
        : row {
        : column {
                : edit_box {
                    label = "Date:      ";
                    key = "date_edit";
                    mnemonic = "D";
                    edit_width = 6;
                    edit_limit = 6;
                }
                : edit_box {
                    label = "Clock Time:";
                    key = "time_edit";
                    mnemonic = "C";
                    edit_width = 6;
                    edit_limit = 6;
                }
                : popup_list { 
                    key = "timezone_popup";
                    list = "PST:8\nMST:7\nCST:6\nEST:5\nNewfoundland:4\nYukon:9";
                }
                : edit_box {
                    label = "Latitude:  ";
                    key = "latitude_edit";
                    mnemonic = "L";
                    edit_width = 6;
                    edit_limit = 6;
                }
                : edit_box {
                    label = "Longitude: ";
                    key = "longitude_edit";
                    mnemonic = "o";
                    edit_width = 6;
                    edit_limit = 6;
                }
        }
        : column {
                : slider {
                    key = "date_slider";
                    min_value = 1;
                    max_value = 365;
                    small_increment = 1;
                    big_increment = 31;
                    width = 10;
                }
                : slider {
                    key = "time_slider";
                    min_value = 0;
                    max_value = 1440;
                    small_increment = 10;
                    big_increment = 60;
                    width = 10;
                }
                : toggle {
                    label = "Daylight Savings";
                    key = "daylight_toggle";
                    mnemonic = "S";
                }
                : slider {
                    key = "latitude_slider";
                    min_value = 0;
                    max_value = 90;
                    small_increment = 1;
                    big_increment = 10;
                    width = 10;
                }
                : slider {
                    key = "longitude_slider";
                    min_value = 0;
                    max_value = 180;
                    small_increment = 1;
                    big_increment = 10;
                    width = 10;
                }
        }
        }
        : row {
            : popup_list { 
                key = "latitude_popup";
                list = "North\nSouth";
            }
            : popup_list { 
                key = "longitude_popup";
                list = "West\nEast";
            }
        }
        : button {
            alignment = centered;
            fixed_width = true;
            key = "location_button";
            label = "Geographic Location...";
            mnemonic = "G";
        }
    }
}
        

azimuth_altitude_panel_write_only : boxed_column {
    : row {
        : column {
            : row {
                : text {
                    label = "Azimuth:";
                }
                : text {
                    label = "      ";
                    key = "azimuth_t";
                    width = 6;
                }
            }
            : image_button {
                key = "azimuth_image";
                color = dialog_background;
                height = 7;
                aspect_ratio = 1;
                fixed_height = true;
                fixed_width = true;
                alignment = centered;
                is_enabled = false;
            }
        }
        : column {
            : row {
                : text {
                    label = "Altitude:";
                }
                : text {
                    label = "      ";
                    key = "altitude_t";
                    width = 6;
                }
            }
            : image_button {
                key = "altitude_image";
                color = dialog_background;
                height = 7;
                aspect_ratio = 1;
                fixed_height = true;
                fixed_width = true;
                alignment = centered;
                is_enabled = false;
            }
        }
    }
    : row {
        : text {
            label = "Solar Time:";
        }
        : text {
            label = "     ";
            key = "solar_time";
        }
    }
}

ave_sun_angle_calc : dialog {
    label = "Sun Angle Calculator";
    initial_focus = "accept";
    : row {
        sun_angle_calculator_panel;
        azimuth_altitude_panel_write_only;
    }
    spacer_1_ok_cancel_help_errtile;
}

shadow_panel : boxed_column {
    label = "Shadows:";
    : toggle {
        alignment = left;
        label = "Shadow On";
        key = "shadow_on";
        mnemonic = "w";
    }
    : button {
        key = "shadow_dialog";
        label = "Shadow Options...";
        mnemonic = "p";
        fixed_width = true;
    }
}


//***************************************************************************
// Tile used only by Spotlights.

ave_spot_lights : column {
    fixed_height = true;
    : edit_box_8 {
        label = "Hotspot:";
        key = "conea_t";
        mnemonic = "t";
    }
    : slider {
        key = "conea_s";
        min_value = 0;
        max_value = 160;
        small_increment = 1;
        big_increment = 10;
    }
    : edit_box_8 {
        label = "Falloff:";
        key = "coned_t";
        mnemonic = "F";
    }
    : slider {
        key = "coned_s";
        min_value = 0;
        max_value = 160;
        small_increment = 1;
        big_increment = 10;
    }
}

//***************************************************************************
// geographic location dialog

ave_geographic_location : dialog {
    key = "dialog";
    initial_focus = "accept";
    label = "Geographic Location";
    : column { 
        key = "top_key";
        : row {
            : column {
                fixed_width = true;
                : list_box {
                    key = "cities";
                    height = 8;
                    width = 21;
                    label = "City:";
                    mnemonic = "C";
                }
                : boxed_column {
                    : text {
                        label = " ";
                        key = "city";
                        width = 21;
                    }
                    : edit_box_8 {
                        label = "Latitude: ";
                        value = "0.";
                        edit_width = 8;
                        key = "latitude";
                        mnemonic = "a";
                    }
                    : edit_box_8 {
                        label = "Longitude: ";
                        value = "0.";
                        edit_width = 8;
                        key = "longitude";
                        mnemonic = "o";
                    }
                    spacer_0;
                }
            }
            : boxed_column {
                : row {
                    : popup_list { 
                        key = "map_name";
                        list = 
"North America\nCanada\nEurope\nSouth America\nAsia\nAustralia\nAsian Subcontinent\nAfrica";
                        files = 
"namer.map\ncanada.map\neurope.map\nsamer.map\nasia.map\naust.map\nindia.map\nafrica.map";
                        width = 18;
                    }
                    : toggle {
                        label = "Nearest Big City";
                        value = "1";
                        key = "nearest";
                        mnemonic = "N";
                    }
                }
                : image_button {
                    key = "map_image";
                    color = -15;             /* background color */
                    height = 15;
                    aspect_ratio = 1.5;
                }
            }
        }
//      spacer_1_ok_cancel_help_errtile;
        ok_cancel_help_errtile;
    }
}

northLocator : dialog {
    label = "North Location";
    spacer;
    spacer;
    : row {
        : boxed_column {
            label = "X/Y Plane:";
            fixed_width = true;
            : image_button {
                key = "northImage";
                color = dialog_background;             /* background color */
                width = 20;
                aspect_ratio = 1;
//              is_enabled = true;
                fixed_width = true;
            }
            : column {
                : edit_box {
                    label = "Angle:";
                    key = "northEdit";
                    mnemonic = "A";
                    edit_width = 6;
                    edit_limit = 6;
                }
                : slider {
                    key = "northSlider";
                    min_value = 0;
                    max_value = 360;
                    small_increment = 1;
                    big_increment = 10;
                    width = 20;
                }
            }
        }
        : list_box {
            width = 20;
            fixed_width = true;
            key = "useUCS";
            label = "Use UCS:";
            mnemonic = "U";
//          list = "Shadow Softness:";
        }
    }
    ok_cancel_help_errtile;
}

shadowMapOptions : dialog {
    label = "Shadow Options";
    spacer;
    spacer;
    : toggle {
        label = "Shadow Volumes/Ray Traced Shadows";
        key = "shadowVolumes";
        mnemonic = "S";
    }
    : popup_list { 
        key = "shadowMapSize";
        fixed_width = true;
        label = "Shadow Map Size";
        list = "64\n128\n256\n512\n1024\n2048\n4096";
    mnemonic = "M";
    }
    : row {
        : edit_box {
            label = "Shadow Softness:";
            edit_width = 6;
            edit_limit = 6;
            key = "beamd_t";
            mnemonic = "o";
        }
        : slider {
            key = "beamd_s";
            min_value = 1;
            max_value = 10;
            small_increment = 1;
            big_increment = 2;
            width = 20;
        }
    }
    : button {
        key = "pick";
        label = "Shadow Bounding Objects <";
        alignment = centered;
        fixed_width = true;
        width = 3;
        mnemonic = "B";
    }
    spacer;
    spacer;
    ok_cancel_help_errtile;
}

ave_make_map : dialog {
    key = "dialog";
    label = "Make Map";
    : row {
        : column {
            : edit_box_8 {
                label = "Longitude: ";
                value = "-99.";
                key = "longitude";
                mnemonic = "X";
            }
            : edit_box_8 {
                label = "Latitude: ";
                value = "38.";
                key = "latitude";
                mnemonic = "Y";
            }
            : edit_box_8 {
                label = "Width (deg): ";
                value = "70.";
                key = "width";
                mnemonic = "S";
            }
            : edit_box_8 {
                label = "Rank: ";
                value = "1";
                key = "rank";
                mnemonic = "R";
            }
            : edit_box_8 {
                label = "File: ";
                value = "bdy.cbd";
                key = "file";
                mnemonic = "F";
            }
            : edit_box {
                label = "Path: ";
                value = "/files1/map/namer.map/";
//              value = "e:\\map\\namer.map\\";
                edit_width = 16;
                edit_limit = 30;
                key = "path";
                mnemonic = "t";
            }
            : edit_box {
                label = "Output: ";
                value = "namer.map";
                edit_width = 12;
                edit_limit = 12;
                key = "save";
                mnemonic = "O";
            }
            : row {
                : button {
                    key = "plot_button";
                    label = "Plot";
                    mnemonic = "P";
                    fixed_width = true;
                }
                : button {
                    key = "header_button";
                    label = "Header";
                    mnemonic = "H";
                    fixed_width = true;
                }
                : button {