render.dcl

Autocad-2005-简体中文-解密版.zip

// Next available MSG number is   485 
// MODULE_ID RENDER_DCL_

//     Copyright (C) 1991-1997 by Autodesk, Inc.
//
//     Permission to use, copy, modify, and distribute this software
//     for any purpose and without fee is hereby granted, provided
//     that the above copyright notice appears in all copies and
//     that both that copyright notice and the limited warranty and
//     restricted rights notice below appear in all supporting
//     documentation.
//
//     AUTODESK PROVIDES THIS PROGRAM "AS IS" AND WITH ALL FAULTS.
//     AUTODESK SPECIFICALLY DISCLAIMS ANY IMPLIED WARRANTY OF
//     MERCHANTABILITY OR FITNESS FOR A PARTICULAR USE.  AUTODESK, INC.
//     DOES NOT WARRANT THAT THE OPERATION OF THE PROGRAM WILL BE
//     UNINTERRUPTED OR ERROR FREE.
//
//     Use, duplication, or disclosure by the U.S. Government is subject to
//     restrictions set forth in FAR 52.227-19 (Commercial Computer
//     Software - Restricted Rights) and DFAR 252.227-7013(c)(1)(ii)
//     (Rights in Technical Data and Computer Software), as applicable.
//
//.

//***************************************************************************
//
// Render Dialogue Control Language (DCL)
//
//***************************************************************************

// Change level to 3 for new DCL auditing.
dcl_settings : default_dcl_settings { }

@include "rendcomm.dcl"

//***************************************************************************
//

// Sub-assemblies common to the render and preferences dialog

render_quality : popup_list {
    label = "Rendering Type:";
    key = "pf_st";
    mnemonic = "R";
    list = "Render\nPhoto Real\nPhoto Raytrace";
    render_types = "crender\nautovis\nraytrace";
    edit_width = 20;
    fixed_width = true;
}

render_query : toggle {
    key = "pf_rp";
    label = "Query for Selections";
    mnemonic = "Q";
}

render_crop : toggle {
    key = "pf_cropwin";
    label = "Crop Window";
    mnemonic = "W";
}

render_procedure : column {
    : boxed_column {
        label = "Rendering Procedure";
        render_query;
        render_crop;
        : toggle {
            key =  "pf_sd";
            //  FIXME
            label = "Skip Render Dialog";
            mnemonic = "k";
        }
    }
    : edit_box_4 {
        label = "Light Icon Scale:";
        key = "pf_ic_tx";
        mnemonic = "L";
    }
    : edit_box_4 {
        label = "Smoothing Angle:";
        key = "pf_sa";
        mnemonic = "g";
    }
}

render_options : boxed_column {
    label = "Rendering Options";
    : toggle {
        key = "pf_ss";
        label = "Smooth Shade";
        mnemonic = "m";
    }
    : toggle {
        key = "pf_af";
        label = "Apply Materials";
        mnemonic = "A";
    }
    : toggle {
        key = "pf_sh";
        label = "Shadows";
        mnemonic = "d";
    }
    : toggle {
        key = "pf_ca";
        label = "Render Cache";
        mnemonic = "C";
    }
    : button {
        key = "Options";
        label = "More Options...";
        mnemonic = "O";
    }
}

sub_sample : boxed_column {
    label = "Sub Sampling";
    mnemonic = "u";
    : popup_list {
        key = "pf_subs";
        mnemonic = "u";
        list = "1:1 (Best)\n2:1\n3:1\n4:1\n5:1\n6:1\n7:1\n8:1 (Fastest)";
        subsample_types = "1\n2\n3\n4\n5\n6\n7\n8";
        edit_width = 15;
    }
}

render_env : column {
    sub_sample;
    : button {
        key = "pf_env_back";
        label = "Background...";
        mnemonic = "B";
    }
    : button {
        key = "pf_env_fog";
        label = "Fog/Depth Cue...";
        mnemonic = "F";
    }
}

render_destination : boxed_column {
    label = "Destination";
    mnemonic = "n";
    : popup_list {
        key = "pf_ds";
        list = "Viewport\nRender Window\nFile";
        mnemonic = "n";

    }
    spacer;
    : column {
        : var_text {
            key = "pf_width";
            alignment = left;
            label = "   Width   :  640";
        }
        : var_text {
            key = "pf_height";
            alignment = left;
            label = "   Height  :  480";
        }
        : var_text {
            key = "pf_colors";
            alignment = left;
            label = "   Colors    :  8-bit";
        }
    }
    spacer;
    : button {
        key = "FOptions";
        label = "More Options...";
        mnemonic = "p";
    }
}

pref : dialog {
    label = "Rendering Preferences";
    render_quality;
    spacer_1;
    : row {
        render_scene_list;
        render_procedure;
    }
    spacer_1;
    : row {
        render_options;
        render_destination;
        render_env;
    }
    spacer_1_ok_cancel_help_errtile;
}


render : dialog {
    label = "Render";
    render_quality;
    spacer_1;
    : row {
        render_scene_list;
        render_procedure;
    }
    spacer_1;
    : row {
        render_options;
        render_destination;
        render_env;
    }
    spacer_1;
    : row {
        fixed_width = true;
        alignment = centered;
        : button {
            key = "pf_re_scene";
            label = "Render";
            is_default = true;
        }
        : spacer { width = 2; }
        cancel_button;
        : spacer { width = 2; }
        help_button;
    }
    errtile;
}

//**************************************************************************
// Rendering Options

rp_alias_mode : boxed_radio_column {
    label = "Anti-Aliasing";
    key = "rpaliasmode";
    fixed_height = true;
    : radio_button {
        key = "ahnv";
        label = "Minimal";
        mnemonic = "i";
    }
    : radio_button {
        key = "ahsv";
        label = "L&ow";
    }
    : radio_button {
        key = "ahsv3";
        label = "M&edium";
    }
    : radio_button {
        key = "ahsv4";
        label = "Hi&gh";
    }
}

rp_adaptive_toggle : toggle {
    label = "Enable";
    key = "adaptive_enable";
    mnemonic = "E";
}

rp_ray_adaptive : boxed_column {
    key = "adapt_samp_box";
    label = "Adaptive Sampling";
    fixed_height = true;
    rp_adaptive_toggle;
    : edit_box_6 {
        label = "Contrast Threshold:";
        key = "contrast_threshold";
        mnemonic = "C";
    }

}


rp_raydepth_mode : boxed_column {
    label = "Ray Tree Depth";
    fixed_height = true;
    : edit_box_4 {
        label = "Maximum Depth:";
        key = "ray_depth";
        mnemonic = "D";
    }
    : edit_box_6 {
        label = "Cutoff Threshold:";
        key = "ray_threshold";
        mnemonic = "T";
    }
}


rp_shadow_mode : boxed_column {
    label = "Depth Map Shadow Controls";
    key = "rpshadowmode";
    : edit_box_8  {
        key = "minbias";
        label = "Minimum Bias: ";
        mnemonic = "B";
    }
    : edit_box_8  {
        key = "maxbias";
        label = "Maximum Bias: ";
        mnemonic = "x";
    }
}

rp_texmap_mode : boxed_radio_column {
    label = "Texture Map Sampling";
    key = "rptexmapmode";
    : radio_button  {
        key = "txpoint";
        label = "Point Sample";
        mnemonic = "P";
    }
    : radio_button  {
        key = "txlinterp";
        label = "Linear Sample";
        mnemonic = "L";
    }
    : radio_button  {
        key = "txmip";
        label = "Mip Map Sample";
        mnemonic = "M";
    }
}

scanline_options : dialog {
    label = "Photo Real Render Options";
    spacer_1;
    : row {
        : column {
            fixed_height = true;
            alignment = top;
            rp_alias_mode;
        }
        spacer_1;
        : column {
            fixed_height = true;
            alignment = top;
            other_options;
            spacer;
            rp_shadow_mode;
            spacer;
            spacer;
            rp_texmap_mode;
        }
    }
    spacer_1_ok_cancel_help_errtile;
}

raytrace_options : dialog {
    label = "Photo Raytrace Render Options";
    spacer_1;
    : row {
        : column {
            rp_alias_mode;
            rp_ray_adaptive;
            rp_raydepth_mode;
        }
        spacer_1;
        : column {
            other_options;
            spacer;
            rp_shadow_mode;
            spacer;
            spacer;
            rp_texmap_mode;
        }
    }
    spacer_1_ok_cancel_help_errtile;
}


//**************************************************************************
// Statistics dialog box

avis_stats : dialog {
    label = "Statistics";
    width = 50;
    : list_box { 
        key = "stats_list";
        height = 16;
        tabs = "24";
    }
    : row {
        alignment = centered;
        fixed_width = true;
        width = 39;
        : toggle {
            label = "Save Statistics to File:";
            mnemonic = "S";
            key = "save_stats";
            height = 1;
        }
        : edit_box {
            label = "";
            key = "stats_name";
            edit_width = 14;
            edit_limit = 132;
        }
        : button {
            label = "Find File...";
            mnemonic = "F";
            key = "findfile";
        }
    }
    spacer_1_ok_cancel_help_errtile;
}

//***************************************************************************
// Main light dialog.

avis_light : dialog {                       // identical to ave_light, plus North Location button
    label = "Lights";
    key = "dialog";
    dialog_kind = "main";
    : row {
        : column {
            : row {
                : list_box_8x8 {
                    key = "list";
                    label = "Lights:";
                    mnemonic = "L";
                }
                : column {
                    spacer_0;
                    button_mod;
                    button_del;
                    button_pkt;
                    spacer_0;
                }
            }
            : row {
                button_new;
                : popup_list { 
                    key = "light_type_popup";
                    edit_width = 15;
                    mnemonic = "T";
                    list = "Point Light\nDistant Light\nSpotlight";
                    light_types = "overhead\ndirect\nsh_spot";
                }
            }
            : button {
                key = "northloc";
                label = "North Location...";
                mnemonic = "o";
                fixed_width = true;
                alignment = centered;
            }
        }
        spacer;
        : column {
            children_alignment = centered;
            : boxed_column {
                label = "Ambient Light";
                : edit_box_4 {
                    label = "Intensity:";
                    key = "ambient_t";
                    mnemonic = "I";
                }
                : slider_0_1 { key = "ambient_s"; }
                : boxed_column {
                    label = "Color";
                    rgb_edit_slider;
                    light_color_panel;
                }
            }
        }
    }
    spacer_1_ok_cancel_help_errtile;
}

//***************************************************************************
// Dialog to edit the currently selected Point light definition.

avis_point_light : dialog {
    key = "dialog";
    dialog_kind = "point";
    : row {
        ave_basic_lights;
        : column {
            alignment = top;
            fixed_height = true;
            attenuation_panel;
            shadow_panel;
            spacer_0;
        }
    }
    spacer_1_ok_cancel_help_errtile;
}

//***************************************************************************