fet110_wdt03.s43

msp430p1110

#include  "msp430x11x1.h"
;******************************************************************************
;   MSP-FET430X110 Demo - WDT Toggle P1.0, Interval Overflow ISR, HF XTAL ACLK 
;
;   Description; Toggle P1.0 using software timed by the WDT ISR. In this 
;   example the WDT is clocked with ACLK which is the same as the XTAL and 
;   divided by the WDT by 512 triggering and ISR that will toggle P1.0.
;   ACLK = MCLK = LFXT1 = HF XTAL
;   //** HF XTAL REQUIRED AND NOT INSTALLED ON FET **//
;
;                MSP430F1121
;             -----------------
;         /|\|              XIN|-  
;          | |                 | HF XTAL (455k - 8Mhz) 
;          --|RST          XOUT|-
;            |                 |
;            |             P1.0|-->LED
;
;   M.Buccini
;   Texas Instruments, Inc
;   March 2002
;******************************************************************************
;------------------------------------------------------------------------------ 
            ORG     0F000h                  ; Program Start
;------------------------------------------------------------------------------ 
RESET       mov.w   #300h,SP                ; Initialize stackpointer
SetupWDT    mov.w   #WDT_ADLY_16,&WDTCTL    ; ACLK / 512, interval timer 
SetupBC     bis.b   #XTS,&BCSCTL1           ; LFXT1 = HF XTAL
SetupOsc    bic.b   #OFIFG,&IFG1            ; Clear OSC fault flag 
            mov.w   #0FFh,R15               ; R15 = Delay 
SetupOsc1   dec.w   R15                     ; Additional delay to ensure start 
            jnz     SetupOsc1               ;
            bit.b   #OFIFG,&IFG1            ; OSC fault flag set? 
            jnz     SetupOsc                ; OSC Fault, clear flag again 
            bis.b   #SELM1+SELM0,&BCSCTL2   ; MCLK = LFXT1
            bis.b   #WDTIE,&IE1             ; Enable WDT interrupt 
SetupP1     bis.b   #001h,&P1DIR            ; P1.0 output
            eint                            ; Enable interrupts      
                                            ;				  
Mainloop    bis.w   #LPM0,SR                ; Remain in LPM0
            nop                             ; Required only for C-spy
                                            ;
;------------------------------------------------------------------------------ 
WDT_ISR;    Toggle P1.0
;------------------------------------------------------------------------------ 
            xor.b   #001h,&P1OUT            ; Toggle P1.0
            reti                            ;		 
                                            ;
;------------------------------------------------------------------------------ 
;           Interrupt Vectors Used MSP430F11x1         
;------------------------------------------------------------------------------ 
            ORG     0FFFEh                  ; MSP430 RESET Vector
            DW      RESET                   ; 
            ORG     0FFF4h                  ; WDT Vector
            DW      WDT_ISR                 ; 
            END