sdram.lcf

Freescale MCF5445evb 参考测试代码

#/*                                                                               
# * File:       sdram.lcf                                                        
# * Purpose:    Linker file targeting SDRAM on Jamaica
# *                                                                               
# * Notes:      
# */                                                                              

MEMORY 
{
    text    (RX) : ORIGIN = 0x40020000,  LENGTH = 0
    data    (RW) : ORIGIN = AFTER(text), LENGTH = 0
}

SECTIONS 
{
    ___FLASH1               = 0x00000000;
    ___FLASH1_SIZE          = (16 * 1024 * 1024);

    ___FLASH0               = 0x04000000;
    ___FLASH0_SIZE          = (512 * 1024);

    ___CPLD                 = 0x08000000;
    ___CPLD_SIZE            = (16 * 1024 * 1024);

    ___FPGA                 = 0x09000000;
    ___FPGA_SIZE            = (16 * 1024 * 1024);

    ___SDRAM                = 0x40000000;
    ___SDRAM_SIZE           = (256 * 1024 * 1024);

    ___SRAM                 = 0x80000000;
    ___SRAM_SIZE            = (32 * 1024);

    ___VECTOR_RAM           = ___SDRAM;

    .text :
    {
        ___TEXT_START        = .;
        vectors.s (.text)   # Force vectors to the bottom of the map
        .                   = . + 0x100;     
        *(.text)
        *(.rodata)
        .                   = ALIGN(0x10);
        ___TEXT_END         = .;
    } > text

    .data :
    {
        .                   = ALIGN(0x10);
        ___DATA_ROM         = .;
        ___DATA_RAM         = .;
        *(.data)
        *(.sdata)
		*(.relocate_code)
		*(.relocate_const)
		*(.relocate_data)
        ___DATA_END         = .;
        .                   = ALIGN(0x10);
        ___BSS_START        = .;
        *(.sbss)
        *(SCOMMON)
        *(.bss)
        *(COMMON)
        .                   = ALIGN(0x10);
        ___BSS_END          = .;
        ___SP_END		    = .;
        ___SP_INIT		    = ___SP_END + (2 * 1024);
        ___HEAP_START	    = ___SP_INIT;
        ___HEAP_END 	    = ___SDRAM + ___SDRAM_SIZE;
    } > data
}