rendcomm.dcl

Autocad-2005-简体中文-解密版.zip

        : edit_box_4       { key = "bottom_edit"; }
    }
    : column {
        : slider_0_1_fixed { key = "top_slider"; }
        : slider_0_1_fixed { key = "middle_slider"; }
        : slider_0_1_fixed { key = "bottom_slider"; }
    }
    : column {
        : color_image      { key = "top_image"; }
        : color_image      { key = "middle_image"; }
        : color_image      { key = "bottom_image"; }
    }
}



color_name : text_part {
    width = 11;
    label = "";
}
 
color_image : image {
    height = 1;
    aspect_ratio = 1;
    fixed_height = true;
    fixed_width = true;
    color = -15;         /* -15 = dialog background color */
}
 
//***************************************************************************
// Replay

replay : dialog {
    label = "Image Specifications";
    width = 22;
    alignment = centered;
    spacer_1;
    : column {
        : row {
            : column {
                fixed_width = true;
                width = 20;
                : text_part {
                    alignment = centered;
                    key = "imgsz";
                    width = 16;
                }
                : image_button {              // Virtual image window
                    alignment = centered;
                    key = "vimg";
                    color = 0;
                    aspect_ratio = 1;
                    height = 6;
                    width = 16;
                    fixed_width = true;
                    fixed_height = true;
                    is_tab_stop = false;
                    image_flush = true;
                }
                spacer;
                : text_part {
                    alignment = centered;
                    label = " Image Offset";
                    width = 16;
                }
                : row {
                    : edit_box_4 { 
                        label = "X:";
                        key = "imgoffx"; 
                    }
                    : edit_box_4 { 
                        label = "Y:";
                        key = "imgoffy"; 
                    }
                }
            }
            spacer;
            : column {
                fixed_width = true;
                width = 20;
                : text_part {
                    alignment = centered;
                    key = "winsz";
                    width = 16;
                }
                : image_button {              // Virtual window window
                    alignment = centered;
                    key = "vwin";
                    color = 0;
                    aspect_ratio = 1;
                    height = 6;
                    width = 16;
                    fixed_width = true;
                    fixed_height = true;
                    is_tab_stop = false;
                }
                spacer;
                : text_part {
                    alignment = centered;
                    label = " Screen Offset";
                    width = 16;
                }
                : row {
                    : edit_box_4 { 
                        label = " X:";
                        key = "winoffx"; 
                    }
                    : edit_box_4 { 
                        label = "Y:";
                        key = "winoffy"; 
                    }
                }
             }
          }
          spacer_1;
          : row {
            : column {
                fixed_width = true;
                width = 20;
                : text_part {
                    alignment = centered;
                    label = " Image Size";
                    width = 16;
                }
                : row {
                    : edit_box_4 { 
                        label = "X:";
                        key = "imgsizex"; 
                    }
                    : edit_box_4 { 
                        label = "Y:";
                        key = "imgsizey"; 
                    }
                }
            }
            : column {
                fixed_width = true;
                width = 20;
                : text_part {
                    alignment = centered;
                    label = " Screen Size";
                    width = 16;
                }
                : row {
                    : concatenation {
                        : text_part { 
                            label = " X:  ";
                        }
                        : text_part { 
                            key = "winsizex"; 
                            width = 4; 
                        }
                    }
                    : concatenation {
                        : text_part { 
                            label = "Y:  ";
                        }
                        : text_part { 
                            key = "winsizey"; 
                            width = 4; 
                        }
                    }
                }
            }
        }
    }
    spacer_1;
    : button {
        key = "rst";
        mnemonic = "R";
        label = "Reset";
        fixed_width = true;
        alignment = centered;
    }
    spacer_1_ok_cancel_help_errtile;
}

//***************************************************************************
//  saveimg dialog

saveimg : dialog {
    label = "Save Image";
    : row {
        : boxed_radio_column {
            label = "Format";
            key = "frmt";
            : radio_button {
                label = "BMP";
                key = "bmp";
                mnemonic = "B";
            }
            : radio_button {
                label = "TGA";
                key = "tga";
                mnemonic = "T";
            }
            : radio_button {
                label = "TIFF";
                key = "tif";
                mnemonic = "F";
            }
            : button {
                key = "opt";
                label = "Options...";
                mnemonic = "p";
            }
        }
        : boxed_row {
            label = "Portion";
            spacer;
            : column {
                : text_part {
                    label = "Active viewport";
                    fixed_width = true;
                    alignment = centered;
                }
                : image_button {              // Virtual window window
                    key = "vwin";
                    color = 0;
                    alignment = centered;
                    aspect_ratio = 1;
                    height = 6;
                    width = 16;
                    fixed_width = true;
                    fixed_height = true;
                    image_flush = true;
                }
                : button {
                    key = "rst";
                    label = "Reset";
                    mnemonic = "R";
                }
            }
            : column {
                : row {
                    : text_part {
                        label = "      Size : ";
                        mnemonic = "S";
                      }
                    : text_part {
                         key = "vportsz";
                         width = 12;
                    }
                }
                : row {
                    : text_part {
                        label = "      Offset ";
                        mnemonic = "O";
                      }
                    : text_part {
                        label = "      Size ";
                        mnemonic = "S";
                      }
                }
                : row {
                    fixed_width = true;
                    alignment = centered;
                    : edit_box_4 {
                        label = "X:";
                        key = "winoffx";
                    }
                    : edit_box_4 {
                        label = " X:";
                        key = "winsizex";
                    }
                }
                : row {
                    fixed_width = true;
                    alignment = centered;
                    : edit_box_4 {
                        label = "Y:";
                        key = "winoffy";
                    }
                    : edit_box_4 {
                        label = " Y:";
                        key = "winsizey";
                    }
                }
            }
        }
    }
    spacer_1_ok_cancel_help_errtile;
}


//***************************************************************************
//

tga_options : dialog {
    label = "TGA Options";
    spacer;
    : boxed_radio_row {
        label = "Compression";
        key = "comp";
        : radio_button {
            label = "None";
            mnemonic = "N";
            key = "none";       // returned as "value" of radio_cluster
        }
        : radio_button {
            label = "RLE";
            mnemonic = "R";
            key = "rle";
        }
    }
    spacer_1_ok_cancel_help;
}

//***************************************************************************
//

tif_options : dialog {
    label = "TIFF Options";
    spacer;
    : boxed_radio_row {
        label = "Compression";
        key = "comp";
        : radio_button {
            label = "None";
            mnemonic = "N";
            key = "none";       // returned as "value" of radio_cluster
        }
        : radio_button {
            label = "PACK";
            mnemonic = "P";
            key = "pack";
        }
    }
    spacer_1_ok_cancel_help;
}

//*****************************************************************************
//*****************************************************************************
// Lights Common widgets

distant_light_parameters_panel : column {
    fixed_height = true;
    : edit_box_8 {
        label = "Light Name:";
        key = "name";
        mnemonic = "N";
    }
    : row {
        : edit_box_8 {
            label = "Intensity: ";
            key = "inten_t";
            edit_width = 8;
            mnemonic = "I";
        }
        : slider {
            key = "inten_s";
            min_value = 0;
            max_value = 10000;
            small_increment = 100;
            big_increment = 1000;
        }
    }
    : boxed_column {
        label = "Color";
        rgb_edit_slider;
        light_color_panel;
    }
}

light_color_panel : row {
    : image_button {
        key = "color";
        color = -15;             /* background color */
        height = 1;
        width = 8;
    }
    spacer_1;
    : column {
        width = 14;
        : button {
            label = "Select Color...";
            key = "mod_color";
            mnemonic = "C";
            alignment = centered;
        }
        : button {
            label = "Select Indexed...";
            key = "select_aci";
            mnemonic = "x";
            alignment = centered;
        }
    }
}


azimuth_altitude_panel : boxed_row {
    : column {
        : edit_box {
            label = "Azimuth:";
            key = "azimuth_t";
            mnemonic = "u";
            edit_width = 6;
            edit_limit = 6;
        }
        : image_button {
            key = "azimuth_image";
            color = dialog_background;
            height = 7;
            aspect_ratio = 1;
            fixed_height = true;
            fixed_width = true;
            alignment = centered;
        }
        : slider  {
            key = "azimuth_slider";
            min_value = -180;
            max_value = 180;
            small_increment = 1;
            big_increment = 10;
        }
    }
    : column {
        : edit_box {
            label = "Altitude:";
            key = "altitude_t";
            mnemonic = "d";
            edit_width = 6;
            edit_limit = 6;
        }
        : image_button {
            key = "altitude_image";
            color = dialog_background;
            height = 7;
            aspect_ratio = 1;
            fixed_height = true;
            fixed_width = true;
            alignment = centered;
        }
        : slider  {
            key = "altitude_slider";
            min_value = 0;
            max_value = 90;
            small_increment = 1;
            big_increment = 10;
        }
    }
}



light_source_panel : column {
    : boxed_column {
        label = "Light Source Vector";
        : row {
            : edit_box_4 {
                label = "X:";
                key = "x";
                mnemonic = "X";
            }
            spacer;
            : edit_box_4 {
                label = "Y:";
                key = "y";
                mnemonic = "Y";
            }
            spacer;
            : edit_box_4 {
                label = "Z:";
                key = "z";
                mnemonic = "Z";
            }
        }
        : button {
            alignment = centered;
            fixed_width = true;
            key = "mod_points";
            label = "Modify <";
            mnemonic = "M";
        }
    }
}


//***************************************************************************
// Tile used by all three light types.
 
ave_basic_lights : column {
    : edit_box_8 {
        label = "Light Name:";
        key = "name";
        mnemonic = "N";
    }
    : edit_box_8 {
        label = "Intensity:";
        key = "inten_t";
        mnemonic = "I";
    }
    : slider  {
        key = "inten_s";
        min_value = 0;
        max_value = 10000;
        small_increment = 100;
        big_increment = 1000;
    }
    position_panel;
    : boxed_column {
        label = "Color";
        rgb_edit_slider;
        light_color_panel;
    }
}

position_panel : boxed_row {