f2812_boot.cmd

TI的2812控制交通灯

/**********************************************************************
* File: f2812.cmd -- Linker command file for Boot to Flash bootmode.
* History: 09/08/03 - original (based on DSP28 header files v1.00, D. Alter)
*          02/14/05 - made consistent with DSP/BIOS linkage allocation (D. Alter)
**********************************************************************/

-l rts2800_ml.lib
-stack 0x400

MEMORY
{
PAGE 0:    /* Program Memory */
   L0SARAM          : origin = 0x008000, length = 0x001000     /* 4Kw L0 SARAM */
   ZONE6            : origin = 0x100000, length = 0x001000     /* XINTF Zone 6 - 64Kw SRAM on eZdspF2812 */
   OTP              : origin = 0x3D7800, length = 0x000400     /* on-chip OTP */
   FLASH_ABCDEFGHIJ : origin = 0x3D8000, length = 0x01FF80     /* on-chip FLASH */
   CSM_RSVD         : origin = 0x3F7F80, length = 0x000076     /* Part of FLASH sector A.  Reserved when CSM is in use. */
   BEGIN_FLASH      : origin = 0x3F7FF6, length = 0x000002     /* Part of FLASH sector A.  Used for "boot to flash" bootloader mode. */
   PASSWORDS        : origin = 0x3F7FF8, length = 0x000008     /* Part of FLASH sector A.  CSM password locations. */
   BEGIN_H0         : origin = 0x3F8000, length = 0x000002     /* Part of H0.  Used for "boot to H0" bootloader mode. */
   H0SARAM          : origin = 0x3F8002, length = 0x001FFE     /* 8Kw H0 SARAM */
   IQTABLES         : origin = 0x3FF000, length = 0x000B50     /* Part of Boot ROM */
   BOOTROM          : origin = 0x3FFB50, length = 0x000470     /* 4Kw Boot ROM, available if MP/MCn=0 */
   RESET            : origin = 0x3FFFC0, length = 0x000002     /* part of Boot ROM (MP/MCn=0) or XINTF zone 7 (MP/MCn=1) */
   VECTORS          : origin = 0x3FFFC2, length = 0x00003E     /* part of Boot ROM (MP/MCn=0) or XINTF zone 7 (MP/MCn=1) */

 PAGE 1 :   /* Data Memory */
   M0SARAM          : origin = 0x000000, length = 0x000400     /* 1Kw M0 SARAM */
   M1SARAM          : origin = 0x000400, length = 0x000400     /* 1Kw M1 SARAM */
   L1SARAM          : origin = 0x009000, length = 0x001000     /* 4Kw L1 SARAM */
}

 
SECTIONS
{
/*** Compiler Required Sections ***/
  /* Program memory (PAGE 0) sections */
   .text             : > FLASH_ABCDEFGHIJ,  PAGE = 0
   .cinit            : > FLASH_ABCDEFGHIJ,  PAGE = 0
   .const            : > FLASH_ABCDEFGHIJ,  PAGE = 0
   .econst           : > FLASH_ABCDEFGHIJ,  PAGE = 0      
   .pinit            : > FLASH_ABCDEFGHIJ,  PAGE = 0
   .reset            : > RESET,             PAGE = 0, TYPE = DSECT  /* We are not using the .reset section */
   .switch           : > FLASH_ABCDEFGHIJ,  PAGE = 0

  /* Data Memory (PAGE 1) sections */
   .bss              : > L1SARAM,           PAGE = 1
   .ebss             : > L1SARAM,           PAGE = 1
   .cio              : > L1SARAM,           PAGE = 1
   .stack            : > M1SARAM,           PAGE = 1
   .sysmem           : > L1SARAM,           PAGE = 1
   .esysmem          : > L1SARAM,           PAGE = 1

/*** User Defined Sections ***/
   codestart         : > BEGIN_FLASH,       PAGE = 0            /* Used by file CodeStartBranch.asm */
   csm_rsvd          : > CSM_RSVD,          PAGE = 0            /* Used by file passwords.asm */
   internalMemFuncs  : > FLASH_ABCDEFGHIJ,  PAGE = 0            /* Used by file Xintf.c.  Link to internal memory. */
   passwords         : > PASSWORDS,         PAGE = 0            /* Used by file passwords.asm */

   /* Section secureRamFuncs used by file SysCtrl.c. */
   
   /*secureRamFuncs    :   LOAD = FLASH_ABCDEFGHIJ, PAGE = 0      /* Should be Flash */
   /*                      RUN = L0SARAM,           PAGE = 0      /* Must be CSM secured RAM */
   /*                      LOAD_START(_secureRamFuncs_loadstart),
                         LOAD_END(_secureRamFuncs_loadend),
                         RUN_START(_secureRamFuncs_runstart)
	*/
}

/******************* end of file ************************/