flash0_sram.lcf

Freescale MCF5445evb 参考测试代码

#/*                                                                               
# * File:       flash0_sram.lcf                                                        
# * Purpose:    Linker file targeting Atmel AT49BV040 flash and on-chip SRAM
# *                                                                               
# * Notes:      Creates a flash-bootable image
# */                                                                              

MEMORY 
{
    rom     (RX) : ORIGIN = 0x04000000, LENGTH = 0
    ram     (RW) : ORIGIN = 0x80000400, LENGTH = 0
}

SECTIONS 
{
    ___FLASH1               = 0x00000000;
    ___FLASH1_SIZE          = (16 * 1024 * 1024);

    ___FLASH0               = 0x04000000;
    ___FLASH0_SIZE          = (512 * 1024);

    ___CPLD                 = 0x08000000;
    ___CPLD_SIZE            = (16 * 1024 * 1024);

    ___FPGA                 = 0x09000000;
    ___FPGA_SIZE            = (16 * 1024 * 1024);

    ___SDRAM                = 0x40000000;
    ___SDRAM_SIZE           = (256 * 1024 * 1024);

    ___SRAM                 = 0x80000000;
    ___SRAM_SIZE            = (32 * 1024);

    ___VECTOR_RAM           = ___SRAM;

    .text :
    {
        vectors.s (.text)   # Force vectors to the bottom of the map       
        *(.text)
        *(.rodata)
        ___DATA_ROM         = ALIGN(0x10);
    } > rom

    .data : AT(___DATA_ROM)
    {
        ___DATA_RAM         = .;
        *(.data)
        *(.sdata)
		*(.relocate_code)
		*(.relocate_const)
		*(.relocate_data)
        ___DATA_END         = .;
        .                   = ALIGN(0x10);
        ___BSS_START        = .;
        *(.sbss)
        *(SCOMMON)
        *(.bss)
        *(COMMON)
        .                   = ALIGN(0x10);
        ___BSS_END          = .;
        ___SP_END		    = .;
        ___SP_INIT		    = ___SP_END + (2 * 1024);
        ___HEAP_START	    = ___SP_INIT;
        ___HEAP_END 	    = ___SRAM + ___SRAM_SIZE;
    } > ram
}