c_index.asp

此文件为一个电子同学录

<!--#include file="conn.asp"-->
<!-- #include file="inc/const.asp" -->
<%
'=========================================================
' File: c_index.asp
 ' Date: 2006-04-06
' Script Written by Leibo
'=========================================================
' Copyright (C) 2002,2008 Mathren.com. All rights reserved.
' Web: http://www.hrbyydz.com
' Email: [e-mail]
'=========================================================

dim orders,ordername
dim currentpage,page_count,Pcount
dim totalrec,endpage
dim bbsnum,usernum
dim select1,select2,select3,select4,select5,select6,select7,select8
dim ilevel

if Cint(GroupSetting(1))=1 then
	Errmsg=Errmsg+"<br>"+"<li>您没有浏览同学录成员通讯录的权限，请<a href=login.asp>登陆</a>或者同管理员联系。"
	founderr=true
end if

if founderr then
	call head()
	call head_var("","")
	call txl_error()
else
	currentPage=request("page")
	if not isInteger(request("orders")) or request("orders")="" then
		orders=1
	else
		orders=request("orders")
	end if
	select case orders
	case 1
		orders=1
		ordername="所有注册用户"
		select1="selected"
	case 2
		orders=2
		ordername="班级成员列表"
		select2="selected"
	case 3
		orders=3
		ordername="班级客人列表"
		select3="selected"
	case 4
		orders=4
		ordername="班级贵宾列表"
		select7="selected"
	case 5
		orders=5
		ordername="大富翁排行榜"
		select8="selected"
	case else
		orders=1
		ordername="所有注册用户"
		select1="selected"
	end select
	
	stats=ordername
	call head()
	call head_var("班级名片","c_index.asp")
	call main()
end if
call foot()


sub main()

	set rs=conn.execute("select top 1 UserNum from config where active=1")
	usernum=rs(0)
%>
<table width="<%=txl_body(0)%>" cellpadding="0" cellspacing="0" align="center" style="border:1px <%=txl_body(9)%> solid; border-top-width: 0px; border-right-width: 1px; border-bottom-width: 0px; border-left-width: 1px;">  
<tr> 
<td  bgcolor=<%=txl_body(10)%>><br>
<table cellpadding=3 cellspacing=1 align=center class=tableBorder1 width=<%=txl_body(19)%>>
<form method=POST action=c_index.asp>
<tr>
<td colspan=5 valign=top width=60% class=tablebody1>&nbsp;>> <B><%=ordername%></B> <<<BR><BR>&nbsp;总注册用户数： <%=usernum%> 人</td>
<td colspan=3 width=40% align=center class=tablebody1>
	<select name=orders onchange='javascript:submit()'>
	<option value=1 <%=select1%>>所有注册用户</option>
	<option value=2 <%=select2%>>班级成员列表</option>
	<option value=3 <%=select3%>>班级客人列表</option>
	<option value=4 <%=select4%>>班级贵宾列表</option>
	<option value=5 <%=select5%>>大富翁排行榜</option>
	</select>
</td>
</tr>
</form>
<tr> 
<th height=25>用户名</th>
<th>Email</th>
<th>OICQ</th>
<th>主页</th>
<th>短消息</th>
<th>注册时间</th>
<th>用户类别</th>
<th>当前财产</th>
</tr>
<%
	if currentpage="" or not isInteger(currentpage) then
		currentpage=1
	else
		currentpage=clng(currentpage)
		if err then
			currentpage=1
			err.clear
		end if
	end if
	set rs=server.createobject("adodb.recordset")
	select case orders
	case 1
		sql="select realname,email,usergroup,oicq,homepage,regtime,usermoney from [user] order by userid desc"
	case 2
		sql="select realname,email,usergroup,oicq,homepage,regtime,usermoney from [user] where usergroupid<=3 order by userid desc"
	case 3
		sql="select realname,email,usergroup,oicq,homepage,regtime,usermoney from [user] where usergroupid=4 order by userid desc"
	case 4
		sql="select realname,email,usergroup,oicq,homepage,regtime,usermoney from [user] where usergroupid=5 order by userid desc"
	case 5
		sql="select realname,email,usergroup,oicq,homepage,regtime,usermoney from [user] order by usermoney desc"
	case else
		sql="select realname,email,usergroup,oicq,homepage,regtime,usermoney from [user] order by userid desc"
	end select
	rs.open sql,conn,1
	if rs.eof and rs.bof then
		response.write "<tr><td colspan=8 class=tablebody1 align=center height=25>还没有任何用户数据。</font></td></tr>"
	else
	if orders=1 then
	totalrec=userNum
	else
	totalrec=rs.recordcount
	end if
  	if totalrec mod txl_set(12)=0 then
     		Pcount= totalrec \ txl_set(12)
  	else
     		Pcount= totalrec \ txl_set(12)+1
  	end if
	RS.MoveFirst
	if currentpage > Pcount then currentpage = Pcount
   	if currentpage<1 then currentpage=1
	RS.Move (currentpage-1) * txl_set(12)
	page_count=0
	do while not rs.eof and page_count < Clng(txl_set(12))
%>
<tr>
<td height=28 class=tablebody1>&nbsp;<a href=userinfo.asp?name=<%=rs("realname")%> target=_blank><%=rs("realname")%></a></td>
<td align=center class=tablebody2><a href=mailto:<%=rs("email")%>><img border=0 src=<%=txl_info(7)%>email.gif></a></td>
<td align=center class=tablebody1><%=iimg(rs("oicq"),"----","<a href=http://search.tencent.com/cgi-bin/friend/user_show_info?ln="&rs("oicq")&" target=_blank><img src="""&txl_info(7)&"oicq.gif"" alt='查看 OICQ:"&rs("oicq")&" 的资料' border=0 ></a>")%></td>
<td align=center class=tablebody2><%=iimg(rs("homepage"),"----","<a href="&rs("homepage")&" target=_blank><img src="""&txl_info(7)&"homepage.gif"" border=0></a>")%></td>
<td align=center class=tablebody1><a href=javascript:openScript('messanger.asp?action=new&touser=<%=htmlencode(rs("realname"))%>',500,400)><img src=<%=txl_info(7)%>message.gif border=0></a></td>
<td align=center class=tablebody2><%=rs("regtime")%></td>
<td align=center class=tablebody1> <%=rs("usergroup")%><br></td>
<td align=center class=tablebody1><%=rs("usermoney")%></td>
</tr>
<%
		page_count=page_count+1
		rs.movenext
	loop
	end if
%>
</table>
<table border=0 cellpadding=0 cellspacing=3 align=center width=<%=txl_body(19)%>>
<tr>
<td valign=middle nowrap>页次：<b><%=currentpage%></b>/<b><%=Pcount%></b>页
&nbsp;
每页<b><%=txl_set(12)%></b> 总数<b><%=totalrec%></b></td>
<td valign=middle nowrap><div align=right><p>分页： 
<%
	if currentpage > 4 then
	response.write "<a href=""?page=1&orders="&orders&""">[1]</a> ..."
	end if
	if Pcount>currentpage+3 then
	endpage=currentpage+3
	else
	endpage=Pcount
	end if
	for i=currentpage-3 to endpage
	if not i<1 then
		if i = clng(currentpage) then
			response.write " <font color=#ce0000>["&i&"]</font>"
		else
			response.write " <a href=""?page="&i&"&orders="&orders&""">["&i&"]</a>"
		end if
	end if
	next
	if currentpage+3 < Pcount then
		response.write "... <a href=""?page="&Pcount&"&orders="&orders&""">["&Pcount&"]</a>"
	end if
%>
</p></div></td></tr>
</table>
<br>
</td>
</tr>
</table>
<%
	rs.close
	set rs=nothing
end sub
%>