configure.ac

fdisk 实现源码,可以查询Linux下系统的分区信息

AC_PREREQ(2.50)
AC_INIT(fdisk, 1.0, [[e-mail]])
AC_CONFIG_AUX_DIR(autotools)

AM_INIT_AUTOMAKE
AM_CONFIG_HEADER(config.h)
AM_GNU_GETTEXT_VERSION([0.16.1])
AM_GNU_GETTEXT([external])

AM_MAINTAINER_MODE

dnl set some basic variables
BUILD_DATE="`date '+%D'`"
AC_DEFINE_UNQUOTED(BUILD_DATE, "$BUILD_DATE", [The date of the build.])

# Check for programs.
AC_PROG_AWK
AC_LANG_C
AC_PROG_CC
AC_PROG_INSTALL
AC_PROG_LN_S


AC_CANONICAL_HOST
case "$host_os" in
	linux*) AC_DEFINE([NAMING_LINUX], [1], [Define 1 if this is an OS with Linux naming scheme]) ;;
	freebsd*) AC_DEFINE([NAMING_BSD], [1], [Define 1 if this is an OS with BSD naming scheme]) ;;
esac

# Check headers.
AC_CHECK_HEADERS([ctype.h errno.h stdio.h getopt.h stdarg.h string.h \
		 stdlib.h unistd.h parted/parted.h])

# Check for library functions.
#AC_CHECK_FUNCS([])

# Check for LFS
AC_SYS_LARGEFILE
CFLAGS="$CFLAGS -D_FILE_OFFSET_BITS=${ac_cv_sys_file_offset_bits}"

dnl libparted
# hack
LIBS="$LIBS -ldl"
CHECK_LIBPARTED([1.7.0], ,
                       AC_MSG_ERROR([*** libparted >= 1.7.0 not installed - please install first ***]))

AC_SUBST(PARTED_LIBS)


dnl ncurses
CHECK_CURSES(have_curses=true , have_curses=false)
AC_SUBST(CURSES_LIBS)

dnl Check if we have check...

dnl PKG_CHECK_MODULES([CHECK],[check >= 0.8.2], have_check=true, have_check=false)
CHECK_CHECK([0.8.2], have_check=true, have_check=false)
AM_CONDITIONAL(MAKE_TESTS, test x$have_check = xtrue)
AM_CONDITIONAL(MAKE_CFDISK, test x$have_curses = xtrue)

dnl Check how to create the {g,l}fdisk links
AC_MSG_CHECKING([how to create links])
rm -f test00 test01
touch test00
ln -s test00 test01 || :
SYMLINK=""
SYMLINKFROM="fdisk"
if test -L test01; then
	SYMLINK="ln -s"
else
	SYMLINKFROM="${sbindir}/fdisk"
	rm -f test01
	ln test00 test01 || :
	if test -e test01; then
		SYMLINK="ln"
	else
		SYMLINK="cp"
	fi
fi
AC_MSG_RESULT($SYMLINK)
AC_SUBST(SYMLINK)
AC_SUBST(SYMLINKFROM)
rm -f test00 test01

AC_ARG_WITH([gnu-ext], AS_HELP_STRING([--with-gnu-ext],[Enable GNU extensions]),
   AC_DEFINE([GNU_EXT], [1], [Define to 1 if you enable GNU extensions]))

AC_ARG_ENABLE(cfdisk, AS_HELP_STRING([--disable-cfdisk],[Do not compile cfdisk]),
   [case "${enableval}" in
     yes) cfdisk=true ;;
     no)  cfdisk=false ;;
     *) AC_MSG_ERROR(bad value ${enableval} for --enable-cfdisk) ;;
   esac],
   [cfdisk=auto])  

if test x$cfdisk = xtrue && test x$have_curses != xtrue; then
	AC_MSG_ERROR([*** curses required for cfdisk ***])
fi

AM_CONDITIONAL(MAKE_CFDISK, test x$cfdisk != xfalse && test x$have_curses = xtrue)

AC_CONFIG_FILES([Makefile src/Makefile doc/Makefile tests/Makefile po/Makefile.in])
AC_OUTPUT