details.vbs

数据库课程设计

' 注释：定义过程用于获得图书的封面图片
Function GetCover(ISBN) 
   Dim fso, fpath
   fpath = "cover/" & ISBN & ".jpg" 
   Set fso = CreateObject("Scripting.FileSystemObject")
   If (fso.FileExists(Server.MapPath(fpath))) Then
      GetCover = fpath
   Else
      GetCover = "cover/none.gif"
   End If
End Function

' 注释：定义过程用于获得图书的装订信息
Function GetFormat(format)
   If IsNull(format) Then
      GetFormat = "不祥"
   ElseIf format = 1 Then
      GetFormat = "简装本"
   Else
      GetFormat = "精装本"
   End If
End Function

' 注释：定义过程用于获得图书的开本信息
Function GetPsize(psize)
   If IsNull(psize) Then
      GetPsize = "不祥"
   Else
      Select Case psize
         Case 1 GetPsize = "小16开（789×1092）"
         Case 2 GetPsize = "大16开（850×1168）"
         Case 3 GetPsize = "其他"
      End Select
   End If
End Function

' 注释：定义过程用于获得图书的页数信息
Function GetPages(pages)
   If IsNull(pages) Then
      GetPages = "不祥"
   Else
      GetPages = pages & " 页"
   End If
End Function

' 注释：定义过程用于获得图书的字数信息
Function GetWords(words)
   If IsNull(words) Then
      GetWords = "不祥"
   Else
      GetWords = words & " 千字"
   End If
End Function
'<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
'<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
' 注释：定义表单的提交事件
Function freg_OnSubmit
' 注释：验证表单数据
' 注释：如果会员名文本框只读表示当前显示的是登录用户的注册资料
   If freg.userid.readonly Then	' 不验证会员名（会员名不可更改）
   ' 注释：如果密码文本框不空，则验证密码
	  If freg.pass.value <> "" Then
         If Not check_pass Then
            freg_OnSubmit = False
            Exit Function
         End If
      End If
   Else	' 否则是新用户注册
   ' 注释：验证会员名
      If Not check_id Then
         freg_OnSubmit = False
         Exit Function
      End If
   ' 注释：验证密码
      If Not check_pass Then
         freg_OnSubmit = False
         Exit Function
      End If
   ' 注释：如果新用户没有设置认证码和真实姓名，则使用默认值
      If freg.affirm.value = "" Then freg.affirm.value = freg.pass.value
      If freg.name.value = "" Then freg.name.value = freg.userid.value
   End If
' 注释：通过验证，可以提交数据
   freg_OnSubmit = True
End Function
' 注释：定义会员名的验证过程
Function check_id
   If freg.userid.value = "" Then
      Alert("[会员名]信息不能为空！请先输入...")
      freg.userid.focus
      check_id = False
   Else
      check_id = True
   End If
End Function
' 注释：定义密码的验证过程
Function check_pass
   Dim ermsg
   ermsg = ""
   
   If freg.pass.value = "" Then
      ermsg = "[密码]信息不能为空！请先输入..."
      freg.pass.focus
   ElseIf freg.repass.value = "" Then
      ermsg = "[重复密码]信息不能为空！请先输入..."
      freg.repass.focus
   ElseIf freg.pass.value <> freg.repass.value Then
      ermsg = "[密码]没有通过确认！请重新确认..."
      freg.repass.value = ""
      freg.repass.focus
   End If
   
   If ermsg = "" Then
      check_pass = True
   Else
      Alert(ermsg)
      check_pass = False
   End If
End Function
'<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
'<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
' 注释： 定义登录按钮的单击事件
Sub login_OnClick
' 注释： 验证用户的登录信息
   If flog.userid.value = "" Then
      ermsg = "会员名信息不能为空！请先输入..."
      flog.userid.focus
   ElseIf flog.pass.value = "" Then
      ermsg = "密码信息不能为空！请先输入..."
      flog.pass.focus
   End If
' 注释： 根据验证结果判断是否提交数据
   If ermsg = "" Then
      flog.submit
   Else
      Alert(ermsg)
   End If
End Sub
' 注释： 定义注册按钮的单击事件
Sub register_OnClick
   window.open "member.asp", "_blank"
End Sub
' 注释： 定义个人资料按钮的单击事件
Sub reginfo_OnClick
   window.open "member.asp", "_blank"
End Sub
' 注释： 定义购书记录按钮的单击事件
Sub history_OnClick
   window.open "orderlist.asp", "_blank"
End Sub
' 注释： 定义结算按钮的单击事件
Sub pay_OnClick
   If parent.sale5.fbag.ISBNs.value = "" Then
      Alert("您的购物袋还是空的！请先选择所需的图书...")
   Else
      parent.sale5.fpay.ISBNs.value = parent.sale5.fbag.ISBNs.value
      parent.sale5.fpay.nums.value = parent.sale5.fbag.nums.value
      parent.sale5.fpay.submit
      parent.sale5.fpay.ISBNs.value = ""
      parent.sale5.fpay.nums.value = ""
   End If
End Sub
' 注释： 定义清空购物袋按钮的单击事件
Sub clear_OnClick
   msg = "是否清空您的购物袋？请确认..."
   If msgbox(msg, 292, "系统提示") = 7 Then Exit Sub
' 注释： 将购物信息清除
   parent.sale5.fbag.ISBNs.value = ""
   parent.sale5.fbag.titles.value = ""
   parent.sale5.fbag.nums.value = ""
' 注释： 更新购物袋的显示
   parent.sale5.fbag.submit
End Sub