t16550-2.asm

芯片16550与PC机串口通信

;T16550-2.asm
;16550与PC机串口通信
;***************根据CHECK配置信息修改下列符号值*******************
INTR_IVADD   EQU   01CCH          ;INTR对应的中断矢量地址
INTR_OCW1    EQU   0A1H           ;INTR对应PC机内部8259的OCW1地址
INTR_OCW2    EQU   0A0H           ;INTR对应PC机内部8259的OCW2地址
INTR_IM      EQU   0F7H           ;INTR对应的中断屏蔽字
PCI_INTCSR   EQU   9438H          ;PCI卡中断控制寄存器地址
IOY0         EQU   9C00H          ;片选IOY0对应的端口始地址
;****************************************************************
MY16550_0    EQU   IOY0+00H*4     ;16550数据缓冲寄存器端口地址
MY16550_1    EQU   IOY0+01H*4     ;16550中断允许寄存器端口地址
MY16550_3    EQU   IOY0+03H*4     ;16550线路控制寄存器端口地址

PC_COM1_0    EQU   03F8H          ;PC机COM1数据缓冲寄存器端口地址
PC_COM1_1    EQU   03F9H          ;PC机COM1中断允许寄存器端口地址
PC_COM1_3    EQU   03FBH          ;PC机COM1线路控制寄存器端口地址

STACK1 SEGMENT STACK
        DW 256 DUP(?)
STACK1 ENDS

DATA SEGMENT 
CS_BAK   DW  ?                    ;保存INTR原中断处理程序入口段地址的变量
IP_BAK   DW  ?                    ;保存INTR原中断处理程序入口偏移地址的变量
IM_BAK   DB  ?                    ;保存INTR原中断屏蔽字的变量
STR1     DB  'Communication with computer!$'    ;字符串
DATA ENDS

CODE SEGMENT
        ASSUME CS:CODE,DS:DATA

START: MOV AX,DATA
       MOV DS,AX
       CLI

       MOV DX,PCI_INTCSR
       SUB DX,19H
       IN  AL,DX 
       MOV DX,PCI_INTCSR          ;初始化PCI卡中断控制寄存器
       MOV AX,1F00H               ;向PCI_INTCSR中写入003F1F00H
       OUT DX,AX
       ADD DX,2
       MOV AX,003FH
       OUT DX,AX

       MOV AX,0000H               ;替换INTR的中断矢量
       MOV ES,AX
       MOV DI,INTR_IVADD          
       MOV AX,ES:[DI]
       MOV IP_BAK,AX              ;保存INTR原中断处理程序入口偏移地址
       MOV AX,OFFSET MYISR
       MOV ES:[DI],AX             ;设置当前中断处理程序入口偏移地址

       ADD DI,2
       MOV AX,ES:[DI]
       MOV CS_BAK,AX              ;保存INTR原中断处理程序入口段地址
       MOV AX,SEG MYISR
       MOV ES:[DI],AX             ;设置当前中断处理程序入口段地址

       MOV DX,INTR_OCW1           ;设置中断屏蔽寄存器，打开INTR的屏蔽位
       IN  AL,DX
       MOV IM_BAK,AL              ;保存INTR原中断屏蔽字
       AND AL,INTR_IM
       OUT DX,AL

       MOV DX,PC_COM1_3           ;设置PC机COM1线路控制寄存器
       MOV AL,80H                 ;准备设置波特率除数寄存器
       OUT DX,AL
                
       MOV DX,PC_COM1_0           ;设置COM1除数寄存器低字节0CH
       MOV AL,0CH                 ;000C对应9600 bit/s
       OUT DX,AL

       MOV DX,PC_COM1_1           ;设置COM1除数寄存器高字节00H     
       MOV AL,00H
       OUT DX,AL

       MOV DX,PC_COM1_3           ;设置COM1线路控制寄存器，初始化数据格式
       MOV AL,1BH                 ;偶校验，1位停止位，字符宽度为8
       OUT DX,AL

       MOV DX,PC_COM1_1           ;设置中断允许寄存器
       MOV AL,00H                 ;中断不打开
       OUT DX,AL  
 
       MOV DX,MY16550_3           ;设置16550线路控制寄存器
       MOV AL,80H                 ;准备设置波特率除数寄存器
       OUT DX,AL
 
       MOV DX,MY16550_0           ;设置除数寄存器低字节0CH  
       MOV AL,0CH                 ;000C对应9600 bit/s
       OUT DX,AL            
                            
       MOV DX,MY16550_1           ;设置除数寄存器高字节00H
       MOV AL,00H
       OUT DX,AL
       
       MOV DX,MY16550_3           ;设置线路控制寄存器，初始化数据格式
       MOV AL,1BH                 ;偶校验，1位停止位，字符宽度为8
       OUT DX,AL
           
       MOV DX,MY16550_1           ;设置中断允许寄存器
       MOV AL,01H                 ;允许接收缓冲寄存器满产生中断
       OUT DX,AL
        
       STI
       MOV BX,OFFSET STR1
       MOV CX,001CH
SEND:  MOV DX,PC_COM1_0           ;将字符串数据写入COM1发送缓冲寄存器
       MOV AL,[BX]
       OUT DX,AL              
       INC BX       
       CALL DALLY
       LOOP SEND
         
QUIT:  CLI
       MOV DX,PCI_INTCSR          ;恢复PCI卡中断控制寄存器
       MOV AX,0000H
       OUT DX,AX

       MOV AX,0000H               ;恢复INTR原中断矢量
       MOV ES,AX
       MOV DI,INTR_IVADD  
       MOV AX,IP_BAK              ;恢复INTR原中断处理程序入口偏移地址
       MOV ES:[DI],AX
       ADD DI,2
       MOV AX,CS_BAK              ;恢复INTR原中断处理程序入口段地址
       MOV ES:[DI],AX

       MOV DX,INTR_OCW1           ;恢复INTR原中断屏蔽寄存器的屏蔽字
       MOV AL,IM_BAK
       OUT DX,AL
       STI

       MOV AX,4C00H               ;返回到DOS
       INT 21H

MYISR PROC NEAR                   ;中断处理程序MYISR
       MOV DX,MY16550_0           ;读取16550接收缓冲寄存器数据并显示
       IN  AL,DX
       MOV AH,0EH
       INT 10H

OVER:  MOV DX,PCI_INTCSR
       SUB DX,19H
       IN  AL,DX 
       MOV DX,PCI_INTCSR          ;清PCI卡中断控制寄存器标志位
       ADD DX,2
       MOV AX,003FH
       OUT DX,AX
       
       MOV DX,INTR_OCW2           ;向PC机内部8259发送中断结束命令
       MOV AL,20H
       OUT DX,AL
       MOV AL,20H
       OUT 20H,AL
       IRET
MYISR ENDP

DALLY PROC NEAR                   ;软件延时子程序
       PUSH CX
       PUSH AX
       MOV CX,0100H
D1:    MOV AX,2000H
D2:    DEC AX
       JNZ D2
       LOOP D1
       POP AX
       POP CX
       RET
DALLY ENDP
   
CODE ENDS
     END START