📄 report.asp
字号:
<!-- #include file = "../include/asphead.asp" -->
<!-- #include file = "../include/function.asp" -->
<%CheckUser()%>
<link href="../include/main.css" rel="stylesheet" type="text/css">
<script src="../include/function.js" type="text/javascript"></script>
<script ID="clientEventHandlersJS" LANGUAGE="javascript">
<!--
function ChgRptOrder(strOrderBy)
{
var strOldOrderBy;
strOldOrderBy=frmData.OrderBy.value;
frmData.OrderBy.value=GetNewOrder(strOrderBy,strOldOrderBy);
frmData.target ="_self";
frmData.submit();
}
function PrintReport()
{
window.focus()
window.print();
}
function window_onload() {
window.parent.RightHead.btnPrint.disabled =false;
window.parent.RightHead.btnExport.disabled =false;
}
//-->
</script>
<%
dim WExcel
set WExcel=server.CreateObject("WExcel.Report")
dim CurItems,MultiSelectItems,SearchValues,strWhere,strWhereDesc,strOrderBy,FromSearch
dim SheetID,ReportID
dim ClientWidth,ClientHeight
dim ReportType,ReportStatus,ReportHead,ListData,ReportChart,TempFile,ActualFields,MayReadFields
SheetID=Request.Cookies("Report")("SheetID")
ReportID=Request.Cookies("Report")("ReportID" & SheetID)
dim Exist
Exist=WExcel.ReportExist(cint(UserID),cint(SheetID),cint(ReportID))
CheckErr
if Exist=false then
Response.Redirect "/hcgis/notfound.asp?Name=报表&Depth=0"
end if
dim Result
if instr(1,Request.ServerVariables("HTTP_REFERER"),"search.asp")>0 then
'来自于查询操作
FromSearch=1
strWhere=""
strWhereDesc=""
CurItems=Request.Form("CurItems")
MultiSelectItems=Request.Form("MultiSelectItems")
if CurItems<>"" then
WExcel.GetSQLWhere cint(SheetID),cstr(CurItems),cstr(MultiSelectItems),strWhere,strWhereDesc,SearchValues
end if
strOrderBy=Request.Cookies("Report")("OrderBy" & CoID & "-" & SheetID & "-" & ReportID)
ClientWidth=Request.Form("ClientWidth")
ClientHeight=Request.Form("ClientHeight")
Result=WExcel.GetReport(cint(UserID),cint(SheetID),cint(ReportID),cint(FromSearch),cstr(strWhere),cstr(strWhereDesc),cstr(strOrderBy),cint(ClientWidth),cint(ClientHeight),ReportType,ReportStatus,ReportHead,ListData,ReportChart,TempFile,ActualFields,MayReadFields)
Response.Cookies("Temp")("ReportFile")=TempFile
Response.Cookies("Temp")("ReportID")=ReportID
Response.Cookies("Report")("ClientWidth")=ClientWidth
Response.Cookies("Report")("ClientHeight")=ClientHeight
Response.Cookies("Report")("Where")=strWhere
Response.Cookies("Report")("WhereDesc")=strWhereDesc
Response.Cookies("Report")("Searched" & CoID & "-" & SheetID & "-" & ReportID)="1"
Response.Cookies("ReportSearchValues")(CoID & "-" & SheetID & "-" & ReportID)=SearchValues
Response.Cookies("ReportSearchValues").Expires = CookieLife
Response.Cookies("Report").Expires = CookieLife
else
'来自于刷新操作
FromSearch=0
strWhere=Request.Cookies("Report")("Where")
strWhereDesc=Request.Cookies("Report")("WhereDesc")
strOrderBy=Request.Form("OrderBy")
ClientWidth=Request.Cookies("Report")("ClientWidth")
ClientHeight=Request.Cookies("Report")("ClientHeight")
Result=WExcel.GetReport(cint(UserID),cint(SheetID),cint(ReportID),cint(FromSearch),cstr(strWhere),cstr(strWhereDesc),cstr(strOrderBy),cint(ClientWidth),cint(ClientHeight),ReportType,ReportStatus,ReportHead,ListData,ReportChart,TempFile,ActualFields,MayReadFields)
Response.Cookies("Report")("OrderBy" & CoID & "-" & SheetID & "-" & ReportID)=strOrderBy
Response.Cookies("Report").Expires = CookieLife
Response.Cookies("Temp")("ReportFile")=TempFile
Response.Cookies("Temp")("ReportID")=ReportID
end if
if cint(ReportType)=ReportType_Analyze then
'偶尔出现图形不能刷新的现象，加入一个变化的参数，让 IE 误认为有不同的调用，达到刷新的目的
ReportChart=replace(ReportChart,".asp",".asp?a=" & cstr(now))
end if
CheckErr
%>
<html>
<head>
</head>
<body leftmargin="0" topmargin="0" marginwidth="0" marginheight="0" LANGUAGE="javascript" onload="return window_onload()">
<table width=95% align=center border=0 CELLSPACING=0 CELLPADDING=0>
<TR height=45>
<TD>
<b><FONT size=4><%=ReportHead%></FONT></b>
</TD>
</TR>
<%if ReportStatus<>1 then%>
<TR height=230 valign="center">
<TD>
有人正在修改报表规格，尚未完成，暂不能访问。
</TD>
</TR>
<%else%>
<%if Result<>0 then%>
<%if Result=2 then%>
<TR height=230 valign="center">
<TD>
服务器端 Excel 程序异常，生成分类统计表时需要利用 Excel 程序。
<br><br>请检查安装此系统的服务器：<br><br>1、是否安装了 Excel 程序，能否正常使用。2、如果 Excel 是正常的，
请检查 IUSR_XXX 用户访问 Excel 的权限，以 WinXP SP2 为例：运行 DCOMCNFG.EXE → 组件服务 → 计算机 →
我的电脑 → DCOM配置 → Microsoft Excel 应用程序 → Right Click → 属性 → 安全 → 启动与激活权限
→ 选中自定义 → 编辑 → 将 IUSR_XXX 添加进来，授予本地启动和激活权限；同样方法，授予 IUSR_XXX 本地访问权限；
重启服务器。其中，IUSR_XXX 中的 XXX 是指服务器的机器名称。
</TD>
</TR>
<%elseif Result=3 then%>
<TR height=90 valign="center">
<TD>
无法生成报表，对于组成本报表的字段，您的查看权限不完整。
</TD>
</TR>
<TR height=70 valign="center">
<TD>
<b>组成本报表的字段：</b><%=ActualFields%>
</TD>
</TR>
<TR height=70 valign="center">
<TD>
<b>您有权访问的字段：</b><%=MayReadFields%>
</TD>
</TR>
<%else%>
<TR height=230 valign="center">
<TD>
报表生成失败。
</TD>
</TR>
<%end if%>
<%else%>
<TR>
<TD>
<%if cint(ReportType)=ReportType_Analyze then%>
<TABLE width=100% border=0 CELLSPACING=1 CELLPADDING=0 bgcolor=999999>
<%else%>
<TABLE width=100% border=0 CELLSPACING=0 CELLPADDING=0>
<%end if%>
<%
dim Count
Count=ubound(ListData)
for i=1 to Count
Response.Write ListData(i-1)
if (i mod 1000)=0 then '数据量很大时，有可能造成传递丢失，因此要及时flush
Response.Flush
end if
next
%>
</TABLE>
</TD>
</TR>
<%if cint(ReportType)=ReportType_Analyze then%>
<TR>
<TD>
<%=ReportChart%>
</TD>
</TR>
<%end if%>
<%end if%>
<%end if%>
<TR>
<TD>
<HR>
</TD>
</TR>
<TR>
<TD>
<table width=100% border=0 CELLSPACING=0 CELLPADDING=0>
<TR>
<TD WIDTH=70%>
<p align=LEFT>附查询条件：<%=server.HTMLEncode(strWhereDesc)%></p>
</TD>
<TD WIDTH=30%>
<p align=RIGHT><%=cstr(now())%></p>
</TD>
</TR>
</TABLE>
</TD>
</TR>
<form METHOD="post" name="frmData">
<input TYPE="hidden" NAME="OrderBy" value="<%=Request.Cookies("Report")("OrderBy" & CoID & "-" & SheetID & "-" & ReportID)%>">
</form>
</TABLE>
</body>
</html>
⌨️ 快捷键说明
复制代码
Ctrl + C
搜索代码
Ctrl + F
全屏模式
F11
切换主题
Ctrl + Shift + D
显示快捷键
?
增大字号
Ctrl + =
减小字号
Ctrl + -